Merge branch 'master' into stereo
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(libspeex/speex.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 SPEEX_MAJOR_VERSION=1
8 SPEEX_MINOR_VERSION=1
9 SPEEX_MICRO_VERSION=15
10 SPEEX_EXTRA_VERSION=.2
11 #SPEEX_VERSION=
12 #SPEEX_VERSION=$SPEEX_MAJOR_VERSION.$SPEEX_MINOR_VERSION.$SPEEX_MICRO_VERSION$SPEEX_EXTRA_VERSION
13 SPEEX_VERSION="1.2beta3.2"
14
15 SPEEX_LT_CURRENT=5
16 SPEEX_LT_REVISION=0
17 SPEEX_LT_AGE=4
18
19 AC_SUBST(SPEEX_LT_CURRENT)
20 AC_SUBST(SPEEX_LT_REVISION)
21 AC_SUBST(SPEEX_LT_AGE)
22
23 # For automake.
24 VERSION=$SPEEX_VERSION
25 PACKAGE=speex
26
27 AC_SUBST(SPEEX_VERSION)
28
29 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
30 AM_MAINTAINER_MODE
31
32 AC_CANONICAL_HOST
33 AC_LIBTOOL_WIN32_DLL
34 AM_PROG_LIBTOOL
35
36 AC_C_BIGENDIAN
37 AC_C_CONST
38 AC_C_INLINE
39 AC_C_RESTRICT
40
41
42 AC_MSG_CHECKING(for C99 variable-size arrays)
43 AC_TRY_COMPILE( , [
44 int foo;
45 foo = 10;
46 int array[foo];
47 ],
48 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
49 ],
50 has_var_arrays=no
51 )
52 AC_MSG_RESULT($has_var_arrays)
53
54 AC_CHECK_HEADERS([alloca.h getopt.h])
55 AC_MSG_CHECKING(for alloca)
56 AC_TRY_COMPILE( [
57 #ifdef HAVE_ALLOCA_H
58 # include <alloca.h>
59 #endif
60 #include <stdlib.h>
61 ], [
62 int foo=10;
63 int *array = alloca(foo);
64 ],
65 [
66 has_alloca=yes;
67 if test x$has_var_arrays = "xno" ; then
68 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
69 fi
70 ],
71 has_alloca=no
72 )
73 AC_MSG_RESULT($has_alloca)
74
75 AC_MSG_CHECKING(for SSE in current arch/CFLAGS)
76 AC_LINK_IFELSE([
77 AC_LANG_PROGRAM([[
78 #include <xmmintrin.h>
79 __m128 testfunc(float *a, float *b) {
80   return _mm_add_ps(_mm_loadu_ps(a), _mm_loadu_ps(b));
81 }
82 ]])],
83 [
84 has_sse=yes
85 ],
86 [
87 has_sse=no
88 ]
89 )
90 AC_MSG_RESULT($has_sse)  
91
92 SAVE_CFLAGS="$CFLAGS"
93 CFLAGS="$CFLAGS -fvisibility=hidden"
94 AC_MSG_CHECKING(for ELF visibility)
95 AC_COMPILE_IFELSE([
96 AC_LANG_PROGRAM([[
97 #pragma GCC visibility push(hidden)
98 __attribute__((visibility("default")))
99 int var=10;
100 ]])],
101 [
102 has_visibility=yes
103 AC_DEFINE([EXPORT], [__attribute__((visibility("default")))], [Symbol visibility prefix])
104 ],
105 [
106 has_visibility=no
107 AC_DEFINE([EXPORT], [], [Symbol visibility prefix])
108 CFLAGS="$SAVE_CFLAGS"
109 ]
110 )
111 AC_MSG_RESULT($has_visibility)
112
113
114 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
115
116 XIPH_PATH_OGG([src="src"], [src=""])
117 AC_SUBST(src)
118
119 AC_CHECK_LIB(m, sin)
120
121 # Check for getopt_long; if not found, use included source.
122 AC_CHECK_FUNCS([getopt_long],,
123 [# FreeBSD has a gnugetopt library.
124   AC_CHECK_LIB([gnugetopt],[getopt_long],
125 [AC_DEFINE([HAVE_GETOPT_LONG])],
126 [# Use the GNU replacement.
127 AC_LIBOBJ(getopt)
128 AC_LIBOBJ(getopt1)])])
129
130 AC_CHECK_LIB(winmm, main)
131
132 AC_DEFINE_UNQUOTED(SPEEX_VERSION, "${SPEEX_VERSION}", [Complete version string])
133 AC_DEFINE_UNQUOTED(SPEEX_MAJOR_VERSION, ${SPEEX_MAJOR_VERSION}, [Version major])
134 AC_DEFINE_UNQUOTED(SPEEX_MINOR_VERSION, ${SPEEX_MINOR_VERSION}, [Version minor])
135 AC_DEFINE_UNQUOTED(SPEEX_MICRO_VERSION, ${SPEEX_MICRO_VERSION}, [Version micro])
136 AC_DEFINE_UNQUOTED(SPEEX_EXTRA_VERSION, "${SPEEX_EXTRA_VERSION}", [Version extra])
137
138 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       Enable valgrind extra checks],
139 [if test "$enableval" = yes; then
140   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
141 fi])
142
143 AC_ARG_ENABLE(sse, [  --enable-sse            Enable SSE support], [
144 if test "x$enableval" != xno; then
145 has_sse=yes
146 CFLAGS="$CFLAGS -O3 -msse"
147 else
148 has_sse=no
149 fi
150 ])
151
152 if test "$has_sse" = yes; then
153   AC_DEFINE([_USE_SSE], , [Enable SSE support])
154 fi
155
156 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    Compile as fixed-point],
157 [if test "$enableval" = yes; then
158   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
159 else
160   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
161 fi],
162 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
163
164 AC_ARG_ENABLE(float-api, [  --disable-float-api     Disable the floating-point API],
165 [if test "$enableval" = no; then
166   AC_DEFINE([DISABLE_FLOAT_API], , [Disable all parts of the API that are using floats])
167 fi])
168
169 AC_ARG_ENABLE(vbr, [  --disable-vbr           Disable VBR and VAD from the codec],
170 [if test "$enableval" = no; then
171   AC_DEFINE([DISABLE_VBR], , [Disable VBR and VAD from the codec])
172 fi])
173
174 AC_ARG_ENABLE(arm4-asm, [  --enable-arm4-asm       Make use of ARM4 assembly optimizations],
175 [if test "$enableval" = yes; then
176   AC_DEFINE([ARM4_ASM], , [Make use of ARM4 assembly optimizations])
177 fi])
178
179 AC_ARG_ENABLE(arm5e-asm, [  --enable-arm5e-asm      Make use of ARM5E assembly optimizations],
180 [if test "$enableval" = yes; then
181   AC_DEFINE([ARM5E_ASM], , [Make use of ARM5E assembly optimizations])
182 fi])
183
184 AC_ARG_ENABLE(blackfin-asm, [  --enable-blackfin-asm   Make use of Blackfin assembly optimizations],
185 [if test "$enableval" = yes; then
186   AC_DEFINE([BFIN_ASM], , [Make use of Blackfin assembly optimizations])
187   LDFLAGS="-Wl,-elf2flt=-s100000"
188 fi])
189
190 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
191 [if test "$enableval" = yes; then
192   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
193 fi])
194
195 AC_ARG_ENABLE(ti-c55x, [  --enable-ti-c55x        Enable support for TI C55X DSP],
196 [if test "$enableval" = yes; then
197   has_char16=yes;
198   AC_DEFINE([TI_C55X], , [Enable support for TI C55X DSP])
199 fi])
200
201 AC_CHECK_SIZEOF(short)
202 AC_CHECK_SIZEOF(int)
203 AC_CHECK_SIZEOF(long)
204
205 if test x$has_char16 = "xyes" ; then
206         case 1 in
207                 $ac_cv_sizeof_short) SIZE16="short";;
208                 $ac_cv_sizeof_int) SIZE16="int";;
209         esac
210 else
211         case 2 in
212                 $ac_cv_sizeof_short) SIZE16="short";;
213                 $ac_cv_sizeof_int) SIZE16="int";;
214         esac
215 fi
216
217 if test x$has_char16 = "xyes" ; then
218         case 2 in
219                 $ac_cv_sizeof_int) SIZE32="int";;
220                 $ac_cv_sizeof_long) SIZE32="long";;
221                 $ac_cv_sizeof_short) SIZE32="short";;
222         esac
223 else
224         case 4 in
225                 $ac_cv_sizeof_int) SIZE32="int";;
226                 $ac_cv_sizeof_long) SIZE32="long";;
227                 $ac_cv_sizeof_short) SIZE32="short";;
228         esac
229 fi
230
231 AC_SUBST(SIZE16)
232 AC_SUBST(SIZE32)
233
234 AC_OUTPUT([Makefile libspeex/Makefile src/Makefile doc/Makefile Speex.spec
235            include/Makefile include/speex/Makefile speex.pc speexdsp.pc
236            win32/Makefile win32/libspeex/Makefile win32/speexenc/Makefile
237            win32/speexdec/Makefile symbian/Makefile 
238            win32/VS2003/Makefile
239            win32/VS2003/tests/Makefile
240            win32/VS2003/libspeex/Makefile
241            win32/VS2003/libspeexdsp/Makefile
242            win32/VS2003/speexdec/Makefile
243            win32/VS2003/speexenc/Makefile
244            win32/VS2005/Makefile
245            win32/VS2005/libspeex/Makefile
246            win32/VS2005/speexdec/Makefile
247            win32/VS2005/speexenc/Makefile
248            win32/VS2005/libspeexdsp/Makefile
249            win32/VS2005/tests/Makefile
250            win32/VS2008/libspeexdsp/Makefile
251            win32/VS2008/Makefile
252            win32/VS2008/speexdec/Makefile
253            win32/VS2008/tests/Makefile
254            win32/VS2008/libspeex/Makefile
255            win32/VS2008/speexenc/Makefile
256            include/speex/speex_config_types.h ti/Makefile 
257            ti/speex_C54_test/Makefile ti/speex_C55_test/Makefile
258            ti/speex_C64_test/Makefile ])
259
260 if test "x$src" = "x"; then 
261 echo "**IMPORTANT**"
262 echo "You don't seem to have the development package for libogg (libogg-devel) installed. Only the Speex library (libspeex) will be built (no encoder/decoder executable)"
263 echo "You can download libogg from http://downloads.xiph.org/releases/ogg/"
264 fi
265
266 echo "Type \"make; make install\" to compile and install Speex";