Preparing for 1.1.9
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(libspeex/speex.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 SPEEX_MAJOR_VERSION=1
8 SPEEX_MINOR_VERSION=1
9 SPEEX_MICRO_VERSION=9
10 SPEEX_EXTRA_VERSION=
11 #SPEEX_VERSION=1.1.7
12 SPEEX_VERSION=$SPEEX_MAJOR_VERSION.$SPEEX_MINOR_VERSION.$SPEEX_MICRO_VERSION$SPEEX_EXTRA_VERSION
13
14 SPEEX_LT_CURRENT=3
15 SPEEX_LT_REVISION=0
16 SPEEX_LT_AGE=2
17
18 AC_SUBST(SPEEX_LT_CURRENT)
19 AC_SUBST(SPEEX_LT_REVISION)
20 AC_SUBST(SPEEX_LT_AGE)
21
22 # For automake.
23 VERSION=$SPEEX_VERSION
24 PACKAGE=speex
25
26 AC_SUBST(SPEEX_VERSION)
27
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 AM_MAINTAINER_MODE
30
31 AC_CANONICAL_HOST
32 AM_PROG_LIBTOOL
33
34 AC_C_BIGENDIAN
35 AC_C_CONST
36 AC_C_INLINE
37 AC_C_RESTRICT
38
39
40 AC_MSG_CHECKING(for C99 variable-size arrays)
41 AC_TRY_COMPILE( , [
42 int foo=10;
43 int array[foo];
44 ],
45 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
46 ],
47 has_var_arrays=no
48 )
49 AC_MSG_RESULT($has_var_arrays)
50
51 AC_MSG_CHECKING(for alloca)
52 AC_TRY_COMPILE( [#include <alloca.h>], [
53 int foo=10;
54 int *array = alloca(foo);
55 ],
56 [
57 has_alloca=yes;
58 if test x$has_var_arrays = "xno" ; then
59 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
60 fi
61 ],
62 has_alloca=no
63 )
64 AC_MSG_RESULT($has_alloca)
65
66
67 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
68
69 XIPH_PATH_OGG([src="src"], [src=""])
70 AC_SUBST(src)
71
72 AC_CHECK_LIB(m, sin)
73
74 # Check for getopt_long; if not found, use included source.
75 AC_CHECK_FUNCS([getopt_long],,
76 [# FreeBSD has a gnugetopt library.
77   AC_CHECK_LIB([gnugetopt],[getopt_long],
78 [AC_DEFINE([HAVE_GETOPT_LONG])],
79 [# Use the GNU replacement.
80 AC_LIBOBJ(getopt)
81 AC_LIBOBJ(getopt1)])])
82
83 AC_CHECK_LIB(winmm, main)
84
85 AC_DEFINE_UNQUOTED(SPEEX_VERSION, "${SPEEX_VERSION}", [Complete version string])
86 AC_DEFINE_UNQUOTED(SPEEX_MAJOR_VERSION, ${SPEEX_MAJOR_VERSION}, [Version major])
87 AC_DEFINE_UNQUOTED(SPEEX_MINOR_VERSION, ${SPEEX_MINOR_VERSION}, [Version minor])
88 AC_DEFINE_UNQUOTED(SPEEX_MICRO_VERSION, ${SPEEX_MICRO_VERSION}, [Version micro])
89 AC_DEFINE_UNQUOTED(SPEEX_EXTRA_VERSION, "${SPEEX_EXTRA_VERSION}", [Version extra])
90
91 AC_ARG_ENABLE(wideband, [  --disable-wideband      Disable wideband codec],
92 [if test "$enableval" = no; then
93   AC_DEFINE([DISABLE_WIDEBAND], , [Disable wideband codec])
94 fi])
95
96 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       Enable valgrind extra checks],
97 [if test "$enableval" = yes; then
98   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
99 fi])
100
101 AC_ARG_ENABLE(sse, [  --enable-sse            Enable SSE support], [if test "$enableval" = yes; then
102 AC_DEFINE([_USE_SSE], , [Enable SSE support])
103 CFLAGS="$CFLAGS -O3 -msse"
104 fi
105 ])
106
107 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    Compile as fixed-point],
108 [if test "$enableval" = yes; then
109   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
110 fi])
111
112 AC_ARG_ENABLE(arm4-asm, [  --enable-arm4-asm       Make use of ARM4 assembly instructions],
113 [if test "$enableval" = yes; then
114   AC_DEFINE([ARM4_ASM], , [Make use of ARM4 assembly instructions])
115 fi])
116
117 AC_ARG_ENABLE(arm5e-asm, [  --enable-arm5e-asm      Make use of ARM5E assembly instructions],
118 [if test "$enableval" = yes; then
119   AC_DEFINE([ARM5_ASM], , [Make use of ARM5E assembly instructions])
120 fi])
121
122 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
123 [if test "$enableval" = yes; then
124   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
125 fi])
126
127 AC_ARG_ENABLE(epic-48k, [  --enable-epic-48k       Enable support for Epic 4.8 kbps mode],
128 [if test "$enableval" = yes; then
129   AC_DEFINE([EPIC_48K], , [Enable support for Epic 4.8 kbps mode])
130 fi])
131
132 AC_ARG_ENABLE(ti-c55x, [  --enable-ti-c55x        Enable support for TI C55X DSP],
133 [if test "$enableval" = yes; then
134   has_char16=yes;
135   AC_DEFINE([TI_C55X], , [Enable support for TI C55X DSP])
136 fi])
137
138 AC_ARG_ENABLE(16bit-precision, [  --enable-16bit-precision Reduce precision to 16 bits (EXPERIMENTAL)],
139 [if test "$enableval" = yes; then
140   AC_DEFINE([PRECISION16], , [Reduce precision to 16 bits (EXPERIMENTAL)])
141 fi])
142
143 AC_CHECK_SIZEOF(short)
144 AC_CHECK_SIZEOF(int)
145 AC_CHECK_SIZEOF(long)
146 AC_CHECK_SIZEOF(long long)
147
148 if test x$has_char16 = "xyes" ; then
149         case 1 in
150                 $ac_cv_sizeof_short) SIZE16="short";;
151                 $ac_cv_sizeof_int) SIZE16="int";;
152         esac
153 else
154         case 2 in
155                 $ac_cv_sizeof_short) SIZE16="short";;
156                 $ac_cv_sizeof_int) SIZE16="int";;
157         esac
158 fi
159
160 if test x$has_char16 = "xyes" ; then
161         case 2 in
162                 $ac_cv_sizeof_int) SIZE32="int";;
163                 $ac_cv_sizeof_long) SIZE32="long";;
164                 $ac_cv_sizeof_short) SIZE32="short";;
165         esac
166 else
167         case 4 in
168                 $ac_cv_sizeof_int) SIZE32="int";;
169                 $ac_cv_sizeof_long) SIZE32="long";;
170                 $ac_cv_sizeof_short) SIZE32="short";;
171         esac
172 fi
173
174 AC_SUBST(SIZE16)
175 AC_SUBST(SIZE32)
176
177 AC_OUTPUT([Makefile libspeex/Makefile src/Makefile doc/Makefile Speex.spec
178            include/Makefile include/speex/Makefile speex.pc
179            win32/Makefile win32/libspeex/Makefile win32/speexenc/Makefile
180            win32/speexdec/Makefile symbian/Makefile 
181            include/speex/speex_config_types.h ])
182
183 if test "x$src" = "x"; then 
184 echo "**IMPORTANT**"
185 echo "You don't seem to have the development package for libogg (libogg-devel) installed. Only the Speex library (libspeex) will be built (no encoder/decoder executable)"
186 echo "You can download libogg from http://www.vorbis.com/download.psp"
187 fi
188
189 echo "Type \"make; make install\" to compile and install Speex";