forgot to init on write
[libopusenc.git] / configure.ac
1 # autoconf source script for generating configure
2
3 dnl The package_version file will be automatically synced to the git revision
4 dnl by the update_version script when configured in the repository, but will
5 dnl remain constant in tarball releases unless it is manually edited.
6 m4_define([CURRENT_VERSION],
7           m4_esyscmd([ ./update_version 2>/dev/null || true
8                        if test -e package_version; then
9                            . ./package_version
10                            printf "$PACKAGE_VERSION"
11                        else
12                            printf "unknown"
13                        fi ]))
14
15 AC_INIT([opusenc],[CURRENT_VERSION],[opus@xiph.org])
16 AC_CONFIG_SRCDIR([src/opusenc.c])
17 AC_CONFIG_MACRO_DIR([m4])
18
19 AC_USE_SYSTEM_EXTENSIONS
20 AC_SYS_LARGEFILE
21
22 AM_INIT_AUTOMAKE([1.11 foreign no-define dist-zip subdir-objects])
23 AM_MAINTAINER_MODE([enable])
24 LT_INIT
25
26 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
27
28 dnl Library versioning for libtool.
29 dnl Please update these for releases.
30 dnl CURRENT, REVISION, AGE
31 dnl - library source changed -> increment REVISION
32 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
33 dnl - interfaces added -> increment AGE
34 dnl - interfaces removed -> AGE = 0
35
36 OP_LT_CURRENT=4
37 OP_LT_REVISION=1
38 OP_LT_AGE=4
39
40 AC_SUBST(OP_LT_CURRENT)
41 AC_SUBST(OP_LT_REVISION)
42 AC_SUBST(OP_LT_AGE)
43
44 CC_CHECK_CFLAGS_APPEND(
45   [-std=c89 -pedantic -Wall -Wextra -Wno-parentheses -Wno-long-long])
46
47 # Platform-specific tweaks
48 case $host in
49   *-mingw*)
50     # -std=c89 causes some warnings under mingw.
51     CC_CHECK_CFLAGS_APPEND([-U__STRICT_ANSI__])
52     # We need WINNT>=0x501 (WindowsXP) for getaddrinfo/freeaddrinfo.
53     # It's okay to define this even when HTTP support is disabled, as it only
54     #  affects header declarations, not linking (unless we actually use some
55     #  XP-only functions).
56     AC_DEFINE_UNQUOTED(_WIN32_WINNT,0x501,
57      [We need at least WindowsXP for getaddrinfo/freeaddrinfo])
58     host_mingw=true
59     ;;
60 esac
61 AM_CONDITIONAL(OP_WIN32, test "$host_mingw" = "true")
62
63 AC_ARG_ENABLE([assertions],
64   AS_HELP_STRING([--enable-assertions], [Enable assertions in code]),,
65   enable_assertions=no)
66
67 AS_IF([test "$enable_assertions" = "yes"], [
68   AC_DEFINE([OP_ENABLE_ASSERTIONS], [1], [Enable assertions in code])
69 ])
70
71 AC_ARG_ENABLE([http],
72   AS_HELP_STRING([--disable-http], [Disable HTTP support]),,
73   enable_http=yes)
74
75 AM_COND_IF(OP_WIN32,
76   AS_IF([test "$enable_http" != "no"],
77     AC_CHECK_HEADER([winsock2.h],,
78       AC_MSG_WARN([HTTP support requires a Winsock socket library.])
79       enable_http=no
80     )
81   ),
82   AS_IF([test "$enable_http" != "no"],
83     AC_CHECK_HEADER([sys/socket.h],,
84       AC_MSG_WARN([HTTP support requires a POSIX socket library.])
85       enable_http=no
86     )
87   )
88 )
89 AC_SEARCH_LIBS(ftime, [compat], , [enable_http=no])
90
91 AS_IF([test "$enable_http" != "no"], [
92    openssl="openssl"
93    AC_DEFINE([OP_ENABLE_HTTP], [1], [Enable HTTP support])
94    PKG_CHECK_MODULES([URL_DEPS], [openssl])
95 ])
96 AM_CONDITIONAL(OP_ENABLE_HTTP, [test "$enable_http" != "no"])
97 AC_SUBST([openssl])
98
99 PKG_CHECK_MODULES([DEPS], [ogg >= 1.3 opus >= 1.0.1])
100
101 AC_ARG_ENABLE([fixed-point],
102   AS_HELP_STRING([--enable-fixed-point], [Enable fixed-point calculation]),,
103   enable_fixed_point=no)
104 AC_ARG_ENABLE([float],
105   AS_HELP_STRING([--disable-float], [Disable floating-point API]),,
106   enable_float=yes)
107
108 AS_IF([test "$enable_float" = "no"],
109   [enable_fixed_point=yes
110    AC_DEFINE([OP_DISABLE_FLOAT_API], [1], [Disable floating-point API])
111   ]
112 )
113
114 AS_IF([test "$enable_fixed_point" = "yes"],
115   [AC_DEFINE([OP_FIXED_POINT], [1], [Enable fixed-point calculation])],
116   [dnl This only has to be tested for if float->fixed conversions are required
117    saved_LIBS="$LIBS"
118    AC_SEARCH_LIBS([lrintf], [m], [
119       AC_DEFINE([OP_HAVE_LRINTF], [1], [Enable use of lrintf function])
120       lrintf_notice="
121     Library for lrintf() ......... ${ac_cv_search_lrintf}"
122    ])
123    LIBS="$saved_LIBS"
124   ]
125 )
126
127 AC_ARG_ENABLE([examples],
128   AS_HELP_STRING([--disable-examples], [Do not build example applications]),,
129   enable_examples=yes)
130 AM_CONDITIONAL([OP_ENABLE_EXAMPLES], [test "$enable_examples" = "yes"])
131
132 AS_CASE(["$ac_cv_search_lrintf"],
133   ["no"],[],
134   ["none required"],[],
135   [lrintf_lib="$ac_cv_search_lrintf"])
136
137 AC_SUBST([lrintf_lib])
138
139 CC_ATTRIBUTE_VISIBILITY([default], [
140   CC_FLAG_VISIBILITY([CFLAGS="${CFLAGS} -fvisibility=hidden"])
141 ])
142
143 dnl Check for doxygen
144 AC_ARG_ENABLE([doc],
145   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),,
146   [enable_doc=yes]
147 )
148
149 AS_IF([test "$enable_doc" = "yes"], [
150   AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
151   AC_CHECK_PROG([HAVE_DOT], [dot], [yes], [no])
152 ],[
153   HAVE_DOXYGEN=no
154 ])
155
156 AM_CONDITIONAL([HAVE_DOXYGEN], [test "$HAVE_DOXYGEN" = "yes"])
157
158 AC_CONFIG_FILES([
159   Makefile
160   opusenc.pc
161   opusenc-uninstalled.pc
162   doc/Doxyfile
163 ])
164 AC_CONFIG_HEADERS([config.h])
165 AC_OUTPUT
166
167 AC_MSG_NOTICE([
168 ------------------------------------------------------------------------
169   $PACKAGE_NAME $PACKAGE_VERSION: Automatic configuration OK.
170
171     Assertions ................... ${enable_assertions}
172
173     HTTP support ................. ${enable_http}
174     Fixed-point .................. ${enable_fixed_point}
175     Floating-point API ........... ${enable_float}${lrintf_notice}
176
177     Hidden visibility ............ ${cc_cv_flag_visibility}
178
179     API code examples ............ ${enable_examples}
180     API documentation ............ ${enable_doc}
181 ------------------------------------------------------------------------
182 ])