Fix an MSVC warning.
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 # Read our default version string from version.mk.
11 # Please update this file for releases.
12 AC_MSG_CHECKING([version.mk])
13 MK_VERSION=$(awk 'BEGIN { FS = "=" }
14                   /OPUS_VERSION/ { ver = $2}
15                   END {
16                         gsub(/"/, "", ver);
17                         gsub(/^ /, "", ver);
18                         gsub(/ $/, "", ver);
19                         print ver;
20                   }' $srcdir/version.mk)
21 if test -z "$MK_VERSION"; then
22   AC_MSG_RESULT([no])
23 else
24   AC_MSG_RESULT([$MK_VERSION])
25   OPUS_VERSION="$MK_VERSION"
26 fi
27
28 # Override with the git version, if available.
29 AC_MSG_CHECKING([git revision])
30 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
31 if test -z "$GIT_VERSION"; then
32   AC_MSG_RESULT([no])
33 else
34   AC_MSG_RESULT([$GIT_VERSION])
35   OPUS_VERSION="$GIT_VERSION"
36 fi
37
38 # Use 'unknown' if all else fails.
39 if test -z "$OPUS_VERSION"; then
40   OPUS_VERSION="unknown"
41 fi
42
43 # For automake.
44 PACKAGE=opus
45 VERSION=$OPUS_VERSION
46
47 # For config.h.
48 AC_SUBST(OPUS_VERSION)
49
50 # For libtool.
51 dnl Please update these for releases.
52 OPUS_LT_CURRENT=2
53 OPUS_LT_REVISION=0
54 OPUS_LT_AGE=2
55
56 AC_SUBST(OPUS_LT_CURRENT)
57 AC_SUBST(OPUS_LT_REVISION)
58 AC_SUBST(OPUS_LT_AGE)
59
60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
61 AM_MAINTAINER_MODE
62
63 AC_CANONICAL_HOST
64 AC_MINGW32
65 AM_PROG_LIBTOOL
66 AM_PROG_CC_C_O
67
68 AC_PROG_CC_C99
69 AC_C_BIGENDIAN
70 AC_C_CONST
71 AC_C_INLINE
72
73 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
74 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
75 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
76   [ac_cv_c_restrict=no
77    # The order here caters to the fact that C++ does not require restrict.
78    for ac_kw in __restrict __restrict__ _Restrict restrict; do
79      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
80       [[typedef int * int_ptr;
81         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
82         return ip[0];
83        }]],
84       [[int s[1];
85         int * $ac_kw t = s;
86         t[0] = 0;
87         return foo(t, (void *)0)]])],
88       [ac_cv_c_restrict=$ac_kw])
89      test "$ac_cv_c_restrict" != no && break
90    done
91   ])
92  AH_VERBATIM([restrict],
93 [/* Define to the equivalent of the C99 'restrict' keyword, or to
94    nothing if this is not supported.  Do not define if restrict is
95    supported directly.  */
96 #undef restrict
97 /* Work around a bug in Sun C++: it does not support _Restrict or
98    __restrict__, even though the corresponding Sun C compiler ends up with
99    "#define restrict _Restrict" or "#define restrict __restrict__" in the
100    previous line.  Perhaps some future version of Sun C++ will work with
101    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
102 #if defined __SUNPRO_CC && !defined __RESTRICT
103 # define _Restrict
104 # define __restrict__
105 #endif])
106  case $ac_cv_c_restrict in
107    restrict) ;;
108    no) AC_DEFINE([restrict], []) ;;
109    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
110  esac
111
112 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
113
114 AC_MSG_CHECKING(for C99 variable-size arrays)
115 AC_TRY_COMPILE( [], [static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];],
116 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
117 ],
118 has_var_arrays=no
119 )
120 AC_MSG_RESULT($has_var_arrays)
121
122 AC_CHECK_HEADERS([alloca.h getopt.h])
123 AC_MSG_CHECKING(for alloca)
124 AC_TRY_COMPILE( [#include <alloca.h>], [
125 int foo=10;
126 int *array = alloca(foo);
127 ],
128 [
129 has_alloca=yes;
130 if test x$has_var_arrays = "xno" ; then
131 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
132 fi
133 ],
134 has_alloca=no
135 )
136 AC_MSG_RESULT($has_alloca)
137
138 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
139 if test x"$fp_libm_not_needed" = xdunno; then
140   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
141 fi
142 AC_SUBST([LIBM])
143
144 has_float_approx=no
145 #case "$host_cpu" in
146 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
147 #  has_float_approx=yes
148 #  ;;
149 #esac    
150
151 ac_enable_fixed="no";
152 ac_enable_float="yes";
153 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point       compile without floating point],
154 [if test "$enableval" = yes; then
155   ac_enable_fixed="yes";
156   ac_enable_float="no";
157   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point])
158 else
159   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
160 fi],
161 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
162
163 ac_enable_fixed_debug="no"
164 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug debug fixed-point implementation],
165 [if test "$enableval" = yes; then
166   ac_enable_fixed_debug="yes"
167   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
168 fi])
169
170 ac_enable_custom_modes="no"
171 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes      enable non-Opus modes, e.g. 44.1 kHz & 2^n frames],
172 [if test "$enableval" = yes; then
173   ac_enable_custom_modes="yes"
174   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
175 fi])
176
177 float_approx=$has_float_approx
178 AC_ARG_ENABLE(float-approx, [  --enable-float-approx      enable fast approximations for floating point],
179     [ if test "$enableval" = yes; then
180     AC_WARN([Floating point approximations are not supported on all platforms.])
181     float_approx=yes
182     else
183     float_approx=no
184     fi], [ float_approx=$has_float_approx ])
185
186 if test "x${float_approx}" = "xyes"; then
187     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
188 fi
189
190 ac_enable_assertions="no"
191 AC_ARG_ENABLE(assertions, [  --enable-assertions        enable additional software error checking],
192 [if test "$enableval" = yes; then
193   ac_enable_assertions="yes"
194   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
195 fi])
196
197 ac_enable_fuzzing="no"
198 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing           causes the encoder to make random decisions],
199 [if test "$enableval" = yes; then
200   ac_enable_fuzzing="yes"
201   AC_DEFINE([FUZZING], , [Fuzzing])
202 fi])
203
204 ac_enable_doc="yes"
205 AC_ARG_ENABLE([doc],
206   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
207                  [ac_enable_doc=$enableval])
208 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
209 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
210   HAVE_DOXYGEN="false"
211   ac_enable_doc="no"
212 fi
213 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
214
215 saved_CFLAGS="$CFLAGS"
216 CFLAGS="$CFLAGS -fvisibility=hidden"
217 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
218 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
219       [ AC_MSG_RESULT([yes])
220         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
221         AC_MSG_RESULT([no]))
222 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
223 AC_SUBST(SYMBOL_VISIBILITY)
224
225 ac_build_stack_protector=no
226 if test "x$ac_cv_c_compiler_gnu" = "xyes" && test "x$MINGW32" != "xyes" ; then
227 AC_ARG_ENABLE(stack-protector,
228      AS_HELP_STRING([--disable-stack-protector],[Disable compiler stack hardening]),
229      [
230        if test "x$enableval" = "xno"; then
231          ac_build_stack_protector=$enableval
232        fi
233      ], [
234        ac_build_stack_protector=yes
235      ])
236 if test "x$ac_build_stack_protector" = "xyes"; then
237 if test "x$ac_cv_c_compiler_gnu" = "xyes" ; then
238 saved_CFLAGS="$CFLAGS"
239 CFLAGS="$CFLAGS -fstack-protector-all"
240 AC_MSG_CHECKING([if ${CC} supports -fstack-protector-all])
241 AC_LINK_IFELSE([AC_LANG_SOURCE([void main(void){char foo;}])],
242       [ AC_MSG_RESULT([yes])
243         STACK_PROTECTOR="-fstack-protector-all" ],
244         AC_MSG_RESULT([no]))
245 CFLAGS="$saved_CFLAGS $STACK_PROTECTOR"
246 fi
247 fi
248 fi
249
250 CFLAGS="$CFLAGS -W"
251
252 saved_CFLAGS="$CFLAGS"
253 CFLAGS="$CFLAGS -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
254 AC_MSG_CHECKING([if ${CC} supports -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes])
255 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
256       [ AC_MSG_RESULT([yes])
257         EXTRA_WARNS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes" ],
258         AC_MSG_RESULT([no]))
259 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
260
261 AC_CHECK_FUNCS([lrintf])
262 AC_CHECK_FUNCS([lrint])
263 AC_CHECK_FUNCS([__malloc_hook])
264
265 AC_CHECK_SIZEOF(short)
266 AC_CHECK_SIZEOF(int)
267 AC_CHECK_SIZEOF(long)
268 AC_CHECK_SIZEOF(long long)
269
270 if test x$has_char16 = "xyes" ; then
271         case 1 in
272                 $ac_cv_sizeof_short) SIZE16="short";;
273                 $ac_cv_sizeof_int) SIZE16="int";;
274         esac
275 else
276         case 2 in
277                 $ac_cv_sizeof_short) SIZE16="short";;
278                 $ac_cv_sizeof_int) SIZE16="int";;
279         esac
280 fi
281
282 if test x$has_char16 = "xyes" ; then
283         case 2 in
284                 $ac_cv_sizeof_int) SIZE32="int";;
285                 $ac_cv_sizeof_long) SIZE32="long";;
286                 $ac_cv_sizeof_short) SIZE32="short";;
287         esac
288 else
289         case 4 in
290                 $ac_cv_sizeof_int) SIZE32="int";;
291                 $ac_cv_sizeof_long) SIZE32="long";;
292                 $ac_cv_sizeof_short) SIZE32="short";;
293         esac
294 fi
295
296 AC_SUBST(SIZE16)
297 AC_SUBST(SIZE32)
298
299 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
300 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
301
302 AC_OUTPUT([Makefile opus.pc opus-uninstalled.pc
303            doc/Makefile doc/Doxyfile])
304
305 AC_MSG_RESULT([
306 ------------------------------------------------------------------------
307   $PACKAGE $VERSION:  Automatic configuration OK.
308   
309     Compiler support:
310
311       C99 var arrays: ................ ${has_var_arrays}
312       C99 lrintf: .................... ${ac_cv_func_lrintf}
313       Alloca: ........................ ${has_alloca}
314     
315     General configuration:
316     
317       Floating point support: ........ ${ac_enable_float}
318       Fast float approximations: ..... ${float_approx}
319       Fixed point debugging: ......... ${ac_enable_fixed_debug}
320       Custom modes: .................. ${ac_enable_custom_modes}
321       Assertion checking: ............ ${ac_enable_assertions}
322       Fuzzing: ....................... ${ac_enable_fuzzing}
323
324       API documentation: ............. ${ac_enable_doc}
325 ------------------------------------------------------------------------
326 ])
327
328 echo "Type \"make; make install\" to compile and install";
329 echo "Type \"make check\" to run the test suite";