remove references to noglobals stuff from build
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(libspeex/speex.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 SPEEX_MAJOR_VERSION=1
8 SPEEX_MINOR_VERSION=1
9 SPEEX_MICRO_VERSION=6
10 SPEEX_EXTRA_VERSION=
11 #SPEEX_VERSION=1.1.6
12 SPEEX_VERSION=$SPEEX_MAJOR_VERSION.$SPEEX_MINOR_VERSION.$SPEEX_MICRO_VERSION$SPEEX_EXTRA_VERSION
13
14 SPEEX_LT_CURRENT=3
15 SPEEX_LT_REVISION=0
16 SPEEX_LT_AGE=2
17
18 AC_SUBST(SPEEX_LT_CURRENT)
19 AC_SUBST(SPEEX_LT_REVISION)
20 AC_SUBST(SPEEX_LT_AGE)
21
22 # For automake.
23 VERSION=$SPEEX_VERSION
24 PACKAGE=speex
25
26 AC_SUBST(SPEEX_VERSION)
27
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 AM_MAINTAINER_MODE
30
31 AC_CANONICAL_HOST
32 AM_PROG_LIBTOOL
33
34 AC_C_BIGENDIAN
35 AC_C_CONST
36 AC_C_INLINE
37
38 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
39
40 XIPH_PATH_OGG([src="src"], [src=""])
41 AC_SUBST(src)
42
43 AC_CHECK_LIB(m, sin)
44
45 # Check for getopt_long; if not found, use included source.
46 AC_CHECK_FUNCS([getopt_long],,
47 [# FreeBSD has a gnugetopt library.
48   AC_CHECK_LIB([gnugetopt],[getopt_long],
49 [AC_DEFINE([HAVE_GETOPT_LONG])],
50 [# Use the GNU replacement.
51 AC_LIBOBJ(getopt)
52 AC_LIBOBJ(getopt1)])])
53
54 AC_CHECK_LIB(winmm, main)
55
56 AC_DEFINE_UNQUOTED(SPEEX_VERSION, "${SPEEX_VERSION}", [Complete version string])
57 AC_DEFINE_UNQUOTED(SPEEX_MAJOR_VERSION, ${SPEEX_MAJOR_VERSION}, [Version major])
58 AC_DEFINE_UNQUOTED(SPEEX_MINOR_VERSION, ${SPEEX_MINOR_VERSION}, [Version minor])
59 AC_DEFINE_UNQUOTED(SPEEX_MICRO_VERSION, ${SPEEX_MICRO_VERSION}, [Version micro])
60 AC_DEFINE_UNQUOTED(SPEEX_EXTRA_VERSION, "${SPEEX_EXTRA_VERSION}", [Version extra])
61
62 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       enable valgrind extra checks],
63 [if test "$enableval" = yes; then
64   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
65 fi])
66
67 AC_ARG_ENABLE(sse, [  --enable-sse            enable SSE support], [if test "$enableval" = yes; then
68 AC_DEFINE([_USE_SSE], , [Enable SSE support])
69 CFLAGS="$CFLAGS -O3 -msse"
70 fi
71 ])
72
73 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    compile as fixed-point],
74 [if test "$enableval" = yes; then
75   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
76 fi])
77
78 AC_ARG_ENABLE(arm-asm, [  --enable-arm-asm        make use of ARM assembly instructions],
79 [if test "$enableval" = yes; then
80   AC_DEFINE([ARM_ASM], , [Make use of ARM assembly instructions])
81 fi])
82
83 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
84 [if test "$enableval" = yes; then
85   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
86 fi])
87
88 AC_ARG_ENABLE(epic-48k, [  --enable-epic-48k       enable support for Epic 4.8 kbps mode],
89 [if test "$enableval" = yes; then
90   AC_DEFINE([EPIC_48K], , [Enable support for Epic 4.8 kbps mode])
91 fi])
92
93 dnl Output the makefiles and version.h.
94
95 AC_OUTPUT([Makefile libspeex/Makefile src/Makefile doc/Makefile Speex.spec
96            include/Makefile include/speex/Makefile speex.pc
97            win32/Makefile win32/libspeex/Makefile win32/speexenc/Makefile
98            win32/speexdec/Makefile ])
99
100 if test "x$src" = "x"; then 
101 echo "You don't seem to have the development package for libogg (libogg-devel) installed. Only the Speex library (libspeex) will be built (no encoder/decoder executable)"
102 echo "You can download libogg from http://www.vorbis.com/download.psp"
103 fi
104
105 echo "Type \"make; make install\" to compile and install Speex";