f26955321e3b7c27d0cfa344a66436ca0546dfee
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT([speexdsp],[1.2rc1],[speex-dev@xiph.org])
4
5 AC_CONFIG_SRCDIR([libspeexdsp/preprocess.c])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 dnl enable silent rules on automake 1.11 and later
9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
10
11
12 SPEEXDSP_LT_CURRENT=6
13 SPEEXDSP_LT_REVISION=0
14 SPEEXDSP_LT_AGE=5
15
16
17 AC_SUBST(SPEEXDSP_LT_CURRENT)
18 AC_SUBST(SPEEXDSP_LT_REVISION)
19 AC_SUBST(SPEEXDSP_LT_AGE)
20
21 AM_INIT_AUTOMAKE([foreign no-define])
22 AM_MAINTAINER_MODE([enable])
23
24 AC_CANONICAL_HOST
25 AC_LIBTOOL_WIN32_DLL
26 AM_PROG_LIBTOOL
27
28 AC_C_BIGENDIAN
29 AC_C_CONST
30 AC_C_INLINE
31 AC_C_RESTRICT
32
33
34 AC_MSG_CHECKING(for C99 variable-size arrays)
35 AC_TRY_COMPILE( , [
36 int foo;
37 foo = 10;
38 int array[foo];
39 ],
40 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
41 ],
42 has_var_arrays=no
43 )
44 AC_MSG_RESULT($has_var_arrays)
45
46 AC_CHECK_HEADERS([alloca.h getopt.h])
47 AC_MSG_CHECKING(for alloca)
48 AC_TRY_COMPILE( [
49 #ifdef HAVE_ALLOCA_H
50 # include <alloca.h>
51 #endif
52 #include <stdlib.h>
53 ], [
54 int foo=10;
55 int *array = alloca(foo);
56 ],
57 [
58 has_alloca=yes;
59 if test x$has_var_arrays = "xno" ; then
60 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
61 fi
62 ],
63 has_alloca=no
64 )
65 AC_MSG_RESULT($has_alloca)
66
67 AC_MSG_CHECKING(for SSE in current arch/CFLAGS)
68 AC_LINK_IFELSE([
69 AC_LANG_PROGRAM([[
70 #include <xmmintrin.h>
71 __m128 testfunc(float *a, float *b) {
72   return _mm_add_ps(_mm_loadu_ps(a), _mm_loadu_ps(b));
73 }
74 ]])],
75 [
76 has_sse=yes
77 ],
78 [
79 has_sse=no
80 ]
81 )
82 AC_MSG_RESULT($has_sse)  
83
84 AC_MSG_CHECKING(for NEON in current arch/CFLAGS)
85 AC_LINK_IFELSE([
86 AC_LANG_PROGRAM([[
87 #include <arm_neon.h>
88 int32x4_t testfunc(int16_t *a, int16_t *b) {
89       return vmull_s16(vld1_s16(a), vld1_s16(b));
90 }
91 ]])],
92 [
93 has_neon=yes
94 ],
95 [
96 has_neon=no
97 ]
98 )
99 AC_MSG_RESULT($has_neon)
100
101 SAVE_CFLAGS="$CFLAGS"
102 CFLAGS="$CFLAGS -fvisibility=hidden"
103 AC_MSG_CHECKING(for ELF visibility)
104 AC_COMPILE_IFELSE([
105 AC_LANG_PROGRAM([[
106 #pragma GCC visibility push(hidden)
107 __attribute__((visibility("default")))
108 int var=10;
109 ]])],
110 [
111 has_visibility=yes
112 AC_DEFINE([EXPORT], [__attribute__((visibility("default")))], [Symbol visibility prefix])
113 ],
114 [
115 has_visibility=no
116 AC_DEFINE([EXPORT], [], [Symbol visibility prefix])
117 CFLAGS="$SAVE_CFLAGS"
118 ]
119 )
120 AC_MSG_RESULT($has_visibility)
121
122 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
123
124 AC_SUBST(src)
125
126 LT_LIB_M
127
128
129 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       Enable valgrind extra checks],
130 [if test "$enableval" = yes; then
131   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
132 fi])
133
134 AC_ARG_ENABLE(sse, [  --enable-sse            Enable SSE support], [
135 if test "x$enableval" != xno; then
136 has_sse=yes
137 CFLAGS="$CFLAGS -O3 -msse"
138 else
139 has_sse=no
140 fi
141 ])
142
143 AC_ARG_ENABLE(neon, [  --enable-neon           Enable NEON support], [
144 if test "x$enableval" != xno; then
145 has_neon=yes
146 CFLAGS="$CFLAGS -O3 -march=armv7-a -mfpu=neon"
147 else
148 has_neon=no
149 fi
150 ])
151
152
153 FFT=smallft
154
155 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    Compile as fixed-point],
156 [if test "$enableval" = yes; then
157   FFT=kiss
158   has_sse=no
159   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
160 else
161   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
162 fi],
163 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
164
165 if test "$has_sse" = yes; then
166   AC_DEFINE([_USE_SSE], , [Enable SSE support])
167 fi
168
169 if test "$has_neon" = yes; then
170   AC_DEFINE([_USE_NEON], , [Enable NEON support])
171 fi
172
173 AC_ARG_ENABLE(float-api, [  --disable-float-api     Disable the floating-point API],
174 [if test "$enableval" = no; then
175   AC_DEFINE([DISABLE_FLOAT_API], , [Disable all parts of the API that are using floats])
176 fi])
177
178 AC_ARG_ENABLE(arm4-asm, [  --enable-arm4-asm       Make use of ARM4 assembly optimizations],
179 [if test "$enableval" = yes; then
180   AC_DEFINE([ARM4_ASM], , [Make use of ARM4 assembly optimizations])
181 fi])
182
183 AC_ARG_ENABLE(arm5e-asm, [  --enable-arm5e-asm      Make use of ARM5E assembly optimizations],
184 [if test "$enableval" = yes; then
185   AC_DEFINE([ARM5E_ASM], , [Make use of ARM5E assembly optimizations])
186 fi])
187
188 AC_ARG_ENABLE(blackfin-asm, [  --enable-blackfin-asm   Make use of Blackfin assembly optimizations],
189 [if test "$enableval" = yes; then
190   AC_DEFINE([BFIN_ASM], , [Make use of Blackfin assembly optimizations])
191 fi])
192 case $host_os in
193   uclinux) LDFLAGS="-Wl,-elf2flt=-s100000 $LDFLAGS";;
194 esac
195
196 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
197 [if test "$enableval" = yes; then
198   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
199 fi])
200
201 AC_ARG_ENABLE(resample-full-sinc-table, [  --enable-resample-full-sinc-table Resample full SINC table (no interpolation)],
202 [if test "$enableval" = yes; then
203   AC_DEFINE([RESAMPLE_FULL_SINC_TABLE], , [Resample with full SINC table (no interpolation)])
204 fi])
205
206 AC_ARG_ENABLE(ti-c55x, [  --enable-ti-c55x        Enable support for TI C55X DSP],
207 [if test "$enableval" = yes; then
208   has_char16=yes;
209   AC_DEFINE([TI_C55X], , [Enable support for TI C55X DSP])
210 fi])
211
212 AC_ARG_WITH([fft], [AS_HELP_STRING([--with-fft=choice],[use an alternate FFT implementation. The available choices are
213 kiss (default fixed point), smallft (default floating point), gpl-fftw3 and proprietary-intel-mkl])],
214 [FFT=$withval]
215 )
216
217 FFT_PKGCONFIG=
218 AS_CASE([$FFT],
219  [kiss], [
220   AC_DEFINE([USE_KISS_FFT], [], [Use KISS Fast Fourier Transform])
221  ],
222  [smallft], [
223   AC_DEFINE([USE_SMALLFT], [], [Use FFT from OggVorbis])
224  ],
225  [gpl-fftw3], [
226   AC_DEFINE([USE_GPL_FFTW3], [], [Use FFTW3 for FFT])
227   PKG_CHECK_MODULES([FFT], [fftw3f])
228  ],
229  [proprietary-intel-mkl], [
230   AC_DEFINE([USE_INTEL_MKL], [], [Use Intel Math Kernel Library for FFT])
231   AC_MSG_CHECKING(for valid MKL)
232   AC_LINK_IFELSE([
233    AC_LANG_PROGRAM([[
234 #include <mkl.h>
235 void func() {
236   DFTI_DESCRIPTOR_HANDLE h;
237   MKL_LONG result=DftiCreateDescriptor(&h, DFTI_SINGLE, DFTI_REAL, 0);
238 }]])],
239    [AC_MSG_RESULT(yes)],
240    [AC_MSG_FAILURE([Failed to compile MKL test program. Make sure you set CFLAGS to include the include directory and set LDFLAGS to include the library directory and all necesarry libraries.])]
241   )
242  ],
243  [AC_MSG_FAILURE([Unknown FFT $FFT specified for --with-fft])]
244 )
245 AM_CONDITIONAL(BUILD_KISS_FFT, [test "$FFT" = "kiss"])
246 AM_CONDITIONAL(BUILD_SMALLFT, [test "$FFT" = "smallft"])
247 AC_SUBST(FFT_PKGCONFIG)
248
249
250 AC_CHECK_SIZEOF([int16_t])
251 AC_CHECK_SIZEOF([uint16_t])
252 AC_CHECK_SIZEOF([u_int16_t])
253 AC_CHECK_SIZEOF([int32_t])
254 AC_CHECK_SIZEOF([uint32_t])
255 AC_CHECK_SIZEOF([u_int32_t])
256 AC_CHECK_SIZEOF([short])
257 AC_CHECK_SIZEOF([int])
258 AC_CHECK_SIZEOF([long])
259
260 AS_IF([test "$has_char16" = "yes"],
261   [
262    SIZEOF16=1
263    SIZEOF32=2
264   ],[
265    SIZEOF16=2
266    SIZEOF32=4
267   ])
268
269 case $SIZEOF16 in
270     $ac_cv_sizeof_int16_t) SIZE16="int16_t";;
271     $ac_cv_sizeof_short) SIZE16="short";;
272     $ac_cv_sizeof_int) SIZE16="int";;
273 esac
274
275 case $SIZEOF16 in
276     $ac_cv_sizeof_uint16_t) USIZE16="uint16_t";;
277     $ac_cv_sizeof_u_int16_t) USIZE16="u_int16_t";;
278     $ac_cv_sizeof_short) USIZE16="unsigned short";;
279     $ac_cv_sizeof_int) USIZE16="unsigned int";;
280 esac
281
282 case $SIZEOF32 in
283     $ac_cv_sizeof_int32_t) SIZE32="int32_t";;
284     $ac_cv_sizeof_int) SIZE32="int";;
285     $ac_cv_sizeof_long) SIZE32="long";;
286     $ac_cv_sizeof_short) SIZE32="short";;
287 esac
288
289 case $SIZEOF32 in
290     $ac_cv_sizeof_uint32_t) USIZE32="uint32_t";;
291     $ac_cv_sizeof_u_int32_t) USIZE32="u_int32_t";;
292     $ac_cv_sizeof_short) USIZE32="unsigned short";;
293     $ac_cv_sizeof_int) USIZE32="unsigned int";;
294     $ac_cv_sizeof_long) USIZE32="unsigned long";;
295 esac
296
297 AS_IF([test -z "$SIZE16"],[AC_MSG_ERROR([No 16 bit type found on this platform!])])
298 AS_IF([test -z "$SIZE32"],[AC_MSG_ERROR([No 32 bit type found on this platform!])])
299 AS_IF([test -z "$USIZE16"],[AC_MSG_ERROR([No unsigned 16 bit type found on this platform!])])
300 AS_IF([test -z "$USIZE32"],[AC_MSG_ERROR([No unsigned 32 bit type found on this platform!])])
301
302 AC_SUBST([SIZE16])
303 AC_SUBST([USIZE16])
304 AC_SUBST([SIZE32])
305 AC_SUBST([USIZE32])
306
307 AC_CONFIG_FILES([
308            Makefile libspeexdsp/Makefile doc/Makefile SpeexDSP.spec
309            include/Makefile include/speex/Makefile speexdsp.pc
310            win32/Makefile win32/libspeexdsp/Makefile
311            symbian/Makefile 
312
313            win32/VS2003/Makefile
314            win32/VS2003/libspeexdsp/Makefile
315            win32/VS2003/tests/Makefile
316
317            win32/VS2005/Makefile
318            win32/VS2005/libspeexdsp/Makefile
319            win32/VS2005/tests/Makefile
320
321            win32/VS2008/Makefile
322            win32/VS2008/libspeexdsp/Makefile
323            win32/VS2008/tests/Makefile
324            include/speex/speexdsp_config_types.h ti/Makefile 
325            ti/speex_C54_test/Makefile ti/speex_C55_test/Makefile
326            ti/speex_C64_test/Makefile ])
327
328 AC_CONFIG_HEADERS([config.h])
329
330 AC_OUTPUT
331
332 echo "Type \"make; make install\" to compile and install Speex";