speex_types.h for win32 and symbian
[speexdsp.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(libspeex/speex.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 SPEEX_MAJOR_VERSION=1
8 SPEEX_MINOR_VERSION=1
9 SPEEX_MICRO_VERSION=8
10 SPEEX_EXTRA_VERSION=
11 #SPEEX_VERSION=1.1.7
12 SPEEX_VERSION=$SPEEX_MAJOR_VERSION.$SPEEX_MINOR_VERSION.$SPEEX_MICRO_VERSION$SPEEX_EXTRA_VERSION
13
14 SPEEX_LT_CURRENT=3
15 SPEEX_LT_REVISION=0
16 SPEEX_LT_AGE=2
17
18 AC_SUBST(SPEEX_LT_CURRENT)
19 AC_SUBST(SPEEX_LT_REVISION)
20 AC_SUBST(SPEEX_LT_AGE)
21
22 # For automake.
23 VERSION=$SPEEX_VERSION
24 PACKAGE=speex
25
26 AC_SUBST(SPEEX_VERSION)
27
28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
29 AM_MAINTAINER_MODE
30
31 AC_CANONICAL_HOST
32 AM_PROG_LIBTOOL
33
34 AC_C_BIGENDIAN
35 AC_C_CONST
36 AC_C_INLINE
37 AC_C_RESTRICT
38
39
40
41 AC_MSG_CHECKING(for C99 variable-size arrays)
42 AC_TRY_RUN([
43 int foo=10;
44 int main() {int array[foo];return 0;}
45 ],
46 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])],
47 has_var_arrays=no,
48 has_var_arrays=no,
49 )
50 AC_MSG_RESULT($has_var_arrays)
51
52 AC_MSG_CHECKING(for alloca)
53 AC_TRY_RUN([
54 #include <alloca.h>
55 int foo=10;
56 int main() {int *array = alloca(foo);return 0;}
57 ],
58 [
59 has_alloca=yes;
60 if test x$has_var_arrays = "xno" ; then
61 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
62 fi
63 ],
64 has_alloca=no,
65 has_alloca=no,
66 )
67 AC_MSG_RESULT($has_alloca)
68
69
70 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
71
72 XIPH_PATH_OGG([src="src"], [src=""])
73 AC_SUBST(src)
74
75 AC_CHECK_LIB(m, sin)
76
77 # Check for getopt_long; if not found, use included source.
78 AC_CHECK_FUNCS([getopt_long],,
79 [# FreeBSD has a gnugetopt library.
80   AC_CHECK_LIB([gnugetopt],[getopt_long],
81 [AC_DEFINE([HAVE_GETOPT_LONG])],
82 [# Use the GNU replacement.
83 AC_LIBOBJ(getopt)
84 AC_LIBOBJ(getopt1)])])
85
86 AC_CHECK_LIB(winmm, main)
87
88 AC_DEFINE_UNQUOTED(SPEEX_VERSION, "${SPEEX_VERSION}", [Complete version string])
89 AC_DEFINE_UNQUOTED(SPEEX_MAJOR_VERSION, ${SPEEX_MAJOR_VERSION}, [Version major])
90 AC_DEFINE_UNQUOTED(SPEEX_MINOR_VERSION, ${SPEEX_MINOR_VERSION}, [Version minor])
91 AC_DEFINE_UNQUOTED(SPEEX_MICRO_VERSION, ${SPEEX_MICRO_VERSION}, [Version micro])
92 AC_DEFINE_UNQUOTED(SPEEX_EXTRA_VERSION, "${SPEEX_EXTRA_VERSION}", [Version extra])
93
94 AC_ARG_ENABLE(wideband, [  --disable-wideband      Disable wideband codec],
95 [if test "$enableval" = no; then
96   AC_DEFINE([DISABLE_WIDEBAND], , [Disable wideband codec])
97 fi])
98
99 AC_ARG_ENABLE(valgrind, [  --enable-valgrind       Enable valgrind extra checks],
100 [if test "$enableval" = yes; then
101   AC_DEFINE([ENABLE_VALGRIND], , [Enable valgrind extra checks])
102 fi])
103
104 AC_ARG_ENABLE(sse, [  --enable-sse            Enable SSE support], [if test "$enableval" = yes; then
105 AC_DEFINE([_USE_SSE], , [Enable SSE support])
106 CFLAGS="$CFLAGS -O3 -msse"
107 fi
108 ])
109
110 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    Compile as fixed-point],
111 [if test "$enableval" = yes; then
112   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
113 fi])
114
115 AC_ARG_ENABLE(arm4-asm, [  --enable-arm4-asm       Make use of ARM4 assembly instructions],
116 [if test "$enableval" = yes; then
117   AC_DEFINE([ARM4_ASM], , [Make use of ARM4 assembly instructions])
118 fi])
119
120 AC_ARG_ENABLE(arm5e-asm, [  --enable-arm5e-asm      Make use of ARM5E assembly instructions],
121 [if test "$enableval" = yes; then
122   AC_DEFINE([ARM5_ASM], , [Make use of ARM5E assembly instructions])
123 fi])
124
125 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  Debug fixed-point implementation],
126 [if test "$enableval" = yes; then
127   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
128 fi])
129
130 AC_ARG_ENABLE(epic-48k, [  --enable-epic-48k       Enable support for Epic 4.8 kbps mode],
131 [if test "$enableval" = yes; then
132   AC_DEFINE([EPIC_48K], , [Enable support for Epic 4.8 kbps mode])
133 fi])
134
135 AC_ARG_ENABLE(ti-c55x, [  --enable-ti-c55x        Enable support for TI C55X DSP],
136 [if test "$enableval" = yes; then
137   has_char16=yes;
138   AC_DEFINE([TI_C55X], , [Enable support for TI C55X DSP])
139 fi])
140
141 AC_ARG_ENABLE(16bit-precision, [  --enable-16bit-precision Reduce precision to 16 bits (EXPERIMENTAL)],
142 [if test "$enableval" = yes; then
143   AC_DEFINE([PRECISION16], , [Reduce precision to 16 bits (EXPERIMENTAL)])
144 fi])
145
146 AC_CHECK_SIZEOF(short)
147 AC_CHECK_SIZEOF(int)
148 AC_CHECK_SIZEOF(long)
149 AC_CHECK_SIZEOF(long long)
150
151 if test x$has_char16 = "xyes" ; then
152         case 1 in
153                 $ac_cv_sizeof_short) SIZE16="short";;
154                 $ac_cv_sizeof_int) SIZE16="int";;
155         esac
156 else
157         case 2 in
158                 $ac_cv_sizeof_short) SIZE16="short";;
159                 $ac_cv_sizeof_int) SIZE16="int";;
160         esac
161 fi
162
163 if test x$has_char16 = "xyes" ; then
164         case 2 in
165                 $ac_cv_sizeof_int) SIZE32="int";;
166                 $ac_cv_sizeof_long) SIZE32="long";;
167                 $ac_cv_sizeof_short) SIZE32="short";;
168         esac
169 else
170         case 4 in
171                 $ac_cv_sizeof_int) SIZE32="int";;
172                 $ac_cv_sizeof_long) SIZE32="long";;
173                 $ac_cv_sizeof_short) SIZE32="short";;
174         esac
175 fi
176
177 AC_SUBST(SIZE16)
178 AC_SUBST(SIZE32)
179
180 AC_OUTPUT([Makefile libspeex/Makefile src/Makefile doc/Makefile Speex.spec
181            include/Makefile include/speex/Makefile speex.pc
182            win32/Makefile win32/libspeex/Makefile win32/speexenc/Makefile
183            win32/speexdec/Makefile include/speex/speex_types.h ])
184
185 if test "x$src" = "x"; then 
186 echo "**IMPORTANT**"
187 echo "You don't seem to have the development package for libogg (libogg-devel) installed. Only the Speex library (libspeex) will be built (no encoder/decoder executable)"
188 echo "You can download libogg from http://www.vorbis.com/download.psp"
189 fi
190
191 echo "Type \"make; make install\" to compile and install Speex";