Variable framesize improvements
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AC_CONFIG_HEADERS([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 # Read our default version string from version.mk.
11 # Please update this file for releases.
12 AC_MSG_CHECKING([version.mk])
13 MK_VERSION=$(awk 'BEGIN { FS = "=" }
14                   /OPUS_VERSION/ { ver = $2}
15                   END {
16                         gsub(/"/, "", ver);
17                         gsub(/^ /, "", ver);
18                         gsub(/ $/, "", ver);
19                         print ver;
20                   }' $srcdir/version.mk)
21 if test -z "$MK_VERSION"; then
22   AC_MSG_RESULT([no])
23 else
24   AC_MSG_RESULT([$MK_VERSION])
25   OPUS_VERSION="$MK_VERSION"
26 fi
27
28 # Override with the git version, if available.
29 AC_MSG_CHECKING([git revision])
30 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
31 if test -z "$GIT_VERSION"; then
32   AC_MSG_RESULT([no])
33 else
34   AC_MSG_RESULT([$GIT_VERSION])
35   OPUS_VERSION="$GIT_VERSION"
36 fi
37
38 # Use 'unknown' if all else fails.
39 if test -z "$OPUS_VERSION"; then
40   OPUS_VERSION="unknown"
41 fi
42
43 # For automake.
44 PACKAGE=opus
45 VERSION=$OPUS_VERSION
46
47 # For autoconf
48 AC_SUBST(OPUS_VERSION)
49
50 # For config.h.
51 AC_DEFINE_UNQUOTED([OPUS_VERSION], ["$OPUS_VERSION"],
52                    [Opus library version string])
53
54 # For libtool.
55 dnl Please update these for releases.
56 OPUS_LT_CURRENT=3
57 OPUS_LT_REVISION=0
58 OPUS_LT_AGE=3
59
60 AC_SUBST(OPUS_LT_CURRENT)
61 AC_SUBST(OPUS_LT_REVISION)
62 AC_SUBST(OPUS_LT_AGE)
63
64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
65 AM_MAINTAINER_MODE([enable])
66
67 AC_CANONICAL_HOST
68 AC_MINGW32
69 AM_PROG_LIBTOOL
70 AM_PROG_CC_C_O
71
72 AC_PROG_CC_C99
73 AC_C_CONST
74 AC_C_INLINE
75
76 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
77 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
78 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
79   [ac_cv_c_restrict=no
80    # The order here caters to the fact that C++ does not require restrict.
81    for ac_kw in __restrict __restrict__ _Restrict restrict; do
82      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
83       [[typedef int * int_ptr;
84         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
85         return ip[0];
86        }]],
87       [[int s[1];
88         int * $ac_kw t = s;
89         t[0] = 0;
90         return foo(t, (void *)0)]])],
91       [ac_cv_c_restrict=$ac_kw])
92      test "$ac_cv_c_restrict" != no && break
93    done
94   ])
95  AH_VERBATIM([restrict],
96 [/* Define to the equivalent of the C99 'restrict' keyword, or to
97    nothing if this is not supported.  Do not define if restrict is
98    supported directly.  */
99 #undef restrict
100 /* Work around a bug in Sun C++: it does not support _Restrict or
101    __restrict__, even though the corresponding Sun C compiler ends up with
102    "#define restrict _Restrict" or "#define restrict __restrict__" in the
103    previous line.  Perhaps some future version of Sun C++ will work with
104    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
105 #if defined __SUNPRO_CC && !defined __RESTRICT
106 # define _Restrict
107 # define __restrict__
108 #endif])
109  case $ac_cv_c_restrict in
110    restrict) ;;
111    no) AC_DEFINE([restrict], []) ;;
112    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
113  esac
114
115 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
116
117 AC_MSG_CHECKING(for C99 variable-size arrays)
118 AC_TRY_COMPILE( [], [static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];],
119 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
120 ],
121 has_var_arrays=no
122 )
123 AC_MSG_RESULT($has_var_arrays)
124
125 AC_CHECK_HEADERS([alloca.h getopt.h])
126 AC_MSG_CHECKING(for alloca)
127 AC_TRY_COMPILE( [#include <alloca.h>], [
128 int foo=10;
129 int *array = alloca(foo);
130 ],
131 [
132 has_alloca=yes;
133 if test x$has_var_arrays = "xno" ; then
134 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
135 fi
136 ],
137 has_alloca=no
138 )
139 AC_MSG_RESULT($has_alloca)
140
141 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
142 if test x"$fp_libm_not_needed" = xdunno; then
143   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
144 fi
145 AC_SUBST([LIBM])
146
147 has_float_approx=no
148 #case "$host_cpu" in
149 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
150 #  has_float_approx=yes
151 #  ;;
152 #esac    
153
154 ac_enable_fixed="no";
155 ac_enable_float="yes";
156 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point       compile without floating point (for machines without a fast enough FPU)],
157 [if test "$enableval" = yes; then
158   ac_enable_fixed="yes";
159   ac_enable_float="no";
160   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point (for machines without a fast enough FPU)])
161 fi])
162
163 ac_enable_fixed_debug="no"
164 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug debug fixed-point implementation],
165 [if test "$enableval" = yes; then
166   ac_enable_fixed_debug="yes"
167   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
168 fi])
169
170 ac_enable_custom_modes="no"
171 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes      enable non-Opus modes, e.g. 44.1 kHz & 2^n frames],
172 [if test "$enableval" = yes; then
173   ac_enable_custom_modes="yes"
174   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
175 fi])
176
177 float_approx=$has_float_approx
178 AC_ARG_ENABLE(float-approx, [  --enable-float-approx      enable fast approximations for floating point],
179     [ if test "$enableval" = yes; then
180     AC_WARN([Floating point approximations are not supported on all platforms.])
181     float_approx=yes
182     else
183     float_approx=no
184     fi], [ float_approx=$has_float_approx ])
185
186 if test "x${float_approx}" = "xyes"; then
187     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
188 fi
189
190 ac_enable_assertions="no"
191 AC_ARG_ENABLE(assertions, [  --enable-assertions        enable additional software error checking],
192 [if test "$enableval" = yes; then
193   ac_enable_assertions="yes"
194   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
195 fi])
196
197 ac_enable_fuzzing="no"
198 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing           causes the encoder to make random decisions],
199 [if test "$enableval" = yes; then
200   ac_enable_fuzzing="yes"
201   AC_DEFINE([FUZZING], , [Fuzzing])
202 fi])
203
204 ac_enable_doc="yes"
205 AC_ARG_ENABLE([doc],
206   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
207                  [ac_enable_doc=$enableval])
208 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
209 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
210   HAVE_DOXYGEN="false"
211   ac_enable_doc="no"
212 fi
213 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
214
215 saved_CFLAGS="$CFLAGS"
216 CFLAGS="$CFLAGS -fvisibility=hidden"
217 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
218 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
219       [ AC_MSG_RESULT([yes])
220         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
221         AC_MSG_RESULT([no]))
222 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
223 AC_SUBST(SYMBOL_VISIBILITY)
224
225 CFLAGS="$CFLAGS -W"
226
227 warn_CFLAGS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
228 saved_CFLAGS="$CFLAGS"
229 CFLAGS="$CFLAGS $warn_CFLAGS"
230 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
231 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
232       [ AC_MSG_RESULT([yes])
233         EXTRA_WARNS=$warn_CFLAGS ],
234         AC_MSG_RESULT([no]))
235 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
236
237 AC_CHECK_FUNCS([lrintf])
238 AC_CHECK_FUNCS([lrint])
239 AC_CHECK_FUNCS([__malloc_hook])
240
241 AC_CHECK_SIZEOF(short)
242 AC_CHECK_SIZEOF(int)
243 AC_CHECK_SIZEOF(long)
244 AC_CHECK_SIZEOF(long long)
245
246 if test x$has_char16 = "xyes" ; then
247         case 1 in
248                 $ac_cv_sizeof_short) SIZE16="short";;
249                 $ac_cv_sizeof_int) SIZE16="int";;
250         esac
251 else
252         case 2 in
253                 $ac_cv_sizeof_short) SIZE16="short";;
254                 $ac_cv_sizeof_int) SIZE16="int";;
255         esac
256 fi
257
258 if test x$has_char16 = "xyes" ; then
259         case 2 in
260                 $ac_cv_sizeof_int) SIZE32="int";;
261                 $ac_cv_sizeof_long) SIZE32="long";;
262                 $ac_cv_sizeof_short) SIZE32="short";;
263         esac
264 else
265         case 4 in
266                 $ac_cv_sizeof_int) SIZE32="int";;
267                 $ac_cv_sizeof_long) SIZE32="long";;
268                 $ac_cv_sizeof_short) SIZE32="short";;
269         esac
270 fi
271
272 AC_SUBST(SIZE16)
273 AC_SUBST(SIZE32)
274
275 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
276 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
277
278 dnl subsitutions for the pkg-config files
279 if test x$ac_enable_float = xyes; then
280   PC_BUILD="floating-point"
281   PC_LIBM=$LIBM
282 else
283   PC_BUILD="fixed-point"
284   PC_LIBM=
285 fi
286 dnl opus_custom requires libm as well
287 if test x$ac_enable_custom_modes = xyes; then
288   PC_BUILD="${PC_BUILD}, custom modes"
289   PC_LIBM=$LIBM
290 fi
291 AC_SUBST([PC_BUILD])
292 AC_SUBST([PC_LIBM])
293
294
295 AC_CONFIG_FILES([Makefile opus.pc opus-uninstalled.pc
296                  doc/Makefile doc/Doxyfile])
297
298 AC_OUTPUT
299
300 AC_MSG_RESULT([
301 ------------------------------------------------------------------------
302   $PACKAGE $VERSION:  Automatic configuration OK.
303   
304     Compiler support:
305
306       C99 var arrays: ................ ${has_var_arrays}
307       C99 lrintf: .................... ${ac_cv_func_lrintf}
308       Alloca: ........................ ${has_alloca}
309     
310     General configuration:
311     
312       Floating point support: ........ ${ac_enable_float}
313       Fast float approximations: ..... ${float_approx}
314       Fixed point debugging: ......... ${ac_enable_fixed_debug}
315       Custom modes: .................. ${ac_enable_custom_modes}
316       Assertion checking: ............ ${ac_enable_assertions}
317       Fuzzing: ....................... ${ac_enable_fuzzing}
318
319       API documentation: ............. ${ac_enable_doc}
320 ------------------------------------------------------------------------
321 ])
322
323 echo "Type \"make; make install\" to compile and install";
324 echo "Type \"make check\" to run the test suite";