df65008c760281ea0f7040d650ddcd7a02fab94b
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 OPUS_MAJOR_VERSION=0
11 OPUS_MINOR_VERSION=9
12 OPUS_MICRO_VERSION=10
13 OPUS_EXTRA_VERSION=
14
15 OPUS_VERSION="$OPUS_MAJOR_VERSION.$OPUS_MINOR_VERSION.$OPUS_MICRO_VERSION$OPUS_EXTRA_VERSION"
16 AC_MSG_CHECKING([git revision])
17 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
18 if test -z "$GIT_VERSION"; then
19   AC_MSG_RESULT([no])
20 else
21   AC_MSG_RESULT([$GIT_VERSION])
22   OPUS_VERSION="$GIT_VERSION"
23 fi
24
25 LIBOPUS_SUFFIX=0
26
27 OPUS_LT_CURRENT=0
28 OPUS_LT_REVISION=0
29 OPUS_LT_AGE=0
30
31 AC_SUBST(OPUS_LT_CURRENT)
32 AC_SUBST(OPUS_LT_REVISION)
33 AC_SUBST(OPUS_LT_AGE)
34 AC_SUBST(LIBOPUS_SUFFIX)
35
36 # For automake.
37 VERSION=$OPUS_VERSION
38 PACKAGE=opus
39
40 # For our version string
41 AC_SUBST(OPUS_VERSION)
42
43 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
44 AM_MAINTAINER_MODE
45
46 AC_CANONICAL_HOST
47 AM_PROG_LIBTOOL
48 AM_PROG_CC_C_O
49
50 AC_PROG_CC_C99
51 AC_C_BIGENDIAN
52 AC_C_CONST
53 AC_C_INLINE
54 AC_C_RESTRICT
55
56 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
57
58 AC_MSG_CHECKING(for C99 variable-size arrays)
59 AC_TRY_COMPILE( , [
60 int foo=10;
61 int array[foo];
62 ],
63 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
64 ],
65 has_var_arrays=no
66 )
67 AC_MSG_RESULT($has_var_arrays)
68
69 AC_CHECK_HEADERS([alloca.h getopt.h])
70 AC_MSG_CHECKING(for alloca)
71 AC_TRY_COMPILE( [#include <alloca.h>], [
72 int foo=10;
73 int *array = alloca(foo);
74 ],
75 [
76 has_alloca=yes;
77 if test x$has_var_arrays = "xno" ; then
78 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
79 fi
80 ],
81 has_alloca=no
82 )
83 AC_MSG_RESULT($has_alloca)
84
85 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
86 if test x"$fp_libm_not_needed" = xdunno; then
87   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
88 fi
89 AC_SUBST([LIBM])
90
91 AC_DEFINE_UNQUOTED(OPUS_VERSION, "${OPUS_VERSION}", [Complete version string])
92 AC_DEFINE_UNQUOTED(OPUS_MAJOR_VERSION, ${OPUS_MAJOR_VERSION}, [Version major])
93 AC_DEFINE_UNQUOTED(OPUS_MINOR_VERSION, ${OPUS_MINOR_VERSION}, [Version minor])
94 AC_DEFINE_UNQUOTED(OPUS_MICRO_VERSION, ${OPUS_MICRO_VERSION}, [Version micro])
95 AC_DEFINE_UNQUOTED(OPUS_EXTRA_VERSION, "${OPUS_EXTRA_VERSION}", [Version extra])
96
97 has_float_approx=no
98 #case "$host_cpu" in
99 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
100 #  has_float_approx=yes
101 #  ;;
102 #esac    
103
104 ac_enable_fixed="no";
105 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    compile as fixed-point],
106 [if test "$enableval" = yes; then
107   ac_enable_fixed="yes";
108   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point])
109 else
110   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
111 fi],
112 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
113
114 ac_enable_fixed_debug="no"
115 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  debug fixed-point implementation],
116 [if test "$enableval" = yes; then
117   ac_enable_fixed_debug="yes"
118   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
119 fi])
120
121 ac_enable_custom_modes="no"
122 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes        Enable non-Opus modes, like 44.1 kHz and powers of two ],
123 [if test "$enableval" = yes; then
124   ac_enable_custom_modes="yes"
125   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
126 fi])
127
128 float_approx=$has_float_approx
129 AC_ARG_ENABLE(float-approx, [  --enable-float-approx   enable fast approximations for floating point],
130     [ if test "$enableval" = yes; then
131     AC_WARN([Floating point approximations are not supported on all platforms.])
132     float_approx=yes
133     else
134     float_approx=no
135     fi], [ float_approx=$has_float_approx ])
136
137 if test "x${float_approx}" = "xyes"; then
138     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
139 fi
140
141 ac_enable_assertions="no"
142 AC_ARG_ENABLE(assertions, [  --enable-assertions     enable additional software error checking],
143 [if test "$enableval" = yes; then
144   ac_enable_assertions="yes"
145   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
146 fi])
147
148 ac_enable_fuzzing="no"
149 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing     causes the encoder to make random decisions],
150 [if test "$enableval" = yes; then
151   ac_enable_fuzzing="yes"
152   AC_DEFINE([FUZZING], , [Fuzzing])
153 fi])
154
155 ac_enable_doc="yes"
156 AC_ARG_ENABLE([doc],
157   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
158                  [ac_enable_doc=$enableval])
159 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
160 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
161   HAVE_DOXYGEN="false"
162   ac_enable_doc="no"
163 fi
164 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
165
166 saved_CFLAGS="$CFLAGS"
167 CFLAGS="$CFLAGS -fvisibility=hidden"
168 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
169 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
170       [ AC_MSG_RESULT([yes])
171         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
172         AC_MSG_RESULT([no]))
173 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
174 AC_SUBST(SYMBOL_VISIBILITY)
175
176 if test $ac_cv_c_compiler_gnu = yes ; then
177 saved_CFLAGS="$CFLAGS"
178 CFLAGS="$CFLAGS -fstack-protector-all"
179 AC_MSG_CHECKING([if ${CC} supports -fstack-protector-all])
180 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
181       [ AC_MSG_RESULT([yes])
182         STACK_PROTECTOR="-fstack-protector-all" ],
183         AC_MSG_RESULT([no]))
184 CFLAGS="$saved_CFLAGS $STACK_PROTECTOR"
185 fi
186
187 CFLAGS="$CFLAGS -W"
188
189 saved_CFLAGS="$CFLAGS"
190 CFLAGS="$CFLAGS -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
191 AC_MSG_CHECKING([if ${CC} supports -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes])
192 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
193       [ AC_MSG_RESULT([yes])
194         EXTRA_WARNS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes" ],
195         AC_MSG_RESULT([no]))
196 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
197
198 AC_CHECK_FUNCS([lrintf])
199 AC_CHECK_FUNCS([lrint])
200 AC_CHECK_FUNCS([__malloc_hook])
201
202 AC_CHECK_SIZEOF(short)
203 AC_CHECK_SIZEOF(int)
204 AC_CHECK_SIZEOF(long)
205 AC_CHECK_SIZEOF(long long)
206
207 if test x$has_char16 = "xyes" ; then
208         case 1 in
209                 $ac_cv_sizeof_short) SIZE16="short";;
210                 $ac_cv_sizeof_int) SIZE16="int";;
211         esac
212 else
213         case 2 in
214                 $ac_cv_sizeof_short) SIZE16="short";;
215                 $ac_cv_sizeof_int) SIZE16="int";;
216         esac
217 fi
218
219 if test x$has_char16 = "xyes" ; then
220         case 2 in
221                 $ac_cv_sizeof_int) SIZE32="int";;
222                 $ac_cv_sizeof_long) SIZE32="long";;
223                 $ac_cv_sizeof_short) SIZE32="short";;
224         esac
225 else
226         case 4 in
227                 $ac_cv_sizeof_int) SIZE32="int";;
228                 $ac_cv_sizeof_long) SIZE32="long";;
229                 $ac_cv_sizeof_short) SIZE32="short";;
230         esac
231 fi
232
233 AC_SUBST(SIZE16)
234 AC_SUBST(SIZE32)
235
236 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
237 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
238
239 AC_OUTPUT([Makefile opus.pc opus-uninstalled.pc
240            doc/Makefile doc/Doxyfile])
241
242 AC_MSG_RESULT([
243 ------------------------------------------------------------------------
244   $PACKAGE $VERSION:  Automatic configuration OK.
245   
246     Compiler support:
247
248       C99 var arrays: ................ ${has_var_arrays}
249       C99 lrintf: .................... ${ac_cv_func_lrintf}
250       Alloca: ........................ ${has_alloca}
251     
252     General configuration:
253     
254       Fast float approximations: ..... ${float_approx}
255       Fixed point support: ........... ${ac_enable_fixed}
256       Fixed point debugging: ......... ${ac_enable_fixed_debug}
257       Custom modes: .................. ${ac_enable_custom_modes}
258       Assertion checking: ............ ${ac_enable_assertions}
259       Fuzzing: ....................... ${ac_enable_fuzzing}
260
261       API documentation: ............. ${ac_enable_doc}
262 ------------------------------------------------------------------------
263 ])
264
265 echo "Type \"make; make install\" to compile and install";
266 echo "Type \"make check\" to run the test suite";