Fix the quoting of AC_LANG_PROGRAM
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 dnl The package_version file will be automatically synced to the git revision
4 dnl by the update_version script when configured in the repository, but will
5 dnl remain constant in tarball releases unless it is manually edited.
6 m4_define([CURRENT_VERSION],
7           m4_esyscmd([ ./update_version 2>/dev/null || true
8                        if test -e package_version; then
9                            . ./package_version
10                            printf "$PACKAGE_VERSION"
11                        else
12                            printf "unknown"
13                        fi ]))
14
15 AC_INIT([opus],[CURRENT_VERSION],[opus@xiph.org])
16
17 AC_CONFIG_SRCDIR(src/opus_encoder.c)
18 AC_CONFIG_MACRO_DIR([m4])
19
20 dnl enable silent rules on automake 1.11 and later
21 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
22
23 # For libtool.
24 dnl Please update these for releases.
25 OPUS_LT_CURRENT=5
26 OPUS_LT_REVISION=0
27 OPUS_LT_AGE=5
28
29 AC_SUBST(OPUS_LT_CURRENT)
30 AC_SUBST(OPUS_LT_REVISION)
31 AC_SUBST(OPUS_LT_AGE)
32
33 AM_INIT_AUTOMAKE([no-define])
34 AM_MAINTAINER_MODE([enable])
35
36 AC_CANONICAL_HOST
37 AC_MINGW32
38 AM_PROG_LIBTOOL
39 AM_PROG_CC_C_O
40
41 AC_PROG_CC_C99
42 AC_C_CONST
43 AC_C_INLINE
44
45 AM_PROG_AS
46
47 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
48
49 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
50 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
51 #Note: Both this and the test for variable-size arrays below are also
52 #      done by AC_PROG_CC_C99, but not thoroughly enough apparently.
53 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
54   [ac_cv_c_restrict=no
55    # The order here caters to the fact that C++ does not require restrict.
56    for ac_kw in __restrict __restrict__ _Restrict restrict; do
57      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
58       [[typedef int * int_ptr;
59         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
60         return ip[0];
61        }]],
62       [[int s[1];
63         int * $ac_kw t = s;
64         t[0] = 0;
65         return foo(t, (void *)0)]])],
66       [ac_cv_c_restrict=$ac_kw])
67      test "$ac_cv_c_restrict" != no && break
68    done
69   ])
70
71 AH_VERBATIM([restrict],
72 [/* Define to the equivalent of the C99 'restrict' keyword, or to
73    nothing if this is not supported.  Do not define if restrict is
74    supported directly.  */
75 #undef restrict
76 /* Work around a bug in Sun C++: it does not support _Restrict or
77    __restrict__, even though the corresponding Sun C compiler ends up with
78    "#define restrict _Restrict" or "#define restrict __restrict__" in the
79    previous line.  Perhaps some future version of Sun C++ will work with
80    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
81 #if defined __SUNPRO_CC && !defined __RESTRICT
82 # define _Restrict
83 # define __restrict__
84 #endif])
85
86 case $ac_cv_c_restrict in
87    restrict) ;;
88    no) AC_DEFINE([restrict], []) ;;
89    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
90 esac
91
92 AC_MSG_CHECKING(for C99 variable-size arrays)
93 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
94                    [[static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];]])],
95     [ has_var_arrays=yes
96       use_alloca="no (using var arrays)"
97       AC_DEFINE([VAR_ARRAYS], [1], [Use C99 variable-size arrays])
98     ],[
99       has_var_arrays=no
100     ])
101 AC_MSG_RESULT([$has_var_arrays])
102
103 AS_IF([test "$has_var_arrays" = "no"],
104   [
105    AC_CHECK_HEADERS([alloca.h])
106    AC_MSG_CHECKING(for alloca)
107    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alloca.h>]],
108                                       [[int foo=10; int *array = alloca(foo);]])],
109      [ use_alloca=yes;
110        AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
111      ],[
112        use_alloca=no
113      ])
114    AC_MSG_RESULT([$use_alloca])
115   ])
116
117 LT_LIB_M
118
119 AC_ARG_ENABLE([fixed-point],
120     [AS_HELP_STRING([--enable-fixed-point],
121                     [compile without floating point (for machines without a fast enough FPU)])],,
122     [enable_fixed_point=no])
123
124 AS_IF([test "$enable_fixed_point" = "yes"],[
125   enable_float="no"
126   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point (for machines without a fast enough FPU)])
127   PC_BUILD="fixed-point"
128 ],[
129   enable_float="yes";
130   PC_BUILD="floating-point"
131 ])
132
133 AM_CONDITIONAL([FIXED_POINT], [test "$enable_fixed_point" = "yes"])
134
135 AC_ARG_ENABLE([fixed-point-debug],
136     [AS_HELP_STRING([--enable-fixed-point-debug], [debug fixed-point implementation])],,
137     [enable_fixed_point_debug=no])
138
139 AS_IF([test "$enable_fixed_point_debug" = "yes"],[
140   AC_DEFINE([FIXED_DEBUG], [1], [Debug fixed-point implementation])
141 ])
142
143 AC_ARG_ENABLE([float_api],
144     [AS_HELP_STRING([--disable-float-api],
145                     [compile without the floating point API (for machines with no float library)])],,
146     [enable_float_api=yes])
147
148 AM_CONDITIONAL([DISABLE_FLOAT_API], [test "$enable_float_api" = "no"])
149
150 AS_IF([test "$enable_float_api" = "no"],[
151   AC_DEFINE([DISABLE_FLOAT_API], [1], [Do not build the float API])
152 ])
153
154 AC_ARG_ENABLE([custom-modes],
155     [AS_HELP_STRING([--enable-custom-modes], [enable non-Opus modes, e.g. 44.1 kHz & 2^n frames])],,
156     [enable_custom_modes=no])
157
158 AS_IF([test "$enable_custom_modes" = "yes"],[
159   AC_DEFINE([CUSTOM_MODES], [1], [Custom modes])
160   PC_BUILD="$PC_BUILD, custom modes"
161 ])
162
163 AM_CONDITIONAL([CUSTOM_MODES], [test "$enable_custom_modes" = "yes"])
164
165 has_float_approx=no
166 #case "$host_cpu" in
167 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
168 #  has_float_approx=yes
169 #  ;;
170 #esac
171
172 AC_ARG_ENABLE([float-approx],
173     [AS_HELP_STRING([--enable-float-approx], [enable fast approximations for floating point])],
174     [if test "$enable_float_approx" = "yes"; then
175        AC_WARN([Floating point approximations are not supported on all platforms.])
176      fi
177     ],
178     [enable_float_approx=$has_float_approx])
179
180 AS_IF([test "$enable_float_approx" = "yes"],[
181   AC_DEFINE([FLOAT_APPROX], [1], [Float approximations])
182 ])
183
184 AC_ARG_ENABLE([asm],
185     [AS_HELP_STRING([--disable-asm], [Disable assembly optimizations])],,
186     [enable_asm=yes])
187
188 AC_ARG_ENABLE([rtcd],
189     [AS_HELP_STRING([--disable-rtcd], [Disable run-time CPU capabilities detection])],,
190     [enable_rtcd=yes])
191
192 AC_ARG_ENABLE([intrinsics],
193     [AS_HELP_STRING([--enable-intrinsics], [Enable intrinsics optimizations (only for fixed point x86)])],,
194     [enable_intrinsics=no])
195
196 rtcd_support=no
197 cpu_arm=no
198
199 AS_IF([test x"${enable_asm}" = x"yes"],[
200     inline_optimization="No ASM for your platform, please send patches"
201     case $host_cpu in
202       arm*)
203         dnl Currently we only have asm for fixed-point
204         AS_IF([test "$enable_float" != "yes"],[
205             cpu_arm=yes
206             AC_DEFINE([OPUS_ARM_ASM], [],  [Make use of ARM asm optimization])
207             AS_GCC_INLINE_ASSEMBLY(
208                 [inline_optimization="ARM"],
209                 [inline_optimization="disabled"]
210             )
211             AS_ASM_ARM_EDSP([OPUS_ARM_INLINE_EDSP=1],[OPUS_ARM_INLINE_EDSP=0])
212             AS_ASM_ARM_MEDIA([OPUS_ARM_INLINE_MEDIA=1],
213                 [OPUS_ARM_INLINE_MEDIA=0])
214             AS_ASM_ARM_NEON([OPUS_ARM_INLINE_NEON=1],[OPUS_ARM_INLINE_NEON=0])
215             AS_IF([test x"$inline_optimization" = x"ARM"],[
216                 AM_CONDITIONAL([OPUS_ARM_INLINE_ASM],[true])
217                 AC_DEFINE([OPUS_ARM_INLINE_ASM], 1,
218                     [Use generic ARMv4 inline asm optimizations])
219                 AS_IF([test x"$OPUS_ARM_INLINE_EDSP" = x"1"],[
220                     AC_DEFINE([OPUS_ARM_INLINE_EDSP], [1],
221                         [Use ARMv5E inline asm optimizations])
222                     inline_optimization="$inline_optimization (EDSP)"
223                 ])
224                 AS_IF([test x"$OPUS_ARM_INLINE_MEDIA" = x"1"],[
225                     AC_DEFINE([OPUS_ARM_INLINE_MEDIA], [1],
226                         [Use ARMv6 inline asm optimizations])
227                     inline_optimization="$inline_optimization (Media)"
228                 ])
229                 AS_IF([test x"$OPUS_ARM_INLINE_NEON" = x"1"],[
230                     AC_DEFINE([OPUS_ARM_INLINE_NEON], 1,
231                         [Use ARM NEON inline asm optimizations])
232                     inline_optimization="$inline_optimization (NEON)"
233                 ])
234             ])
235             dnl We need Perl to translate RVCT-syntax asm to gas syntax.
236             AC_CHECK_PROG([HAVE_PERL], perl, yes, no)
237             AS_IF([test x"$HAVE_PERL" = x"yes"],[
238                 AM_CONDITIONAL([OPUS_ARM_EXTERNAL_ASM],[true])
239                 asm_optimization="ARM"
240                 AS_IF([test x"$OPUS_ARM_INLINE_EDSP" = x"1"], [
241                     OPUS_ARM_PRESUME_EDSP=1
242                     OPUS_ARM_MAY_HAVE_EDSP=1
243                 ],
244                 [
245                     OPUS_ARM_PRESUME_EDSP=0
246                     OPUS_ARM_MAY_HAVE_EDSP=0
247                 ])
248                 AS_IF([test x"$OPUS_ARM_INLINE_MEDIA" = x"1"], [
249                     OPUS_ARM_PRESUME_MEDIA=1
250                     OPUS_ARM_MAY_HAVE_MEDIA=1
251                 ],
252                 [
253                     OPUS_ARM_PRESUME_MEDIA=0
254                     OPUS_ARM_MAY_HAVE_MEDIA=0
255                 ])
256                 AS_IF([test x"$OPUS_ARM_INLINE_NEON" = x"1"], [
257                     OPUS_ARM_PRESUME_NEON=1
258                     OPUS_ARM_MAY_HAVE_NEON=1
259                 ],
260                 [
261                     OPUS_ARM_PRESUME_NEON=0
262                     OPUS_ARM_MAY_HAVE_NEON=0
263                 ])
264                 AS_IF([test x"$enable_rtcd" = x"yes"],[
265                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_EDSP" != x"1"],[
266                         AC_MSG_NOTICE(
267                           [Trying to force-enable armv5e EDSP instructions...])
268                         AS_ASM_ARM_EDSP_FORCE([OPUS_ARM_MAY_HAVE_EDSP=1])
269                     ])
270                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_MEDIA" != x"1"],[
271                         AC_MSG_NOTICE(
272                           [Trying to force-enable ARMv6 media instructions...])
273                         AS_ASM_ARM_MEDIA_FORCE([OPUS_ARM_MAY_HAVE_MEDIA=1])
274                     ])
275                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON" != x"1"],[
276                         AC_MSG_NOTICE(
277                           [Trying to force-enable NEON instructions...])
278                         AS_ASM_ARM_NEON_FORCE([OPUS_ARM_MAY_HAVE_NEON=1])
279                     ])
280                 ])
281                 rtcd_support=
282                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_EDSP" = x"1"],[
283                     AC_DEFINE(OPUS_ARM_MAY_HAVE_EDSP, 1,
284                         [Define if assembler supports EDSP instructions])
285                     AS_IF([test x"$OPUS_ARM_PRESUME_EDSP" = x"1"],[
286                         AC_DEFINE(OPUS_ARM_PRESUME_EDSP, 1,
287                           [Define if binary requires EDSP instruction support])
288                         asm_optimization="$asm_optimization (EDSP)"
289                     ],
290                         [rtcd_support="$rtcd_support (EDSP)"]
291                     )
292                 ])
293                 AC_SUBST(OPUS_ARM_MAY_HAVE_EDSP)
294                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_MEDIA" = x"1"],[
295                     AC_DEFINE(OPUS_ARM_MAY_HAVE_MEDIA, 1,
296                       [Define if assembler supports ARMv6 media instructions])
297                     AS_IF([test x"$OPUS_ARM_PRESUME_MEDIA" = x"1"],[
298                         AC_DEFINE(OPUS_ARM_PRESUME_MEDIA, 1,
299                           [Define if binary requires ARMv6 media instruction support])
300                         asm_optimization="$asm_optimization (Media)"
301                     ],
302                         [rtcd_support="$rtcd_support (Media)"]
303                     )
304                 ])
305                 AC_SUBST(OPUS_ARM_MAY_HAVE_MEDIA)
306                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON" = x"1"],[
307                     AC_DEFINE(OPUS_ARM_MAY_HAVE_NEON, 1,
308                       [Define if compiler supports NEON instructions])
309                     AS_IF([test x"$OPUS_ARM_PRESUME_NEON" = x"1"], [
310                         AC_DEFINE(OPUS_ARM_PRESUME_NEON, 1,
311                           [Define if binary requires NEON instruction support])
312                         asm_optimization="$asm_optimization (NEON)"
313                     ],
314                         [rtcd_support="$rtcd_support (NEON)"]
315                     )
316                 ])
317                 AC_SUBST(OPUS_ARM_MAY_HAVE_NEON)
318                 dnl Make sure turning on RTCD gets us at least one
319                 dnl instruction set.
320                 AS_IF([test x"$rtcd_support" != x""],
321                     [rtcd_support=ARM"$rtcd_support"],
322                     [rtcd_support="no"]
323                 )
324                 AC_MSG_CHECKING([for apple style tools])
325                 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
326 #ifndef __APPLE__
327 #error 1
328 #endif],[])],
329                     [AC_MSG_RESULT([yes]); ARM2GNU_PARAMS="--apple"],
330                     [AC_MSG_RESULT([no]); ARM2GNU_PARAMS=""])
331                 AC_SUBST(ARM2GNU_PARAMS)
332             ],
333             [
334                 AC_MSG_WARN(
335                   [*** ARM assembly requires perl -- disabling optimizations])
336                 asm_optimization="(missing perl dependency for ARM)"
337             ])
338         ])
339         ;;
340     esac
341 ],[
342    inline_optimization="disabled"
343    asm_optimization="disabled"
344 ])
345
346 AM_CONDITIONAL([CPU_ARM], [test "$cpu_arm" = "yes"])
347 AM_CONDITIONAL([OPUS_ARM_INLINE_ASM],
348     [test x"${inline_optimization%% *}" = x"ARM"])
349 AM_CONDITIONAL([OPUS_ARM_EXTERNAL_ASM],
350     [test x"${asm_optimization%% *}" = x"ARM"])
351
352 AM_CONDITIONAL([HAVE_SSE4_1], [false])
353 AM_CONDITIONAL([HAVE_SSE2], [false])
354 AS_IF([test x"$enable_intrinsics" = x"yes"],[
355 AS_IF([test x"$enable_float" = x"no"],
356 [AS_IF([test x"$host_cpu" = x"i386" -o x"$host_cpu" = x"i686" -o x"$host_cpu" = x"x86_64"],[
357     AS_IF([test x"$enable_rtcd" = x"yes"],[
358             get_cpuid_by_asm="no"
359             AC_MSG_CHECKING([Get CPU Info])
360             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
361                  #include <stdio.h>
362             ]],[[
363                  unsigned int CPUInfo0;
364                  unsigned int CPUInfo1;
365                  unsigned int CPUInfo2;
366                  unsigned int CPUInfo3;
367                  unsigned int InfoType;
368                  __asm__ __volatile__ (
369                  "cpuid11":
370                  "=a" (CPUInfo0),
371                  "=b" (CPUInfo1),
372                  "=c" (CPUInfo2),
373                  "=d" (CPUInfo3) :
374                  "a" (InfoType), "c" (0)
375                 );
376             ]])],
377             [get_cpuid_by_asm="yes"
378              AC_MSG_RESULT([Inline Assembly])],
379              [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
380                  #include <cpuid.h>
381             ]],[[
382                  unsigned int CPUInfo0;
383                  unsigned int CPUInfo1;
384                  unsigned int CPUInfo2;
385                  unsigned int CPUInfo3;
386                  unsigned int InfoType;
387                  __get_cpuid(InfoType, &CPUInfo0, &CPUInfo1, &CPUInfo2, &CPUInfo3);
388             ]])],
389             [AC_MSG_RESULT([C method])],
390             [AC_MSG_ERROR([not support Get CPU Info, please disable intrinsics ])])])
391
392        AC_MSG_CHECKING([sse4.1])
393        TMP_CFLAGS="$CFLAGS"
394        gcc -Q --help=target | grep "\-msse4.1 "
395        AS_IF([test x"$?" = x"0"],[
396             CFLAGS="$CFLAGS -msse4.1"
397             AC_CHECK_HEADER(xmmintrin.h, [], [AC_MSG_ERROR([Couldn't find xmmintrin.h])])
398             AC_CHECK_HEADER(emmintrin.h, [], [AC_MSG_ERROR([Couldn't find emmintrin.h])])
399             AC_CHECK_HEADER(smmintrin.h, [], [AC_MSG_ERROR([Couldn't find smmintrin.h])],[
400             #ifdef HAVE_XMMINSTRIN_H
401                  #include <xmmintrin.h>
402                  #endif
403                  #ifdef HAVE_EMMINSTRIN_H
404                  #include <emmintrin.h>
405                  #endif
406             ])
407
408             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
409                  #include <xmmintrin.h>
410                  #include <emmintrin.h>
411                  #include <smmintrin.h>
412             ]],[[
413                  __m128i mtest = _mm_setzero_si128();
414                  mtest = _mm_cmpeq_epi64(mtest, mtest);
415             ]])],
416             [AC_MSG_RESULT([yes])], [AC_MSG_ERROR([Compiler & linker failure for sse4.1, please disable intrinsics])])
417
418             CFLAGS="$TMP_CFLAGS"
419             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE4_1], [1], [For x86 sse4.1 instrinsics optimizations])
420             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE2], [1], [For x86 sse2 instrinsics optimizations])
421             rtcd_support="x86 sse4.1"
422             AM_CONDITIONAL([HAVE_SSE4_1], [true])
423             AM_CONDITIONAL([HAVE_SSE2], [true])
424             AS_IF([test x"$get_cpuid_by_asm" = x"yes"],[AC_DEFINE([CPU_INFO_BY_ASM], [1], [Get CPU Info by asm method])],
425             [AC_DEFINE([CPU_INFO_BY_C], [1], [Get CPU Info by C method])])
426              ],[
427                gcc -Q --help=target | grep "\-msse2 "
428                AC_MSG_CHECKING([sse2])
429                AS_IF([test x"$?" = x"0"],[
430                    AC_MSG_RESULT([yes])
431                    CFLAGS="$CFLAGS -msse2"
432                    AC_CHECK_HEADER(xmmintrin.h, [], [AC_MSG_ERROR([Couldn't find xmmintrin.h])])
433                    AC_CHECK_HEADER(emmintrin.h, [], [AC_MSG_ERROR([Couldn't find emmintrin.h])])
434
435                    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
436                         #include <xmmintrin.h>
437                         #include <emmintrin.h>
438                    ]],[[
439                         __m128i mtest = _mm_setzero_si128();
440                    ]])],
441                    [AC_MSG_RESULT([yes])], [AC_MSG_ERROR([Compiler & linker failure for sse2, please disable intrinsics])])
442
443                   CFLAGS="$TMP_CFLAGS"
444                   AC_DEFINE([OPUS_X86_MAY_HAVE_SSE2], [1], [For x86 sse2 instrinsics optimize])
445                   rtcd_support="x86 sse2"
446                   AM_CONDITIONAL([HAVE_SSE2], [true])
447                   AS_IF([test x"$get_cpuid_by_asm" = x"yes"],[AC_DEFINE([CPU_INFO_BY_ASM], [1], [Get CPU Info by asm method])],
448                   [AC_DEFINE([CPU_INFO_BY_C], [1], [Get CPU Info by c method])])
449             ],[enable_intrinsics="no"])
450         ])
451     ], [enable_intrinsics="no"])
452 ])
453 ], [enable_intrinsics="no"])
454 ])
455
456 AS_IF([test x"$enable_rtcd" = x"yes"],[
457     AS_IF([test x"$rtcd_support" != x"no"],[
458         AC_DEFINE([OPUS_HAVE_RTCD], [1],
459             [Use run-time CPU capabilities detection])
460         OPUS_HAVE_RTCD=1
461         AC_SUBST(OPUS_HAVE_RTCD)
462     ])
463 ],[
464     rtcd_support="disabled"
465 ])
466
467 AC_ARG_ENABLE([assertions],
468     [AS_HELP_STRING([--enable-assertions],[enable additional software error checking])],,
469     [enable_assertions=no])
470
471 AS_IF([test "$enable_assertions" = "yes"], [
472   AC_DEFINE([ENABLE_ASSERTIONS], [1], [Assertions])
473 ])
474
475 AC_ARG_ENABLE([fuzzing],
476     [AS_HELP_STRING([--enable-fuzzing],[causes the encoder to make random decisions])],,
477     [enable_fuzzing=no])
478
479 AS_IF([test "$enable_fuzzing" = "yes"], [
480   AC_DEFINE([FUZZING], [1], [Fuzzing])
481 ])
482
483 AC_ARG_ENABLE([doc],
484     [AS_HELP_STRING([--disable-doc], [Do not build API documentation])],,
485     [enable_doc=yes])
486
487 AS_IF([test "$enable_doc" = "yes"], [
488   AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
489 ],[
490   HAVE_DOXYGEN=no
491 ])
492
493 AM_CONDITIONAL([HAVE_DOXYGEN], [test "$HAVE_DOXYGEN" = "yes"])
494
495 AC_ARG_ENABLE([extra-programs],
496     [AS_HELP_STRING([--disable-extra-programs], [Do not build extra programs (demo and tests)])],,
497     [enable_extra_programs=yes])
498
499 AM_CONDITIONAL([EXTRA_PROGRAMS], [test "$enable_extra_programs" = "yes"])
500
501
502 saved_CFLAGS="$CFLAGS"
503 CFLAGS="$CFLAGS -fvisibility=hidden"
504 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
505 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
506     [ AC_MSG_RESULT([yes]) ],
507     [ AC_MSG_RESULT([no])
508       CFLAGS="$saved_CFLAGS"
509     ])
510
511 CFLAGS="$CFLAGS -W"
512
513 warn_CFLAGS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
514 saved_CFLAGS="$CFLAGS"
515 CFLAGS="$CFLAGS $warn_CFLAGS"
516 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
517 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
518     [ AC_MSG_RESULT([yes]) ],
519     [ AC_MSG_RESULT([no])
520       CFLAGS="$saved_CFLAGS"
521     ])
522
523 saved_LIBS="$LIBS"
524 LIBS="$LIBS $LIBM"
525 AC_CHECK_FUNCS([lrintf])
526 AC_CHECK_FUNCS([lrint])
527 LIBS="$saved_LIBS"
528
529 AC_CHECK_FUNCS([__malloc_hook])
530
531 AC_SUBST([PC_BUILD])
532
533 AC_CONFIG_FILES([
534     Makefile
535     opus.pc
536     opus-uninstalled.pc
537     celt/arm/armopts.s
538     doc/Makefile
539     doc/Doxyfile
540 ])
541 AC_CONFIG_HEADERS([config.h])
542
543 AC_OUTPUT
544
545 AC_MSG_NOTICE([
546 ------------------------------------------------------------------------
547   $PACKAGE_NAME $PACKAGE_VERSION:  Automatic configuration OK.
548
549     Compiler support:
550
551       C99 var arrays: ................ ${has_var_arrays}
552       C99 lrintf: .................... ${ac_cv_func_lrintf}
553       Use alloca: .................... ${use_alloca}
554
555     General configuration:
556
557       Floating point support: ........ ${enable_float}
558       Fast float approximations: ..... ${enable_float_approx}
559       Fixed point debugging: ......... ${enable_fixed_point_debug}
560       Inline Assembly Optimizations: . ${inline_optimization}
561       External Assembly Optimizations: ${asm_optimization}
562       Intrinsics Optimizations.......: ${enable_intrinsics}
563       Run-time CPU detection: ........ ${rtcd_support}
564       Custom modes: .................. ${enable_custom_modes}
565       Assertion checking: ............ ${enable_assertions}
566       Fuzzing: ....................... ${enable_fuzzing}
567
568       API documentation: ............. ${enable_doc}
569       Extra programs: ................ ${enable_extra_programs}
570 ------------------------------------------------------------------------
571
572  Type "make; make install" to compile and install
573  Type "make check" to run the test suite
574 ])
575