cf7df1c32694fa49614ac13683e0b5b725096479
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 OPUS_MAJOR_VERSION=1
11 OPUS_MINOR_VERSION=0
12 OPUS_MICRO_VERSION=1
13 OPUS_EXTRA_VERSION=-rc
14
15 OPUS_VERSION="$OPUS_MAJOR_VERSION.$OPUS_MINOR_VERSION.$OPUS_MICRO_VERSION$OPUS_EXTRA_VERSION"
16 AC_MSG_CHECKING([git revision])
17 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
18 if test -z "$GIT_VERSION"; then
19   AC_MSG_RESULT([no])
20 else
21   AC_MSG_RESULT([$GIT_VERSION])
22   OPUS_VERSION="$GIT_VERSION"
23 fi
24
25 # For automake.
26 VERSION=$OPUS_VERSION
27 PACKAGE=opus
28
29 # For our version string.
30 AC_SUBST(OPUS_VERSION)
31
32 # For config.h
33 AC_DEFINE_UNQUOTED(OPUS_VERSION, "${OPUS_VERSION}", [Complete version string])
34 AC_DEFINE_UNQUOTED(OPUS_MAJOR_VERSION, ${OPUS_MAJOR_VERSION}, [Version major])
35 AC_DEFINE_UNQUOTED(OPUS_MINOR_VERSION, ${OPUS_MINOR_VERSION}, [Version minor])
36 AC_DEFINE_UNQUOTED(OPUS_MICRO_VERSION, ${OPUS_MICRO_VERSION}, [Version micro])
37 AC_DEFINE_UNQUOTED(OPUS_EXTRA_VERSION, "${OPUS_EXTRA_VERSION}", [Version extra])
38
39 # For libtool.
40 OPUS_LT_CURRENT=2
41 OPUS_LT_REVISION=0
42 OPUS_LT_AGE=2
43
44 AC_SUBST(OPUS_LT_CURRENT)
45 AC_SUBST(OPUS_LT_REVISION)
46 AC_SUBST(OPUS_LT_AGE)
47
48 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
49 AM_MAINTAINER_MODE
50
51 AC_CANONICAL_HOST
52 AC_MINGW32
53 AM_PROG_LIBTOOL
54 AM_PROG_CC_C_O
55
56 AC_PROG_CC_C99
57 AC_C_BIGENDIAN
58 AC_C_CONST
59 AC_C_INLINE
60
61 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
62 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
63 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
64   [ac_cv_c_restrict=no
65    # The order here caters to the fact that C++ does not require restrict.
66    for ac_kw in __restrict __restrict__ _Restrict restrict; do
67      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
68       [[typedef int * int_ptr;
69         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
70         return ip[0];
71        }]],
72       [[int s[1];
73         int * $ac_kw t = s;
74         t[0] = 0;
75         return foo(t, (void *)0)]])],
76       [ac_cv_c_restrict=$ac_kw])
77      test "$ac_cv_c_restrict" != no && break
78    done
79   ])
80  AH_VERBATIM([restrict],
81 [/* Define to the equivalent of the C99 'restrict' keyword, or to
82    nothing if this is not supported.  Do not define if restrict is
83    supported directly.  */
84 #undef restrict
85 /* Work around a bug in Sun C++: it does not support _Restrict or
86    __restrict__, even though the corresponding Sun C compiler ends up with
87    "#define restrict _Restrict" or "#define restrict __restrict__" in the
88    previous line.  Perhaps some future version of Sun C++ will work with
89    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
90 #if defined __SUNPRO_CC && !defined __RESTRICT
91 # define _Restrict
92 # define __restrict__
93 #endif])
94  case $ac_cv_c_restrict in
95    restrict) ;;
96    no) AC_DEFINE([restrict], []) ;;
97    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
98  esac
99
100 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
101
102 AC_MSG_CHECKING(for C99 variable-size arrays)
103 AC_TRY_COMPILE( [], [static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];],
104 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
105 ],
106 has_var_arrays=no
107 )
108 AC_MSG_RESULT($has_var_arrays)
109
110 AC_CHECK_HEADERS([alloca.h getopt.h])
111 AC_MSG_CHECKING(for alloca)
112 AC_TRY_COMPILE( [#include <alloca.h>], [
113 int foo=10;
114 int *array = alloca(foo);
115 ],
116 [
117 has_alloca=yes;
118 if test x$has_var_arrays = "xno" ; then
119 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
120 fi
121 ],
122 has_alloca=no
123 )
124 AC_MSG_RESULT($has_alloca)
125
126 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
127 if test x"$fp_libm_not_needed" = xdunno; then
128   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
129 fi
130 AC_SUBST([LIBM])
131
132 has_float_approx=no
133 #case "$host_cpu" in
134 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
135 #  has_float_approx=yes
136 #  ;;
137 #esac    
138
139 ac_enable_fixed="no";
140 ac_enable_float="yes";
141 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point       compile without floating point],
142 [if test "$enableval" = yes; then
143   ac_enable_fixed="yes";
144   ac_enable_float="no";
145   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point])
146 else
147   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
148 fi],
149 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
150
151 ac_enable_fixed_debug="no"
152 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug debug fixed-point implementation],
153 [if test "$enableval" = yes; then
154   ac_enable_fixed_debug="yes"
155   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
156 fi])
157
158 ac_enable_custom_modes="no"
159 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes      enable non-Opus modes, e.g. 44.1 kHz & 2^n frames],
160 [if test "$enableval" = yes; then
161   ac_enable_custom_modes="yes"
162   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
163 fi])
164
165 float_approx=$has_float_approx
166 AC_ARG_ENABLE(float-approx, [  --enable-float-approx      enable fast approximations for floating point],
167     [ if test "$enableval" = yes; then
168     AC_WARN([Floating point approximations are not supported on all platforms.])
169     float_approx=yes
170     else
171     float_approx=no
172     fi], [ float_approx=$has_float_approx ])
173
174 if test "x${float_approx}" = "xyes"; then
175     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
176 fi
177
178 ac_enable_assertions="no"
179 AC_ARG_ENABLE(assertions, [  --enable-assertions        enable additional software error checking],
180 [if test "$enableval" = yes; then
181   ac_enable_assertions="yes"
182   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
183 fi])
184
185 ac_enable_fuzzing="no"
186 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing           causes the encoder to make random decisions],
187 [if test "$enableval" = yes; then
188   ac_enable_fuzzing="yes"
189   AC_DEFINE([FUZZING], , [Fuzzing])
190 fi])
191
192 ac_enable_doc="yes"
193 AC_ARG_ENABLE([doc],
194   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
195                  [ac_enable_doc=$enableval])
196 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
197 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
198   HAVE_DOXYGEN="false"
199   ac_enable_doc="no"
200 fi
201 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
202
203 saved_CFLAGS="$CFLAGS"
204 CFLAGS="$CFLAGS -fvisibility=hidden"
205 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
206 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
207       [ AC_MSG_RESULT([yes])
208         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
209         AC_MSG_RESULT([no]))
210 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
211 AC_SUBST(SYMBOL_VISIBILITY)
212
213 ac_build_stack_protector=no
214 if test "x$ac_cv_c_compiler_gnu" = "xyes" && test "x$MINGW32" != "xyes" ; then
215 AC_ARG_ENABLE(stack-protector,
216      AS_HELP_STRING([--disable-stack-protector],[Disable compiler stack hardening]),
217      [
218        if test "x$enableval" = "xno"; then
219          ac_build_stack_protector=$enableval
220        fi
221      ], [
222        ac_build_stack_protector=yes
223      ])
224 if test "x$ac_build_stack_protector" = "xyes"; then
225 if test "x$ac_cv_c_compiler_gnu" = "xyes" ; then
226 saved_CFLAGS="$CFLAGS"
227 CFLAGS="$CFLAGS -fstack-protector-all"
228 AC_MSG_CHECKING([if ${CC} supports -fstack-protector-all])
229 AC_LINK_IFELSE([AC_LANG_SOURCE([void main(void){char foo;}])],
230       [ AC_MSG_RESULT([yes])
231         STACK_PROTECTOR="-fstack-protector-all" ],
232         AC_MSG_RESULT([no]))
233 CFLAGS="$saved_CFLAGS $STACK_PROTECTOR"
234 fi
235 fi
236 fi
237
238 CFLAGS="$CFLAGS -W"
239
240 saved_CFLAGS="$CFLAGS"
241 CFLAGS="$CFLAGS -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
242 AC_MSG_CHECKING([if ${CC} supports -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes])
243 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
244       [ AC_MSG_RESULT([yes])
245         EXTRA_WARNS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes" ],
246         AC_MSG_RESULT([no]))
247 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
248
249 AC_CHECK_FUNCS([lrintf])
250 AC_CHECK_FUNCS([lrint])
251 AC_CHECK_FUNCS([__malloc_hook])
252
253 AC_CHECK_SIZEOF(short)
254 AC_CHECK_SIZEOF(int)
255 AC_CHECK_SIZEOF(long)
256 AC_CHECK_SIZEOF(long long)
257
258 if test x$has_char16 = "xyes" ; then
259         case 1 in
260                 $ac_cv_sizeof_short) SIZE16="short";;
261                 $ac_cv_sizeof_int) SIZE16="int";;
262         esac
263 else
264         case 2 in
265                 $ac_cv_sizeof_short) SIZE16="short";;
266                 $ac_cv_sizeof_int) SIZE16="int";;
267         esac
268 fi
269
270 if test x$has_char16 = "xyes" ; then
271         case 2 in
272                 $ac_cv_sizeof_int) SIZE32="int";;
273                 $ac_cv_sizeof_long) SIZE32="long";;
274                 $ac_cv_sizeof_short) SIZE32="short";;
275         esac
276 else
277         case 4 in
278                 $ac_cv_sizeof_int) SIZE32="int";;
279                 $ac_cv_sizeof_long) SIZE32="long";;
280                 $ac_cv_sizeof_short) SIZE32="short";;
281         esac
282 fi
283
284 AC_SUBST(SIZE16)
285 AC_SUBST(SIZE32)
286
287 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
288 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
289
290 AC_OUTPUT([Makefile opus.pc opus-uninstalled.pc
291            doc/Makefile doc/Doxyfile])
292
293 AC_MSG_RESULT([
294 ------------------------------------------------------------------------
295   $PACKAGE $VERSION:  Automatic configuration OK.
296   
297     Compiler support:
298
299       C99 var arrays: ................ ${has_var_arrays}
300       C99 lrintf: .................... ${ac_cv_func_lrintf}
301       Alloca: ........................ ${has_alloca}
302     
303     General configuration:
304     
305       Floating point support: ........ ${ac_enable_float}
306       Fast float approximations: ..... ${float_approx}
307       Fixed point debugging: ......... ${ac_enable_fixed_debug}
308       Custom modes: .................. ${ac_enable_custom_modes}
309       Assertion checking: ............ ${ac_enable_assertions}
310       Fuzzing: ....................... ${ac_enable_fuzzing}
311
312       API documentation: ............. ${ac_enable_doc}
313 ------------------------------------------------------------------------
314 ])
315
316 echo "Type \"make; make install\" to compile and install";
317 echo "Type \"make check\" to run the test suite";