Add -lm to the pkg-config link line.
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 # Read our default version string from version.mk.
11 # Please update this file for releases.
12 AC_MSG_CHECKING([version.mk])
13 MK_VERSION=$(awk 'BEGIN { FS = "=" }
14                   /OPUS_VERSION/ { ver = $2}
15                   END {
16                         gsub(/"/, "", ver);
17                         gsub(/^ /, "", ver);
18                         gsub(/ $/, "", ver);
19                         print ver;
20                   }' $srcdir/version.mk)
21 if test -z "$MK_VERSION"; then
22   AC_MSG_RESULT([no])
23 else
24   AC_MSG_RESULT([$MK_VERSION])
25   OPUS_VERSION="$MK_VERSION"
26 fi
27
28 # Override with the git version, if available.
29 AC_MSG_CHECKING([git revision])
30 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
31 if test -z "$GIT_VERSION"; then
32   AC_MSG_RESULT([no])
33 else
34   AC_MSG_RESULT([$GIT_VERSION])
35   OPUS_VERSION="$GIT_VERSION"
36 fi
37
38 # Use 'unknown' if all else fails.
39 if test -z "$OPUS_VERSION"; then
40   OPUS_VERSION="unknown"
41 fi
42
43 # For automake.
44 PACKAGE=opus
45 VERSION=$OPUS_VERSION
46
47 # For autoconf
48 AC_SUBST(OPUS_VERSION)
49
50 # For config.h.
51 AC_DEFINE_UNQUOTED([OPUS_VERSION], ["$OPUS_VERSION"],
52                    [Opus library version string])
53
54 # For libtool.
55 dnl Please update these for releases.
56 OPUS_LT_CURRENT=2
57 OPUS_LT_REVISION=0
58 OPUS_LT_AGE=2
59
60 AC_SUBST(OPUS_LT_CURRENT)
61 AC_SUBST(OPUS_LT_REVISION)
62 AC_SUBST(OPUS_LT_AGE)
63
64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
65 AM_MAINTAINER_MODE
66
67 AC_CANONICAL_HOST
68 AC_MINGW32
69 AM_PROG_LIBTOOL
70 AM_PROG_CC_C_O
71
72 AC_PROG_CC_C99
73 AC_C_BIGENDIAN
74 AC_C_CONST
75 AC_C_INLINE
76
77 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
78 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
79 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
80   [ac_cv_c_restrict=no
81    # The order here caters to the fact that C++ does not require restrict.
82    for ac_kw in __restrict __restrict__ _Restrict restrict; do
83      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
84       [[typedef int * int_ptr;
85         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
86         return ip[0];
87        }]],
88       [[int s[1];
89         int * $ac_kw t = s;
90         t[0] = 0;
91         return foo(t, (void *)0)]])],
92       [ac_cv_c_restrict=$ac_kw])
93      test "$ac_cv_c_restrict" != no && break
94    done
95   ])
96  AH_VERBATIM([restrict],
97 [/* Define to the equivalent of the C99 'restrict' keyword, or to
98    nothing if this is not supported.  Do not define if restrict is
99    supported directly.  */
100 #undef restrict
101 /* Work around a bug in Sun C++: it does not support _Restrict or
102    __restrict__, even though the corresponding Sun C compiler ends up with
103    "#define restrict _Restrict" or "#define restrict __restrict__" in the
104    previous line.  Perhaps some future version of Sun C++ will work with
105    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
106 #if defined __SUNPRO_CC && !defined __RESTRICT
107 # define _Restrict
108 # define __restrict__
109 #endif])
110  case $ac_cv_c_restrict in
111    restrict) ;;
112    no) AC_DEFINE([restrict], []) ;;
113    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
114  esac
115
116 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
117
118 AC_MSG_CHECKING(for C99 variable-size arrays)
119 AC_TRY_COMPILE( [], [static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];],
120 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
121 ],
122 has_var_arrays=no
123 )
124 AC_MSG_RESULT($has_var_arrays)
125
126 AC_CHECK_HEADERS([alloca.h getopt.h])
127 AC_MSG_CHECKING(for alloca)
128 AC_TRY_COMPILE( [#include <alloca.h>], [
129 int foo=10;
130 int *array = alloca(foo);
131 ],
132 [
133 has_alloca=yes;
134 if test x$has_var_arrays = "xno" ; then
135 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
136 fi
137 ],
138 has_alloca=no
139 )
140 AC_MSG_RESULT($has_alloca)
141
142 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
143 if test x"$fp_libm_not_needed" = xdunno; then
144   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
145 fi
146 AC_SUBST([LIBM])
147
148 has_float_approx=no
149 #case "$host_cpu" in
150 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
151 #  has_float_approx=yes
152 #  ;;
153 #esac    
154
155 ac_enable_fixed="no";
156 ac_enable_float="yes";
157 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point       compile without floating point (for machines without a fast enough FPU)],
158 [if test "$enableval" = yes; then
159   ac_enable_fixed="yes";
160   ac_enable_float="no";
161   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point (for machines without a fast enough FPU)])
162 fi])
163
164 ac_enable_fixed_debug="no"
165 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug debug fixed-point implementation],
166 [if test "$enableval" = yes; then
167   ac_enable_fixed_debug="yes"
168   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
169 fi])
170
171 ac_enable_custom_modes="no"
172 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes      enable non-Opus modes, e.g. 44.1 kHz & 2^n frames],
173 [if test "$enableval" = yes; then
174   ac_enable_custom_modes="yes"
175   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
176 fi])
177
178 float_approx=$has_float_approx
179 AC_ARG_ENABLE(float-approx, [  --enable-float-approx      enable fast approximations for floating point],
180     [ if test "$enableval" = yes; then
181     AC_WARN([Floating point approximations are not supported on all platforms.])
182     float_approx=yes
183     else
184     float_approx=no
185     fi], [ float_approx=$has_float_approx ])
186
187 if test "x${float_approx}" = "xyes"; then
188     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
189 fi
190
191 ac_enable_assertions="no"
192 AC_ARG_ENABLE(assertions, [  --enable-assertions        enable additional software error checking],
193 [if test "$enableval" = yes; then
194   ac_enable_assertions="yes"
195   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
196 fi])
197
198 ac_enable_fuzzing="no"
199 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing           causes the encoder to make random decisions],
200 [if test "$enableval" = yes; then
201   ac_enable_fuzzing="yes"
202   AC_DEFINE([FUZZING], , [Fuzzing])
203 fi])
204
205 ac_enable_doc="yes"
206 AC_ARG_ENABLE([doc],
207   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
208                  [ac_enable_doc=$enableval])
209 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
210 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
211   HAVE_DOXYGEN="false"
212   ac_enable_doc="no"
213 fi
214 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
215
216 saved_CFLAGS="$CFLAGS"
217 CFLAGS="$CFLAGS -fvisibility=hidden"
218 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
219 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
220       [ AC_MSG_RESULT([yes])
221         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
222         AC_MSG_RESULT([no]))
223 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
224 AC_SUBST(SYMBOL_VISIBILITY)
225
226 CFLAGS="$CFLAGS -W"
227
228 saved_CFLAGS="$CFLAGS"
229 CFLAGS="$CFLAGS -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
230 AC_MSG_CHECKING([if ${CC} supports -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes])
231 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
232       [ AC_MSG_RESULT([yes])
233         EXTRA_WARNS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes" ],
234         AC_MSG_RESULT([no]))
235 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
236
237 AC_CHECK_FUNCS([lrintf])
238 AC_CHECK_FUNCS([lrint])
239 AC_CHECK_FUNCS([__malloc_hook])
240
241 AC_CHECK_SIZEOF(short)
242 AC_CHECK_SIZEOF(int)
243 AC_CHECK_SIZEOF(long)
244 AC_CHECK_SIZEOF(long long)
245
246 if test x$has_char16 = "xyes" ; then
247         case 1 in
248                 $ac_cv_sizeof_short) SIZE16="short";;
249                 $ac_cv_sizeof_int) SIZE16="int";;
250         esac
251 else
252         case 2 in
253                 $ac_cv_sizeof_short) SIZE16="short";;
254                 $ac_cv_sizeof_int) SIZE16="int";;
255         esac
256 fi
257
258 if test x$has_char16 = "xyes" ; then
259         case 2 in
260                 $ac_cv_sizeof_int) SIZE32="int";;
261                 $ac_cv_sizeof_long) SIZE32="long";;
262                 $ac_cv_sizeof_short) SIZE32="short";;
263         esac
264 else
265         case 4 in
266                 $ac_cv_sizeof_int) SIZE32="int";;
267                 $ac_cv_sizeof_long) SIZE32="long";;
268                 $ac_cv_sizeof_short) SIZE32="short";;
269         esac
270 fi
271
272 AC_SUBST(SIZE16)
273 AC_SUBST(SIZE32)
274
275 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
276 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
277
278 dnl subsitutions for the pkg-config files
279 if test x$ac_enable_float = xyes; then
280   PC_BUILD="floating-point"
281   PC_LIBM=$LIBM
282 else
283   PC_BUILD="fixed-point"
284   PC_LIBM=
285 fi
286 AC_SUBST([PC_BUILD])
287 AC_SUBST([PC_LIBM])
288
289 AC_OUTPUT([Makefile opus.pc opus-uninstalled.pc
290            doc/Makefile doc/Doxyfile])
291
292 AC_MSG_RESULT([
293 ------------------------------------------------------------------------
294   $PACKAGE $VERSION:  Automatic configuration OK.
295   
296     Compiler support:
297
298       C99 var arrays: ................ ${has_var_arrays}
299       C99 lrintf: .................... ${ac_cv_func_lrintf}
300       Alloca: ........................ ${has_alloca}
301     
302     General configuration:
303     
304       Floating point support: ........ ${ac_enable_float}
305       Fast float approximations: ..... ${float_approx}
306       Fixed point debugging: ......... ${ac_enable_fixed_debug}
307       Custom modes: .................. ${ac_enable_custom_modes}
308       Assertion checking: ............ ${ac_enable_assertions}
309       Fuzzing: ....................... ${ac_enable_fuzzing}
310
311       API documentation: ............. ${ac_enable_doc}
312 ------------------------------------------------------------------------
313 ])
314
315 echo "Type \"make; make install\" to compile and install";
316 echo "Type \"make check\" to run the test suite";