5e21dce6fd5d5d2f19717e5f4a1c05c8380b1711
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 # Read our default version string from version.mk.
11 # Please update this file for releases.
12 AC_MSG_CHECKING([version.mk])
13 MK_VERSION=$(awk 'BEGIN { FS = "=" }
14                   /OPUS_VERSION/ { ver = $2}
15                   END {
16                         gsub(/"/, "", ver);
17                         gsub(/^ /, "", ver);
18                         gsub(/ $/, "", ver);
19                         print ver;
20                   }' $srcdir/version.mk)
21 if test -z "$MK_VERSION"; then
22   AC_MSG_RESULT([no])
23 else
24   AC_MSG_RESULT([$MK_VERSION])
25   OPUS_VERSION="$MK_VERSION"
26 fi
27
28 # Override with the git version, if available.
29 AC_MSG_CHECKING([git revision])
30 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
31 if test -z "$GIT_VERSION"; then
32   AC_MSG_RESULT([no])
33 else
34   AC_MSG_RESULT([$GIT_VERSION])
35   OPUS_VERSION="$GIT_VERSION"
36 fi
37
38 # Use 'unknown' if all else fails.
39 if test -z "$OPUS_VERSION"; then
40   OPUS_VERSION="unknown"
41 fi
42
43 # For automake.
44 PACKAGE=opus
45 VERSION=$OPUS_VERSION
46
47 # For config.h.
48 AC_SUBST(OPUS_VERSION)
49 AC_DEFINE_UNQUOTED([OPUS_VERSION], ["$OPUS_VERSION"],
50                    [Opus library version string])
51
52 # For libtool.
53 dnl Please update these for releases.
54 OPUS_LT_CURRENT=2
55 OPUS_LT_REVISION=0
56 OPUS_LT_AGE=2
57
58 AC_SUBST(OPUS_LT_CURRENT)
59 AC_SUBST(OPUS_LT_REVISION)
60 AC_SUBST(OPUS_LT_AGE)
61
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
63 AM_MAINTAINER_MODE
64
65 AC_CANONICAL_HOST
66 AC_MINGW32
67 AM_PROG_LIBTOOL
68 AM_PROG_CC_C_O
69
70 AC_PROG_CC_C99
71 AC_C_BIGENDIAN
72 AC_C_CONST
73 AC_C_INLINE
74
75 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
76 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
77 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
78   [ac_cv_c_restrict=no
79    # The order here caters to the fact that C++ does not require restrict.
80    for ac_kw in __restrict __restrict__ _Restrict restrict; do
81      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
82       [[typedef int * int_ptr;
83         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
84         return ip[0];
85        }]],
86       [[int s[1];
87         int * $ac_kw t = s;
88         t[0] = 0;
89         return foo(t, (void *)0)]])],
90       [ac_cv_c_restrict=$ac_kw])
91      test "$ac_cv_c_restrict" != no && break
92    done
93   ])
94  AH_VERBATIM([restrict],
95 [/* Define to the equivalent of the C99 'restrict' keyword, or to
96    nothing if this is not supported.  Do not define if restrict is
97    supported directly.  */
98 #undef restrict
99 /* Work around a bug in Sun C++: it does not support _Restrict or
100    __restrict__, even though the corresponding Sun C compiler ends up with
101    "#define restrict _Restrict" or "#define restrict __restrict__" in the
102    previous line.  Perhaps some future version of Sun C++ will work with
103    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
104 #if defined __SUNPRO_CC && !defined __RESTRICT
105 # define _Restrict
106 # define __restrict__
107 #endif])
108  case $ac_cv_c_restrict in
109    restrict) ;;
110    no) AC_DEFINE([restrict], []) ;;
111    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
112  esac
113
114 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
115
116 AC_MSG_CHECKING(for C99 variable-size arrays)
117 AC_TRY_COMPILE( [], [static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];],
118 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
119 ],
120 has_var_arrays=no
121 )
122 AC_MSG_RESULT($has_var_arrays)
123
124 AC_CHECK_HEADERS([alloca.h getopt.h])
125 AC_MSG_CHECKING(for alloca)
126 AC_TRY_COMPILE( [#include <alloca.h>], [
127 int foo=10;
128 int *array = alloca(foo);
129 ],
130 [
131 has_alloca=yes;
132 if test x$has_var_arrays = "xno" ; then
133 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
134 fi
135 ],
136 has_alloca=no
137 )
138 AC_MSG_RESULT($has_alloca)
139
140 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
141 if test x"$fp_libm_not_needed" = xdunno; then
142   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
143 fi
144 AC_SUBST([LIBM])
145
146 has_float_approx=no
147 #case "$host_cpu" in
148 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
149 #  has_float_approx=yes
150 #  ;;
151 #esac    
152
153 ac_enable_fixed="no";
154 ac_enable_float="yes";
155 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point       compile without floating point],
156 [if test "$enableval" = yes; then
157   ac_enable_fixed="yes";
158   ac_enable_float="no";
159   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point])
160 else
161   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
162 fi],
163 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
164
165 ac_enable_fixed_debug="no"
166 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug debug fixed-point implementation],
167 [if test "$enableval" = yes; then
168   ac_enable_fixed_debug="yes"
169   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
170 fi])
171
172 ac_enable_custom_modes="no"
173 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes      enable non-Opus modes, e.g. 44.1 kHz & 2^n frames],
174 [if test "$enableval" = yes; then
175   ac_enable_custom_modes="yes"
176   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
177 fi])
178
179 float_approx=$has_float_approx
180 AC_ARG_ENABLE(float-approx, [  --enable-float-approx      enable fast approximations for floating point],
181     [ if test "$enableval" = yes; then
182     AC_WARN([Floating point approximations are not supported on all platforms.])
183     float_approx=yes
184     else
185     float_approx=no
186     fi], [ float_approx=$has_float_approx ])
187
188 if test "x${float_approx}" = "xyes"; then
189     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
190 fi
191
192 ac_enable_assertions="no"
193 AC_ARG_ENABLE(assertions, [  --enable-assertions        enable additional software error checking],
194 [if test "$enableval" = yes; then
195   ac_enable_assertions="yes"
196   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
197 fi])
198
199 ac_enable_fuzzing="no"
200 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing           causes the encoder to make random decisions],
201 [if test "$enableval" = yes; then
202   ac_enable_fuzzing="yes"
203   AC_DEFINE([FUZZING], , [Fuzzing])
204 fi])
205
206 ac_enable_doc="yes"
207 AC_ARG_ENABLE([doc],
208   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
209                  [ac_enable_doc=$enableval])
210 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
211 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
212   HAVE_DOXYGEN="false"
213   ac_enable_doc="no"
214 fi
215 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
216
217 saved_CFLAGS="$CFLAGS"
218 CFLAGS="$CFLAGS -fvisibility=hidden"
219 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
220 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
221       [ AC_MSG_RESULT([yes])
222         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
223         AC_MSG_RESULT([no]))
224 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
225 AC_SUBST(SYMBOL_VISIBILITY)
226
227 ac_build_stack_protector=no
228 if test "x$ac_cv_c_compiler_gnu" = "xyes" && test "x$MINGW32" != "xyes" ; then
229 AC_ARG_ENABLE(stack-protector,
230      AS_HELP_STRING([--disable-stack-protector],[Disable compiler stack hardening]),
231      [
232        if test "x$enableval" = "xno"; then
233          ac_build_stack_protector=$enableval
234        fi
235      ], [
236        ac_build_stack_protector=yes
237      ])
238 if test "x$ac_build_stack_protector" = "xyes"; then
239 if test "x$ac_cv_c_compiler_gnu" = "xyes" ; then
240 saved_CFLAGS="$CFLAGS"
241 CFLAGS="$CFLAGS -fstack-protector-all"
242 AC_MSG_CHECKING([if ${CC} supports -fstack-protector-all])
243 AC_LINK_IFELSE([AC_LANG_SOURCE([void main(void){char foo;}])],
244       [ AC_MSG_RESULT([yes])
245         STACK_PROTECTOR="-fstack-protector-all" ],
246         AC_MSG_RESULT([no]))
247 CFLAGS="$saved_CFLAGS $STACK_PROTECTOR"
248 fi
249 fi
250 fi
251
252 CFLAGS="$CFLAGS -W"
253
254 saved_CFLAGS="$CFLAGS"
255 CFLAGS="$CFLAGS -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
256 AC_MSG_CHECKING([if ${CC} supports -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes])
257 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
258       [ AC_MSG_RESULT([yes])
259         EXTRA_WARNS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes" ],
260         AC_MSG_RESULT([no]))
261 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
262
263 AC_CHECK_FUNCS([lrintf])
264 AC_CHECK_FUNCS([lrint])
265 AC_CHECK_FUNCS([__malloc_hook])
266
267 AC_CHECK_SIZEOF(short)
268 AC_CHECK_SIZEOF(int)
269 AC_CHECK_SIZEOF(long)
270 AC_CHECK_SIZEOF(long long)
271
272 if test x$has_char16 = "xyes" ; then
273         case 1 in
274                 $ac_cv_sizeof_short) SIZE16="short";;
275                 $ac_cv_sizeof_int) SIZE16="int";;
276         esac
277 else
278         case 2 in
279                 $ac_cv_sizeof_short) SIZE16="short";;
280                 $ac_cv_sizeof_int) SIZE16="int";;
281         esac
282 fi
283
284 if test x$has_char16 = "xyes" ; then
285         case 2 in
286                 $ac_cv_sizeof_int) SIZE32="int";;
287                 $ac_cv_sizeof_long) SIZE32="long";;
288                 $ac_cv_sizeof_short) SIZE32="short";;
289         esac
290 else
291         case 4 in
292                 $ac_cv_sizeof_int) SIZE32="int";;
293                 $ac_cv_sizeof_long) SIZE32="long";;
294                 $ac_cv_sizeof_short) SIZE32="short";;
295         esac
296 fi
297
298 AC_SUBST(SIZE16)
299 AC_SUBST(SIZE32)
300
301 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
302 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
303
304 AC_OUTPUT([Makefile opus.pc opus-uninstalled.pc
305            doc/Makefile doc/Doxyfile])
306
307 AC_MSG_RESULT([
308 ------------------------------------------------------------------------
309   $PACKAGE $VERSION:  Automatic configuration OK.
310   
311     Compiler support:
312
313       C99 var arrays: ................ ${has_var_arrays}
314       C99 lrintf: .................... ${ac_cv_func_lrintf}
315       Alloca: ........................ ${has_alloca}
316     
317     General configuration:
318     
319       Floating point support: ........ ${ac_enable_float}
320       Fast float approximations: ..... ${float_approx}
321       Fixed point debugging: ......... ${ac_enable_fixed_debug}
322       Custom modes: .................. ${ac_enable_custom_modes}
323       Assertion checking: ............ ${ac_enable_assertions}
324       Fuzzing: ....................... ${ac_enable_fuzzing}
325
326       API documentation: ............. ${ac_enable_doc}
327 ------------------------------------------------------------------------
328 ])
329
330 echo "Type \"make; make install\" to compile and install";
331 echo "Type \"make check\" to run the test suite";