354cc3574bd9a803b8ea403d8936471e6e72beaf
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 dnl The package_version file will be automatically synced to the git revision
4 dnl by the update_version script when configured in the repository, but will
5 dnl remain constant in tarball releases unless it is manually edited.
6 m4_define([CURRENT_VERSION],
7           m4_esyscmd([ ./update_version 2>/dev/null || true
8                        if test -e package_version; then
9                            . ./package_version
10                            printf "$PACKAGE_VERSION"
11                        else
12                            printf "unknown"
13                        fi ]))
14
15 AC_INIT([opus],[CURRENT_VERSION],[opus@xiph.org])
16
17 AC_CONFIG_SRCDIR(src/opus_encoder.c)
18 AC_CONFIG_MACRO_DIR([m4])
19
20 dnl enable silent rules on automake 1.11 and later
21 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
22
23 # For libtool.
24 dnl Please update these for releases.
25 OPUS_LT_CURRENT=5
26 OPUS_LT_REVISION=0
27 OPUS_LT_AGE=5
28
29 AC_SUBST(OPUS_LT_CURRENT)
30 AC_SUBST(OPUS_LT_REVISION)
31 AC_SUBST(OPUS_LT_AGE)
32
33 AM_INIT_AUTOMAKE([no-define])
34 AM_MAINTAINER_MODE([enable])
35
36 AC_CANONICAL_HOST
37 AC_MINGW32
38 AM_PROG_LIBTOOL
39 AM_PROG_CC_C_O
40
41 AC_PROG_CC_C99
42 AC_C_CONST
43 AC_C_INLINE
44
45 AM_PROG_AS
46
47 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
48
49 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
50 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
51 #Note: Both this and the test for variable-size arrays below are also
52 #      done by AC_PROG_CC_C99, but not thoroughly enough apparently.
53 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
54   [ac_cv_c_restrict=no
55    # The order here caters to the fact that C++ does not require restrict.
56    for ac_kw in __restrict __restrict__ _Restrict restrict; do
57      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
58       [[typedef int * int_ptr;
59         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
60         return ip[0];
61        }]],
62       [[int s[1];
63         int * $ac_kw t = s;
64         t[0] = 0;
65         return foo(t, (void *)0)]])],
66       [ac_cv_c_restrict=$ac_kw])
67      test "$ac_cv_c_restrict" != no && break
68    done
69   ])
70
71 AH_VERBATIM([restrict],
72 [/* Define to the equivalent of the C99 'restrict' keyword, or to
73    nothing if this is not supported.  Do not define if restrict is
74    supported directly.  */
75 #undef restrict
76 /* Work around a bug in Sun C++: it does not support _Restrict or
77    __restrict__, even though the corresponding Sun C compiler ends up with
78    "#define restrict _Restrict" or "#define restrict __restrict__" in the
79    previous line.  Perhaps some future version of Sun C++ will work with
80    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
81 #if defined __SUNPRO_CC && !defined __RESTRICT
82 # define _Restrict
83 # define __restrict__
84 #endif])
85
86 case $ac_cv_c_restrict in
87    restrict) ;;
88    no) AC_DEFINE([restrict], []) ;;
89    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
90 esac
91
92 AC_MSG_CHECKING(for C99 variable-size arrays)
93 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
94                    [[static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];]])],
95     [ has_var_arrays=yes
96       use_alloca="no (using var arrays)"
97       AC_DEFINE([VAR_ARRAYS], [1], [Use C99 variable-size arrays])
98     ],[
99       has_var_arrays=no
100     ])
101 AC_MSG_RESULT([$has_var_arrays])
102
103 AS_IF([test "$has_var_arrays" = "no"],
104   [
105    AC_CHECK_HEADERS([alloca.h])
106    AC_MSG_CHECKING(for alloca)
107    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alloca.h>]],
108                                       [[int foo=10; int *array = alloca(foo);]])],
109      [ use_alloca=yes;
110        AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
111      ],[
112        use_alloca=no
113      ])
114    AC_MSG_RESULT([$use_alloca])
115   ])
116
117 LT_LIB_M
118
119 AC_ARG_ENABLE([fixed-point],
120     [AS_HELP_STRING([--enable-fixed-point],
121                     [compile without floating point (for machines without a fast enough FPU)])],,
122     [enable_fixed_point=no])
123
124 AS_IF([test "$enable_fixed_point" = "yes"],[
125   enable_float="no"
126   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point (for machines without a fast enough FPU)])
127   PC_BUILD="fixed-point"
128 ],[
129   enable_float="yes";
130   PC_BUILD="floating-point"
131 ])
132
133 AM_CONDITIONAL([FIXED_POINT], [test "$enable_fixed_point" = "yes"])
134
135 AC_ARG_ENABLE([fixed-point-debug],
136     [AS_HELP_STRING([--enable-fixed-point-debug], [debug fixed-point implementation])],,
137     [enable_fixed_point_debug=no])
138
139 AS_IF([test "$enable_fixed_point_debug" = "yes"],[
140   AC_DEFINE([FIXED_DEBUG], [1], [Debug fixed-point implementation])
141 ])
142
143 AC_ARG_ENABLE([float_api],
144     [AS_HELP_STRING([--disable-float-api],
145                     [compile without the floating point API (for machines with no float library)])],,
146     [enable_float_api=yes])
147
148 AM_CONDITIONAL([DISABLE_FLOAT_API], [test "$enable_float_api" = "no"])
149
150 AS_IF([test "$enable_float_api" = "no"],[
151   AC_DEFINE([DISABLE_FLOAT_API], [1], [Do not build the float API])
152 ])
153
154 AC_ARG_ENABLE([custom-modes],
155     [AS_HELP_STRING([--enable-custom-modes], [enable non-Opus modes, e.g. 44.1 kHz & 2^n frames])],,
156     [enable_custom_modes=no])
157
158 AS_IF([test "$enable_custom_modes" = "yes"],[
159   AC_DEFINE([CUSTOM_MODES], [1], [Custom modes])
160   PC_BUILD="$PC_BUILD, custom modes"
161 ])
162
163 AM_CONDITIONAL([CUSTOM_MODES], [test "$enable_custom_modes" = "yes"])
164
165 has_float_approx=no
166 #case "$host_cpu" in
167 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
168 #  has_float_approx=yes
169 #  ;;
170 #esac
171
172 AC_ARG_ENABLE([float-approx],
173     [AS_HELP_STRING([--enable-float-approx], [enable fast approximations for floating point])],
174     [if test "$enable_float_approx" = "yes"; then
175        AC_WARN([Floating point approximations are not supported on all platforms.])
176      fi
177     ],
178     [enable_float_approx=$has_float_approx])
179
180 AS_IF([test "$enable_float_approx" = "yes"],[
181   AC_DEFINE([FLOAT_APPROX], [1], [Float approximations])
182 ])
183
184 AC_ARG_ENABLE([asm],
185     [AS_HELP_STRING([--disable-asm], [Disable assembly optimizations])],,
186     [enable_asm=yes])
187
188 AC_ARG_ENABLE([rtcd],
189     [AS_HELP_STRING([--disable-rtcd], [Disable run-time CPU capabilities detection])],,
190     [enable_rtcd=yes])
191
192 AC_ARG_ENABLE([intrinsics],
193     [AS_HELP_STRING([--enable-intrinsics], [Enable intrinsics optimizations for ARM(float) X86(fixed)])],,
194     [enable_intrinsics=no])
195
196 rtcd_support=no
197 cpu_arm=no
198
199 AS_IF([test x"${enable_asm}" = x"yes"],[
200     inline_optimization="No inline ASM for your platform, please send patches"
201     case $host_cpu in
202       arm*)
203         dnl Currently we only have asm for fixed-point
204         AS_IF([test "$enable_float" != "yes"],[
205             cpu_arm=yes
206             AC_DEFINE([OPUS_ARM_ASM], [],  [Make use of ARM asm optimization])
207             AS_GCC_INLINE_ASSEMBLY(
208                 [inline_optimization="ARM"],
209                 [inline_optimization="disabled"]
210             )
211             AS_ASM_ARM_EDSP([OPUS_ARM_INLINE_EDSP=1],[OPUS_ARM_INLINE_EDSP=0])
212             AS_ASM_ARM_MEDIA([OPUS_ARM_INLINE_MEDIA=1],
213                 [OPUS_ARM_INLINE_MEDIA=0])
214             AS_ASM_ARM_NEON([OPUS_ARM_INLINE_NEON=1],[OPUS_ARM_INLINE_NEON=0])
215             AS_IF([test x"$inline_optimization" = x"ARM"],[
216                 AM_CONDITIONAL([OPUS_ARM_INLINE_ASM],[true])
217                 AC_DEFINE([OPUS_ARM_INLINE_ASM], 1,
218                     [Use generic ARMv4 inline asm optimizations])
219                 AS_IF([test x"$OPUS_ARM_INLINE_EDSP" = x"1"],[
220                     AC_DEFINE([OPUS_ARM_INLINE_EDSP], [1],
221                         [Use ARMv5E inline asm optimizations])
222                     inline_optimization="$inline_optimization (EDSP)"
223                 ])
224                 AS_IF([test x"$OPUS_ARM_INLINE_MEDIA" = x"1"],[
225                     AC_DEFINE([OPUS_ARM_INLINE_MEDIA], [1],
226                         [Use ARMv6 inline asm optimizations])
227                     inline_optimization="$inline_optimization (Media)"
228                 ])
229                 AS_IF([test x"$OPUS_ARM_INLINE_NEON" = x"1"],[
230                     AC_DEFINE([OPUS_ARM_INLINE_NEON], 1,
231                         [Use ARM NEON inline asm optimizations])
232                     inline_optimization="$inline_optimization (NEON)"
233                 ])
234             ])
235             dnl We need Perl to translate RVCT-syntax asm to gas syntax.
236             AC_CHECK_PROG([HAVE_PERL], perl, yes, no)
237             AS_IF([test x"$HAVE_PERL" = x"yes"],[
238                 AM_CONDITIONAL([OPUS_ARM_EXTERNAL_ASM],[true])
239                 asm_optimization="ARM"
240                 AS_IF([test x"$OPUS_ARM_INLINE_EDSP" = x"1"], [
241                     OPUS_ARM_PRESUME_EDSP=1
242                     OPUS_ARM_MAY_HAVE_EDSP=1
243                 ],
244                 [
245                     OPUS_ARM_PRESUME_EDSP=0
246                     OPUS_ARM_MAY_HAVE_EDSP=0
247                 ])
248                 AS_IF([test x"$OPUS_ARM_INLINE_MEDIA" = x"1"], [
249                     OPUS_ARM_PRESUME_MEDIA=1
250                     OPUS_ARM_MAY_HAVE_MEDIA=1
251                 ],
252                 [
253                     OPUS_ARM_PRESUME_MEDIA=0
254                     OPUS_ARM_MAY_HAVE_MEDIA=0
255                 ])
256                 AS_IF([test x"$OPUS_ARM_INLINE_NEON" = x"1"], [
257                     OPUS_ARM_PRESUME_NEON=1
258                     OPUS_ARM_MAY_HAVE_NEON=1
259                 ],
260                 [
261                     OPUS_ARM_PRESUME_NEON=0
262                     OPUS_ARM_MAY_HAVE_NEON=0
263                 ])
264                 AS_IF([test x"$enable_rtcd" = x"yes"],[
265                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_EDSP" != x"1"],[
266                         AC_MSG_NOTICE(
267                           [Trying to force-enable armv5e EDSP instructions...])
268                         AS_ASM_ARM_EDSP_FORCE([OPUS_ARM_MAY_HAVE_EDSP=1])
269                     ])
270                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_MEDIA" != x"1"],[
271                         AC_MSG_NOTICE(
272                           [Trying to force-enable ARMv6 media instructions...])
273                         AS_ASM_ARM_MEDIA_FORCE([OPUS_ARM_MAY_HAVE_MEDIA=1])
274                     ])
275                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON" != x"1"],[
276                         AC_MSG_NOTICE(
277                           [Trying to force-enable NEON instructions...])
278                         AS_ASM_ARM_NEON_FORCE([OPUS_ARM_MAY_HAVE_NEON=1])
279                     ])
280                 ])
281                 rtcd_support=
282                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_EDSP" = x"1"],[
283                     AC_DEFINE(OPUS_ARM_MAY_HAVE_EDSP, 1,
284                         [Define if assembler supports EDSP instructions])
285                     AS_IF([test x"$OPUS_ARM_PRESUME_EDSP" = x"1"],[
286                         AC_DEFINE(OPUS_ARM_PRESUME_EDSP, 1,
287                           [Define if binary requires EDSP instruction support])
288                         asm_optimization="$asm_optimization (EDSP)"
289                     ],
290                         [rtcd_support="$rtcd_support (EDSP)"]
291                     )
292                 ])
293                 AC_SUBST(OPUS_ARM_MAY_HAVE_EDSP)
294                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_MEDIA" = x"1"],[
295                     AC_DEFINE(OPUS_ARM_MAY_HAVE_MEDIA, 1,
296                       [Define if assembler supports ARMv6 media instructions])
297                     AS_IF([test x"$OPUS_ARM_PRESUME_MEDIA" = x"1"],[
298                         AC_DEFINE(OPUS_ARM_PRESUME_MEDIA, 1,
299                           [Define if binary requires ARMv6 media instruction support])
300                         asm_optimization="$asm_optimization (Media)"
301                     ],
302                         [rtcd_support="$rtcd_support (Media)"]
303                     )
304                 ])
305                 AC_SUBST(OPUS_ARM_MAY_HAVE_MEDIA)
306                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON" = x"1"],[
307                     AC_DEFINE(OPUS_ARM_MAY_HAVE_NEON, 1,
308                       [Define if compiler supports NEON instructions])
309                     AS_IF([test x"$OPUS_ARM_PRESUME_NEON" = x"1"], [
310                         AC_DEFINE(OPUS_ARM_PRESUME_NEON, 1,
311                           [Define if binary requires NEON instruction support])
312                         asm_optimization="$asm_optimization (NEON)"
313                     ],
314                         [rtcd_support="$rtcd_support (NEON)"]
315                     )
316                 ])
317                 AC_SUBST(OPUS_ARM_MAY_HAVE_NEON)
318                 dnl Make sure turning on RTCD gets us at least one
319                 dnl instruction set.
320                 AS_IF([test x"$rtcd_support" != x""],
321                     [rtcd_support=ARM"$rtcd_support"],
322                     [rtcd_support="no"]
323                 )
324                 AC_MSG_CHECKING([for apple style tools])
325                 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
326 #ifndef __APPLE__
327 #error 1
328 #endif],[])],
329                     [AC_MSG_RESULT([yes]); ARM2GNU_PARAMS="--apple"],
330                     [AC_MSG_RESULT([no]); ARM2GNU_PARAMS=""])
331                 AC_SUBST(ARM2GNU_PARAMS)
332             ],
333             [
334                 AC_MSG_WARN(
335                   [*** ARM assembly requires perl -- disabling optimizations])
336                 asm_optimization="(missing perl dependency for ARM)"
337             ])
338         ])
339         ;;
340     esac
341 ],[
342    inline_optimization="disabled"
343    asm_optimization="disabled"
344 ])
345
346 AM_CONDITIONAL([OPUS_ARM_INLINE_ASM],
347     [test x"${inline_optimization%% *}" = x"ARM"])
348 AM_CONDITIONAL([OPUS_ARM_EXTERNAL_ASM],
349     [test x"${asm_optimization%% *}" = x"ARM"])
350
351 AM_CONDITIONAL([HAVE_SSE2], [false])
352 AM_CONDITIONAL([HAVE_SSE4_1], [false])
353
354 m4_define([DEFAULT_X86_SSE2_CFLAGS], [-msse2])
355 m4_define([DEFAULT_X86_SSE4_1_CFLAGS], [-msse4.1])
356 m4_define([DEFAULT_ARM_NEON_INTR_CFLAGS], [-mfpu=neon])
357 # With GCC on ARM32 softfp architectures (e.g. Android, or older Ubuntu) you need to specify
358 # -mfloat-abi=softfp for -mfpu=neon to work.  However, on ARM32 hardfp architectures (e.g. newer Ubuntu),
359 # this option will break things.
360
361 # As a heuristic, if host matches arm*eabi* but not arm*hf*, it's probably soft-float.
362 m4_define([DEFAULT_ARM_NEON_SOFTFP_INTR_CFLAGS], [-mfpu=neon -mfloat-abi=softfp])
363
364 AS_CASE([$host],
365         [arm*hf*], [AS_VAR_SET([RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS], "DEFAULT_ARM_NEON_INTR_CFLAGS")],
366         [arm*eabi*], [AS_VAR_SET([RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS], "DEFAULT_ARM_NEON_SOFTFP_INTR_CFLAGS")],
367         [AS_VAR_SET([RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS], "DEFAULT_ARM_NEON_INTR_CFLAGS")])
368
369 AC_ARG_VAR([X86_SSE2_CFLAGS], [C compiler flags to compile SSE2 intrinsics @<:@default=]DEFAULT_X86_SSE2_CFLAGS[@:>@])
370 AC_ARG_VAR([X86_SSE4_1_CFLAGS], [C compiler flags to compile SSE4.1 intrinsics @<:@default=]DEFAULT_X86_SSE4_1_CFLAGS[@:>@])
371 AC_ARG_VAR([ARM_NEON_INTR_CFLAGS], [C compiler flags to compile ARM NEON intrinsics @<:@default=]DEFAULT_ARM_NEON_INTR_CFLAGS / DEFAULT_ARM_NEON_SOFTFP_INTR_CFLAGS[@:>@])
372
373 AS_VAR_SET_IF([X86_SSE2_CFLAGS], [], [AS_VAR_SET([X86_SSE2_CFLAGS], "DEFAULT_X86_SSE2_CFLAGS")])
374 AS_VAR_SET_IF([X86_SSE4_1_CFLAGS], [], [AS_VAR_SET([X86_SSE4_1_CFLAGS], "DEFAULT_X86_SSE4_1_CFLAGS")])
375 AS_VAR_SET_IF([ARM_NEON_INTR_CFLAGS], [], [AS_VAR_SET([ARM_NEON_INTR_CFLAGS], ["$RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS"])])
376
377 AS_IF([test x"$enable_intrinsics" = x"yes"],[
378    intrinsics_support=""
379    AS_CASE([$host_cpu],
380    [arm*],
381    [
382       cpu_arm=yes
383       OPUS_CHECK_INTRINSICS(
384          [ARM Neon],
385          [$ARM_NEON_INTR_CFLAGS],
386          [OPUS_ARM_MAY_HAVE_NEON_INTR],
387          [OPUS_ARM_PRESUME_NEON_INTR],
388          [[#include <arm_neon.h>
389          ]],
390          [[
391             static float32x4_t A0, A1, SUMM;
392             SUMM = vmlaq_f32(SUMM, A0, A1);
393          ]]
394       )
395       AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON_INTR" = x"1" && test x"$OPUS_ARM_PRESUME_NEON_INTR" != x"1"],
396           [
397              OPUS_ARM_NEON_INTR_CFLAGS="$ARM_NEON_INTR_CFLAGS"
398              AC_SUBST([OPUS_ARM_NEON_INTR_CFLAGS])
399           ]
400       )
401
402       #Currently we only have intrinsic optimizations for floating point
403       AS_IF([test x"$enable_float" = x"yes"],
404       [
405          AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON_INTR" = x"1"],
406          [
407             AC_DEFINE([OPUS_ARM_MAY_HAVE_NEON_INTR], 1, [Compiler supports ARMv7 Neon Intrinsics])
408             intrinsics_support="$intrinsics_support (Neon_Intrinsics)"
409
410             AS_IF([test x"enable_rtcd" != x"" && test x"$OPUS_ARM_PRESUME_NEON_INTR" != x"1"],
411                [rtcd_support="$rtcd_support (ARMv7_Neon_Intrinsics)"],[])
412
413             AS_IF([test x"$OPUS_ARM_PRESUME_NEON_INTR" = x"1"],
414                [AC_DEFINE([OPUS_ARM_PRESUME_NEON_INTR], 1, [Define if binary requires NEON intrinsics support])])
415
416                         AS_IF([test x"$rtcd_support" = x""],
417                [rtcd_support=no])
418
419             AS_IF([test x"$intrinsics_support" = x""],
420                [intrinsics_support=no],
421                            [intrinsics_support="arm$intrinsics_support"])
422          ],
423          [
424             AC_MSG_WARN([Compiler does not support ARM intrinsics])
425             intrinsics_support=no
426          ])
427       ], [
428             AC_MSG_WARN([Currently only have ARM intrinsics for float])
429             intrinsics_support=no
430       ])
431    ],
432    [i?86|x86_64],
433    [
434       OPUS_CHECK_INTRINSICS(
435          [SSE2],
436          [$X86_SSE2_CFLAGS],
437          [OPUS_X86_MAY_HAVE_SSE2],
438          [OPUS_X86_PRESUME_SSE2],
439          [[#include <emmintrin.h>
440          ]],
441          [[
442              static __m128i mtest;
443              mtest = _mm_setzero_si128();
444          ]]
445       )
446       AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE2" = x"1" && test x"$OPUS_X86_PRESUME_SSE2" != x"1"],
447           [
448              OPUS_X86_SSE2_CFLAGS="$X86_SSE2_CFLAGS"
449              AC_SUBST([OPUS_X86_SSE2_CFLAGS])
450           ]
451       )
452       OPUS_CHECK_INTRINSICS(
453          [SSE4.1],
454          [$X86_SSE4_1_CFLAGS],
455          [OPUS_X86_MAY_HAVE_SSE4_1],
456          [OPUS_X86_PRESUME_SSE4_1],
457          [[#include <smmintrin.h>
458          ]],
459          [[
460             static __m128i mtest;
461             mtest = _mm_setzero_si128();
462             mtest = _mm_cmpeq_epi64(mtest, mtest);
463          ]]
464       )
465       AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE4_1" = x"1" && test x"$OPUS_X86_PRESUME_SSE4_1" != x"1"],
466           [
467              OPUS_X86_SSE4_1_CFLAGS="$X86_SSE4_1_CFLAGS"
468              AC_SUBST([OPUS_X86_SSE4_1_CFLAGS])
469           ]
470       )
471
472       #Currently we only have intrinsic optimizations for floating point
473       AS_IF([test x"$enable_float" = x"no"],
474       [
475          AS_IF([test x"$rtcd_support" = x"no"], [rtcd_support=""])
476          AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE2" = x"1"],
477          [
478             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE2], 1, [Compiler supports X86 SSE2 Intrinsics])
479             intrinsics_support="$intrinsics_support SSE2"
480
481             AS_IF([test x"$OPUS_X86_PRESUME_SSE2" = x"1"],
482                [AC_DEFINE([OPUS_X86_PRESUME_SSE2], 1, [Define if binary requires SSE2 intrinsics support])],
483                [rtcd_support="$rtcd_support SSE2"])
484          ],
485          [
486             AC_MSG_WARN([Compiler does not support SSE2 intrinsics])
487          ])
488
489          AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE4_1" = x"1"],
490          [
491             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE4_1], 1, [Compiler supports X86 SSE4.1 Intrinsics])
492             intrinsics_support="$intrinsics_support SSE4.1"
493
494             AS_IF([test x"$OPUS_X86_PRESUME_SSE4_1" = x"1"],
495                [AC_DEFINE([OPUS_X86_PRESUME_SSE4_1], 1, [Define if binary requires SSE4.1 intrinsics support])],
496                [rtcd_support="$rtcd_support SSE4.1"])
497          ],
498          [
499             AC_MSG_WARN([Compiler does not support SSE4.1 intrinsics])
500          ])
501          AS_IF([test x"$intrinsics_support" = x""],
502             [intrinsics_support=no],
503             [intrinsics_support="x86$intrinsics_support"]
504          )
505          AS_IF([test x"$rtcd_support" = x""],
506             [rtcd_support=no],
507             [rtcd_support="x86$rtcd_support"],
508         )
509       ], [
510             AC_MSG_WARN([Currently only have X86 intrinsics for fixed-point])
511             intrinsics_support=no
512       ]
513     )
514
515     AS_IF([test x"$enable_rtcd" = x"yes" && test x"$rtcd_support" != x""],[
516             get_cpuid_by_asm="no"
517             AC_MSG_CHECKING([How to get X86 CPU Info])
518             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
519                  #include <stdio.h>
520             ]],[[
521                  unsigned int CPUInfo0;
522                  unsigned int CPUInfo1;
523                  unsigned int CPUInfo2;
524                  unsigned int CPUInfo3;
525                  unsigned int InfoType;
526                  __asm__ __volatile__ (
527                  "cpuid11":
528                  "=a" (CPUInfo0),
529                  "=b" (CPUInfo1),
530                  "=c" (CPUInfo2),
531                  "=d" (CPUInfo3) :
532                  "a" (InfoType), "c" (0)
533                 );
534             ]])],
535             [get_cpuid_by_asm="yes"
536              AC_MSG_RESULT([Inline Assembly])
537                          AC_DEFINE([CPU_INFO_BY_ASM], [1], [Get CPU Info by asm method])],
538              [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
539                  #include <cpuid.h>
540             ]],[[
541                  unsigned int CPUInfo0;
542                  unsigned int CPUInfo1;
543                  unsigned int CPUInfo2;
544                  unsigned int CPUInfo3;
545                  unsigned int InfoType;
546                  __get_cpuid(InfoType, &CPUInfo0, &CPUInfo1, &CPUInfo2, &CPUInfo3);
547             ]])],
548             [AC_MSG_RESULT([C method])
549                          AC_DEFINE([CPU_INFO_BY_C], [1], [Get CPU Info by c method])],
550             [AC_MSG_ERROR([no supported Get CPU Info method, please disable intrinsics])])])])
551    ],
552    [
553       AC_MSG_WARN([No intrinsics support for your architecture])
554       intrinsics_support="no"
555    ])
556 ],
557 [
558    intrinsics_support="no"
559 ])
560
561 AM_CONDITIONAL([CPU_ARM], [test "$cpu_arm" = "yes"])
562 AM_CONDITIONAL([OPUS_ARM_NEON_INTR],
563     [test x"$OPUS_ARM_MAY_HAVE_NEON_INTR" = x"1"])
564 AM_CONDITIONAL([HAVE_SSE2],
565     [test x"$OPUS_X86_MAY_HAVE_SSE2" = x"1"])
566 AM_CONDITIONAL([HAVE_SSE4_1],
567     [test x"$OPUS_X86_MAY_HAVE_SSE4_1" = x"1"])
568
569 AS_IF([test x"$enable_rtcd" = x"yes"],[
570     AS_IF([test x"$rtcd_support" != x"no"],[
571         AC_DEFINE([OPUS_HAVE_RTCD], [1],
572             [Use run-time CPU capabilities detection])
573         OPUS_HAVE_RTCD=1
574         AC_SUBST(OPUS_HAVE_RTCD)
575     ])
576 ],[
577     rtcd_support="disabled"
578 ])
579
580 AC_ARG_ENABLE([assertions],
581     [AS_HELP_STRING([--enable-assertions],[enable additional software error checking])],,
582     [enable_assertions=no])
583
584 AS_IF([test "$enable_assertions" = "yes"], [
585   AC_DEFINE([ENABLE_ASSERTIONS], [1], [Assertions])
586 ])
587
588 AC_ARG_ENABLE([fuzzing],
589     [AS_HELP_STRING([--enable-fuzzing],[causes the encoder to make random decisions])],,
590     [enable_fuzzing=no])
591
592 AS_IF([test "$enable_fuzzing" = "yes"], [
593   AC_DEFINE([FUZZING], [1], [Fuzzing])
594 ])
595
596 AC_ARG_ENABLE([doc],
597     [AS_HELP_STRING([--disable-doc], [Do not build API documentation])],,
598     [enable_doc=yes])
599
600 AS_IF([test "$enable_doc" = "yes"], [
601   AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
602 ],[
603   HAVE_DOXYGEN=no
604 ])
605
606 AM_CONDITIONAL([HAVE_DOXYGEN], [test "$HAVE_DOXYGEN" = "yes"])
607
608 AC_ARG_ENABLE([extra-programs],
609     [AS_HELP_STRING([--disable-extra-programs], [Do not build extra programs (demo and tests)])],,
610     [enable_extra_programs=yes])
611
612 AM_CONDITIONAL([EXTRA_PROGRAMS], [test "$enable_extra_programs" = "yes"])
613
614
615 saved_CFLAGS="$CFLAGS"
616 CFLAGS="$CFLAGS -fvisibility=hidden"
617 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
618 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
619     [ AC_MSG_RESULT([yes]) ],
620     [ AC_MSG_RESULT([no])
621       CFLAGS="$saved_CFLAGS"
622     ])
623
624 CFLAGS="$CFLAGS -W"
625
626 warn_CFLAGS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
627 saved_CFLAGS="$CFLAGS"
628 CFLAGS="$CFLAGS $warn_CFLAGS"
629 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
630 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
631     [ AC_MSG_RESULT([yes]) ],
632     [ AC_MSG_RESULT([no])
633       CFLAGS="$saved_CFLAGS"
634     ])
635
636 saved_LIBS="$LIBS"
637 LIBS="$LIBS $LIBM"
638 AC_CHECK_FUNCS([lrintf])
639 AC_CHECK_FUNCS([lrint])
640 LIBS="$saved_LIBS"
641
642 AC_CHECK_FUNCS([__malloc_hook])
643
644 AC_SUBST([PC_BUILD])
645
646 AC_CONFIG_FILES([
647     Makefile
648     opus.pc
649     opus-uninstalled.pc
650     celt/arm/armopts.s
651     doc/Makefile
652     doc/Doxyfile
653 ])
654 AC_CONFIG_HEADERS([config.h])
655
656 AC_OUTPUT
657
658 AC_MSG_NOTICE([
659 ------------------------------------------------------------------------
660   $PACKAGE_NAME $PACKAGE_VERSION:  Automatic configuration OK.
661
662     Compiler support:
663
664       C99 var arrays: ................ ${has_var_arrays}
665       C99 lrintf: .................... ${ac_cv_func_lrintf}
666       Use alloca: .................... ${use_alloca}
667
668     General configuration:
669
670       Floating point support: ........ ${enable_float}
671       Fast float approximations: ..... ${enable_float_approx}
672       Fixed point debugging: ......... ${enable_fixed_point_debug}
673       Inline Assembly Optimizations: . ${inline_optimization}
674       External Assembly Optimizations: ${asm_optimization}
675       Intrinsics Optimizations.......: ${intrinsics_support}
676       Run-time CPU detection: ........ ${rtcd_support}
677       Custom modes: .................. ${enable_custom_modes}
678       Assertion checking: ............ ${enable_assertions}
679       Fuzzing: ....................... ${enable_fuzzing}
680
681       API documentation: ............. ${enable_doc}
682       Extra programs: ................ ${enable_extra_programs}
683 ------------------------------------------------------------------------
684
685  Type "make; make install" to compile and install
686  Type "make check" to run the test suite
687 ])
688