Added pkg-config file for libspeexdsp
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(libspeex/speex.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 SPEEX_MAJOR_VERSION=1
8 SPEEX_MINOR_VERSION=1
9 SPEEX_MICRO_VERSION=15
10 SPEEX_EXTRA_VERSION=-git
11 #SPEEX_VERSION=
12 #SPEEX_VERSION=$SPEEX_MAJOR_VERSION.$SPEEX_MINOR_VERSION.$SPEEX_MICRO_VERSION$SPEEX_EXTRA_VERSION
13 SPEEX_VERSION="1.2beta3"
14
15 SPEEX_LT_CURRENT=5
16 SPEEX_LT_REVISION=0
17 SPEEX_LT_AGE=4
18
19 AC_SUBST(SPEEX_LT_CURRENT)
20 AC_SUBST(SPEEX_LT_REVISION)
21 AC_SUBST(SPEEX_LT_AGE)
22
23 # For automake.
24 VERSION=$SPEEX_VERSION
25 PACKAGE=speex
26
27 AC_SUBST(SPEEX_VERSION)
28
29 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
30 AM_MAINTAINER_MODE
31
32 AC_CANONICAL_HOST
33 AM_PROG_LIBTOOL
34
35 AC_C_BIGENDIAN
36 AC_C_CONST
37 AC_C_INLINE
38 AC_C_RESTRICT
39
40
41 AC_MSG_CHECKING(for C99 variable-size arrays)
42 AC_TRY_COMPILE( , [
43 int foo;
44 foo = 10;
45 int array[foo];
46 ],
47 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
48 ],
49 has_var_arrays=no
50 )
51 AC_MSG_RESULT($has_var_arrays)
52
53 AC_CHECK_HEADERS(alloca.h)
54 AC_MSG_CHECKING(for alloca)
55 AC_TRY_COMPILE( [
56 #ifdef HAVE_ALLOCA_H
57 # include <alloca.h>
58 #endif
59 #include <stdlib.h>
60 ], [
61 int foo=10;
62 int *array = alloca(foo);
63 ],
64 [
65 has_alloca=yes;
66 if test x$has_var_arrays = "xno" ; then
67 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
68 fi
69 ],
70 has_alloca=no
71 )
72 AC_MSG_RESULT($has_alloca)
73
74
75 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
76
77 XIPH_PATH_OGG([src="src"], [src=""])
78 AC_SUBST(src)
79
80 AC_CHECK_LIB(m, sin)
81
82 # Check for getopt_long; if not found, use included source.
83 AC_CHECK_FUNCS([getopt_long],,
84 [# FreeBSD has a gnugetopt library.
85   AC_CHECK_LIB([gnugetopt],[getopt_long],
86 [AC_DEFINE([HAVE_GETOPT_LONG])],
87 [# Use the GNU replacement.
88 AC_LIBOBJ(getopt)
89 AC_LIBOBJ(getopt1)])])
90
91 AC_CHECK_LIB(winmm, main)
92
93 AC_DEFINE_UNQUOTED(SPEEX_VERSION, "${SPEEX_VERSION}", [Complete version string])
94 AC_DEFINE_UNQUOTED(SPEEX_MAJOR_VERSION, ${SPEEX_MAJOR_VERSION}, [Version major])
95 AC_DEFINE_UNQUOTED(SPEEX_MINOR_VERSION, ${SPEEX_MINOR_VERSION}, [Version minor])
96 AC_DEFINE_UNQUOTED(SPEEX_MICRO_VERSION, ${SPEEX_MICRO_VERSION}, [Version micro])
97 AC_DEFINE_UNQUOTED(SPEEX_EXTRA_VERSION, "${SPEEX_EXTRA_VERSION}", [Version extra])
98
99 AC_ARG_ENABLE(wideband, [  --disable-wideband      Disable wideband codec],
100 [if test "$enableval" = no; then
101   AC_DEFINE([DISABLE_WIDEBAND], , [Disable wideband codec])
102 fi])
103
104 AC_ARG_ENABLE(vorbis-psy, [  --enable-vorbis-psy       Enable Vorbis-style psychoacoustics (EXPERIMENTAL)],
105 [if test "$enableval" = yes; then
106   AC_DEFINE([VORBIS_PSYCHO], , [Enable Vorbis-style psychoacoustics (EXPERIMENTAL)])
107 fi])
108
109 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       Enable valgrind extra checks],
110 [if test "$enableval" = yes; then
111   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
112 fi])
113
114 AC_ARG_ENABLE(sse, [  --enable-sse            Enable SSE support], [if test "$enableval" = yes; then
115 AC_DEFINE([_USE_SSE], , [Enable SSE support])
116 CFLAGS="$CFLAGS -O3 -msse"
117 fi
118 ])
119
120 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    Compile as fixed-point],
121 [if test "$enableval" = yes; then
122   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
123 fi])
124
125 AC_ARG_ENABLE(arm4-asm, [  --enable-arm4-asm       Make use of ARM4 assembly optimizations],
126 [if test "$enableval" = yes; then
127   AC_DEFINE([ARM4_ASM], , [Make use of ARM4 assembly optimizations])
128 fi])
129
130 AC_ARG_ENABLE(arm5e-asm, [  --enable-arm5e-asm      Make use of ARM5E assembly optimizations],
131 [if test "$enableval" = yes; then
132   AC_DEFINE([ARM5E_ASM], , [Make use of ARM5E assembly optimizations])
133 fi])
134
135 AC_ARG_ENABLE(blackfin-asm, [  --enable-blackfin-asm      Make use of Blackfin assembly optimizations],
136 [if test "$enableval" = yes; then
137   AC_DEFINE([BFIN_ASM], , [Make use of Blackfin assembly optimizations])
138   LDFLAGS="-Wl,-elf2flt=-s100000"
139 fi])
140
141 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
142 [if test "$enableval" = yes; then
143   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
144 fi])
145
146 AC_ARG_ENABLE(epic-48k, [  --enable-epic-48k       Enable support for Epic 4.8 kbps mode],
147 [if test "$enableval" = yes; then
148   AC_DEFINE([EPIC_48K], , [Enable support for Epic 4.8 kbps mode])
149 fi])
150
151 AC_ARG_ENABLE(ti-c55x, [  --enable-ti-c55x        Enable support for TI C55X DSP],
152 [if test "$enableval" = yes; then
153   has_char16=yes;
154   AC_DEFINE([TI_C55X], , [Enable support for TI C55X DSP])
155 fi])
156
157 AC_ARG_ENABLE(16bit-precision, [  --enable-16bit-precision Reduce precision to 16 bits (EXPERIMENTAL)],
158 [if test "$enableval" = yes; then
159   AC_DEFINE([PRECISION16], , [Reduce precision to 16 bits (EXPERIMENTAL)])
160 fi])
161
162 AC_CHECK_SIZEOF(short)
163 AC_CHECK_SIZEOF(int)
164 AC_CHECK_SIZEOF(long)
165
166 if test x$has_char16 = "xyes" ; then
167         case 1 in
168                 $ac_cv_sizeof_short) SIZE16="short";;
169                 $ac_cv_sizeof_int) SIZE16="int";;
170         esac
171 else
172         case 2 in
173                 $ac_cv_sizeof_short) SIZE16="short";;
174                 $ac_cv_sizeof_int) SIZE16="int";;
175         esac
176 fi
177
178 if test x$has_char16 = "xyes" ; then
179         case 2 in
180                 $ac_cv_sizeof_int) SIZE32="int";;
181                 $ac_cv_sizeof_long) SIZE32="long";;
182                 $ac_cv_sizeof_short) SIZE32="short";;
183         esac
184 else
185         case 4 in
186                 $ac_cv_sizeof_int) SIZE32="int";;
187                 $ac_cv_sizeof_long) SIZE32="long";;
188                 $ac_cv_sizeof_short) SIZE32="short";;
189         esac
190 fi
191
192 AC_SUBST(SIZE16)
193 AC_SUBST(SIZE32)
194
195 AC_OUTPUT([Makefile libspeex/Makefile src/Makefile doc/Makefile Speex.spec
196            include/Makefile include/speex/Makefile speex.pc speexdsp.pc
197            win32/Makefile win32/libspeex/Makefile win32/speexenc/Makefile
198            win32/speexdec/Makefile symbian/Makefile 
199            win32/VS2003/Makefile
200            win32/VS2003/tests/Makefile
201            win32/VS2003/libspeex/Makefile
202            win32/VS2003/speexdec/Makefile
203            win32/VS2003/speexenc/Makefile
204            win32/VS2005/Makefile
205            win32/VS2005/libspeex/Makefile
206            win32/VS2005/speexdec/Makefile
207            win32/VS2005/speexenc/Makefile
208            include/speex/speex_config_types.h ti/Makefile 
209            ti/speex_C54_test/Makefile ti/speex_C55_test/Makefile
210            ti/speex_C64_test/Makefile ])
211
212 if test "x$src" = "x"; then 
213 echo "**IMPORTANT**"
214 echo "You don't seem to have the development package for libogg (libogg-devel) installed. Only the Speex library (libspeex) will be built (no encoder/decoder executable)"
215 echo "You can download libogg from http://downloads.xiph.org/releases/ogg/"
216 fi
217
218 echo "Type \"make; make install\" to compile and install Speex";