Prefer the stdint types if available
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT([speexdsp],[1.2rc1],[speex-dev@xiph.org])
4
5 AC_CONFIG_SRCDIR([libspeexdsp/preprocess.c])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 dnl enable silent rules on automake 1.11 and later
9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
10
11
12 SPEEXDSP_LT_CURRENT=6
13 SPEEXDSP_LT_REVISION=0
14 SPEEXDSP_LT_AGE=5
15
16
17 AC_SUBST(SPEEXDSP_LT_CURRENT)
18 AC_SUBST(SPEEXDSP_LT_REVISION)
19 AC_SUBST(SPEEXDSP_LT_AGE)
20
21 AM_INIT_AUTOMAKE([foreign no-define])
22 AM_MAINTAINER_MODE([enable])
23
24 AC_CANONICAL_HOST
25 AC_LIBTOOL_WIN32_DLL
26 AM_PROG_LIBTOOL
27
28 AC_C_BIGENDIAN
29 AC_C_CONST
30 AC_C_INLINE
31 AC_C_RESTRICT
32
33
34 AC_MSG_CHECKING(for C99 variable-size arrays)
35 AC_TRY_COMPILE( , [
36 int foo;
37 foo = 10;
38 int array[foo];
39 ],
40 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
41 ],
42 has_var_arrays=no
43 )
44 AC_MSG_RESULT($has_var_arrays)
45
46 AC_CHECK_HEADERS([alloca.h getopt.h])
47 AC_MSG_CHECKING(for alloca)
48 AC_TRY_COMPILE( [
49 #ifdef HAVE_ALLOCA_H
50 # include <alloca.h>
51 #endif
52 #include <stdlib.h>
53 ], [
54 int foo=10;
55 int *array = alloca(foo);
56 ],
57 [
58 has_alloca=yes;
59 if test x$has_var_arrays = "xno" ; then
60 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
61 fi
62 ],
63 has_alloca=no
64 )
65 AC_MSG_RESULT($has_alloca)
66
67 AC_MSG_CHECKING(for SSE in current arch/CFLAGS)
68 AC_LINK_IFELSE([
69 AC_LANG_PROGRAM([[
70 #include <xmmintrin.h>
71 __m128 testfunc(float *a, float *b) {
72   return _mm_add_ps(_mm_loadu_ps(a), _mm_loadu_ps(b));
73 }
74 ]])],
75 [
76 has_sse=yes
77 ],
78 [
79 has_sse=no
80 ]
81 )
82 AC_MSG_RESULT($has_sse)  
83
84 SAVE_CFLAGS="$CFLAGS"
85 CFLAGS="$CFLAGS -fvisibility=hidden"
86 AC_MSG_CHECKING(for ELF visibility)
87 AC_COMPILE_IFELSE([
88 AC_LANG_PROGRAM([[
89 #pragma GCC visibility push(hidden)
90 __attribute__((visibility("default")))
91 int var=10;
92 ]])],
93 [
94 has_visibility=yes
95 AC_DEFINE([EXPORT], [__attribute__((visibility("default")))], [Symbol visibility prefix])
96 ],
97 [
98 has_visibility=no
99 AC_DEFINE([EXPORT], [], [Symbol visibility prefix])
100 CFLAGS="$SAVE_CFLAGS"
101 ]
102 )
103 AC_MSG_RESULT($has_visibility)
104
105 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
106
107 AC_SUBST(src)
108
109 AC_CHECK_LIB(m, sin)
110
111
112 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       Enable valgrind extra checks],
113 [if test "$enableval" = yes; then
114   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
115 fi])
116
117 AC_ARG_ENABLE(sse, [  --enable-sse            Enable SSE support], [
118 if test "x$enableval" != xno; then
119 has_sse=yes
120 CFLAGS="$CFLAGS -O3 -msse"
121 else
122 has_sse=no
123 fi
124 ])
125
126
127 FFT=smallft
128
129 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    Compile as fixed-point],
130 [if test "$enableval" = yes; then
131   FFT=kiss
132   has_sse=no
133   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
134 else
135   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
136 fi],
137 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
138
139 if test "$has_sse" = yes; then
140   AC_DEFINE([_USE_SSE], , [Enable SSE support])
141 fi
142
143 AC_ARG_ENABLE(float-api, [  --disable-float-api     Disable the floating-point API],
144 [if test "$enableval" = no; then
145   AC_DEFINE([DISABLE_FLOAT_API], , [Disable all parts of the API that are using floats])
146 fi])
147
148 AC_ARG_ENABLE(arm4-asm, [  --enable-arm4-asm       Make use of ARM4 assembly optimizations],
149 [if test "$enableval" = yes; then
150   AC_DEFINE([ARM4_ASM], , [Make use of ARM4 assembly optimizations])
151 fi])
152
153 AC_ARG_ENABLE(arm5e-asm, [  --enable-arm5e-asm      Make use of ARM5E assembly optimizations],
154 [if test "$enableval" = yes; then
155   AC_DEFINE([ARM5E_ASM], , [Make use of ARM5E assembly optimizations])
156 fi])
157
158 AC_ARG_ENABLE(blackfin-asm, [  --enable-blackfin-asm   Make use of Blackfin assembly optimizations],
159 [if test "$enableval" = yes; then
160   AC_DEFINE([BFIN_ASM], , [Make use of Blackfin assembly optimizations])
161 fi])
162 case $host_os in
163   uclinux) LDFLAGS="-Wl,-elf2flt=-s100000 $LDFLAGS";;
164 esac
165
166 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
167 [if test "$enableval" = yes; then
168   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
169 fi])
170
171 AC_ARG_ENABLE(ti-c55x, [  --enable-ti-c55x        Enable support for TI C55X DSP],
172 [if test "$enableval" = yes; then
173   has_char16=yes;
174   AC_DEFINE([TI_C55X], , [Enable support for TI C55X DSP])
175 fi])
176
177 AC_ARG_WITH([fft], [AS_HELP_STRING([--with-fft=choice],[use an alternate FFT implementation. The available choices are
178 kiss (default fixed point), smallft (default floating point), gpl-fftw3 and proprietary-intel-mkl])],
179 [FFT=$withval]
180 )
181
182 FFT_PKGCONFIG=
183 AS_CASE([$FFT],
184  [kiss], [
185   AC_DEFINE([USE_KISS_FFT], [], [Use KISS Fast Fourier Transform])
186  ],
187  [smallft], [
188   AC_DEFINE([USE_SMALLFT], [], [Use FFT from OggVorbis])
189  ],
190  [gpl-fftw3], [
191   AC_DEFINE([USE_GPL_FFTW3], [], [Use FFTW3 for FFT])
192   PKG_CHECK_MODULES(FFT, fftw3f)
193  ],
194  [proprietary-intel-mkl], [
195   AC_DEFINE([USE_INTEL_MKL], [], [Use Intel Math Kernel Library for FFT])
196   AC_MSG_CHECKING(for valid MKL)
197   AC_LINK_IFELSE([
198    AC_LANG_PROGRAM([[
199 #include <mkl.h>
200 void func() {
201   DFTI_DESCRIPTOR_HANDLE h;
202   MKL_LONG result=DftiCreateDescriptor(&h, DFTI_SINGLE, DFTI_REAL, 0);
203 }]])],
204    [AC_MSG_RESULT(yes)],
205    [AC_MSG_FAILURE([Failed to compile MKL test program. Make sure you set CFLAGS to include the include directory and set LDFLAGS to include the library directory and all necesarry libraries.])]
206   )
207  ],
208  [AC_MSG_FAILURE([Unknown FFT $FFT specified for --with-fft])]
209 )
210 AM_CONDITIONAL(BUILD_KISS_FFT, [test "$FFT" = "kiss"])
211 AM_CONDITIONAL(BUILD_SMALLFT, [test "$FFT" = "smallft"])
212 AC_SUBST(FFT_PKGCONFIG)
213
214
215 AC_CHECK_SIZEOF([int16_t])
216 AC_CHECK_SIZEOF([uint16_t])
217 AC_CHECK_SIZEOF([u_int16_t])
218 AC_CHECK_SIZEOF([int32_t])
219 AC_CHECK_SIZEOF([uint32_t])
220 AC_CHECK_SIZEOF([u_int32_t])
221 AC_CHECK_SIZEOF([short])
222 AC_CHECK_SIZEOF([int])
223 AC_CHECK_SIZEOF([long])
224
225 AS_IF([test "$has_char16" = "yes"],
226   [
227    SIZEOF16=1
228    SIZEOF32=2
229   ],[
230    SIZEOF16=2
231    SIZEOF32=4
232   ])
233
234 case $SIZEOF16 in
235     $ac_cv_sizeof_int16_t) SIZE16="int16_t";;
236     $ac_cv_sizeof_short) SIZE16="short";;
237     $ac_cv_sizeof_int) SIZE16="int";;
238 esac
239
240 case $SIZEOF16 in
241     $ac_cv_sizeof_uint16_t) USIZE16="uint16_t";;
242     $ac_cv_sizeof_u_int16_t) USIZE16="u_int16_t";;
243     $ac_cv_sizeof_short) USIZE16="unsigned short";;
244     $ac_cv_sizeof_int) USIZE16="unsigned int";;
245 esac
246
247 case $SIZEOF32 in
248     $ac_cv_sizeof_int32_t) SIZE32="int32_t";;
249     $ac_cv_sizeof_int) SIZE32="int";;
250     $ac_cv_sizeof_long) SIZE32="long";;
251     $ac_cv_sizeof_short) SIZE32="short";;
252 esac
253
254 case $SIZEOF32 in
255     $ac_cv_sizeof_uint32_t) USIZE32="uint32_t";;
256     $ac_cv_sizeof_u_int32_t) USIZE32="u_int32_t";;
257     $ac_cv_sizeof_short) USIZE32="unsigned short";;
258     $ac_cv_sizeof_int) USIZE32="unsigned int";;
259     $ac_cv_sizeof_long) USIZE32="unsigned long";;
260 esac
261
262 AS_IF([test -z "$SIZE16"],[AC_MSG_ERROR([No 16 bit type found on this platform!])])
263 AS_IF([test -z "$SIZE32"],[AC_MSG_ERROR([No 32 bit type found on this platform!])])
264 AS_IF([test -z "$USIZE16"],[AC_MSG_ERROR([No unsigned 16 bit type found on this platform!])])
265 AS_IF([test -z "$USIZE32"],[AC_MSG_ERROR([No unsigned 32 bit type found on this platform!])])
266
267 AC_SUBST([SIZE16])
268 AC_SUBST([USIZE16])
269 AC_SUBST([SIZE32])
270 AC_SUBST([USIZE32])
271
272 AC_CONFIG_FILES([
273            Makefile libspeexdsp/Makefile doc/Makefile SpeexDSP.spec
274            include/Makefile include/speex/Makefile speexdsp.pc
275            win32/Makefile win32/libspeexdsp/Makefile
276            symbian/Makefile 
277
278            win32/VS2003/Makefile
279            win32/VS2003/libspeexdsp/Makefile
280            win32/VS2003/tests/Makefile
281
282            win32/VS2005/Makefile
283            win32/VS2005/libspeexdsp/Makefile
284            win32/VS2005/tests/Makefile
285
286            win32/VS2008/Makefile
287            win32/VS2008/libspeexdsp/Makefile
288            win32/VS2008/tests/Makefile
289            include/speex/speexdsp_config_types.h ti/Makefile 
290            ti/speex_C54_test/Makefile ti/speex_C55_test/Makefile
291            ti/speex_C64_test/Makefile ])
292
293 AC_CONFIG_HEADERS([config.h])
294
295 AC_OUTPUT
296
297 echo "Type \"make; make install\" to compile and install Speex";