Numerous autoconf changes. Configure option for FLOAT_APPROX
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(libcelt/arch.h)
4
5 AM_CONFIG_HEADER([config.h])
6
7 CELT_MAJOR_VERSION=0
8 CELT_MINOR_VERSION=6
9 CELT_MICRO_VERSION=0
10 CELT_EXTRA_VERSION=
11 CELT_VERSION=$CELT_MAJOR_VERSION.$CELT_MINOR_VERSION.$CELT_MICRO_VERSION$CELT_EXTRA_VERSION
12
13 CELT_LT_CURRENT=0
14 CELT_LT_REVISION=0
15 CELT_LT_AGE=0
16
17 AC_SUBST(CELT_LT_CURRENT)
18 AC_SUBST(CELT_LT_REVISION)
19 AC_SUBST(CELT_LT_AGE)
20
21 # For automake.
22 VERSION=$CELT_VERSION
23 PACKAGE=celt
24
25 AC_SUBST(CELT_VERSION)
26
27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
28 AM_MAINTAINER_MODE
29
30 AC_CANONICAL_HOST
31 AM_PROG_LIBTOOL
32
33 AC_PROG_CC_C99
34 AC_C_BIGENDIAN
35 AC_C_CONST
36 AC_C_INLINE
37 AC_C_RESTRICT
38
39 AC_DEFINE([CELT_BUILD], [], [This is a build of CELT])
40
41 AC_MSG_CHECKING(for C99 variable-size arrays)
42 AC_TRY_COMPILE( , [
43 int foo=10;
44 int array[foo];
45 ],
46 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
47 ],
48 has_var_arrays=no
49 )
50 AC_MSG_RESULT($has_var_arrays)
51
52 AC_CHECK_HEADERS([alloca.h getopt.h])
53 AC_MSG_CHECKING(for alloca)
54 AC_TRY_COMPILE( [#include <alloca.h>], [
55 int foo=10;
56 int *array = alloca(foo);
57 ],
58 [
59 has_alloca=yes;
60 if test x$has_var_arrays = "xno" ; then
61 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
62 fi
63 ],
64 has_alloca=no
65 )
66 AC_MSG_RESULT($has_alloca)
67
68 AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)
69
70 AS_IF([test "x$with_ogg" != xno],
71  [XIPH_PATH_OGG([tools="tools"], [tools=""])],
72  [tools=""])
73 AC_SUBST(tools)
74
75 AC_CHECK_LIB(m, sin)
76
77 # Check for getopt_long; if not found, use included source.
78 AC_CHECK_FUNCS([getopt_long],,
79 [# FreeBSD has a gnugetopt library.
80   AC_CHECK_LIB([gnugetopt],[getopt_long],
81 [AC_DEFINE([HAVE_GETOPT_LONG])],
82 [# Use the GNU replacement.
83 AC_LIBOBJ(getopt)
84 AC_LIBOBJ(getopt1)])])
85
86 AC_CHECK_LIB(winmm, main)
87
88 AC_DEFINE_UNQUOTED(CELT_VERSION, "${CELT_VERSION}", [Complete version string])
89 AC_DEFINE_UNQUOTED(CELT_MAJOR_VERSION, ${CELT_MAJOR_VERSION}, [Version major])
90 AC_DEFINE_UNQUOTED(CELT_MINOR_VERSION, ${CELT_MINOR_VERSION}, [Version minor])
91 AC_DEFINE_UNQUOTED(CELT_MICRO_VERSION, ${CELT_MICRO_VERSION}, [Version micro])
92 AC_DEFINE_UNQUOTED(CELT_EXTRA_VERSION, "${CELT_EXTRA_VERSION}", [Version extra])
93
94 has_float_approx=no
95 #case "$host_cpu" in
96 #i[[3456]]86 | x86_64)
97 #  has_float_approx=yes
98 #  ;;
99 #esac    
100
101 ac_enable_fixed="no";
102 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    compile as fixed-point],
103 [if test "$enableval" = yes; then
104   ac_enable_fixed="yes";
105   AC_DEFINE([FIXED_POINT], , [Compile as fixed-point])
106   AC_DEFINE([DOUBLE_PRECISION], , [Compile as fixed-point])
107   AC_DEFINE([MIXED_PRECISION], , [Compile as fixed-point])
108 else
109   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
110 fi],
111 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
112
113 ac_enable_fixed_debug="no"
114 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  debug fixed-point implementation],
115 [if test "$enableval" = yes; then
116   ac_enable_fixed_debug="yes"
117   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
118 fi])
119
120 float_approx=$has_float_approx
121 AC_ARG_ENABLE(float-approx, [  --disable-float-approx  do not use fast approximations for floating point],
122     [ if test "$enableval" = yes; then
123     AC_WARN([Floating point approximations are not supported on all platforms.])
124     float_approx=yes
125     else
126     float_approx=no
127     fi], [ float_approx=$has_float_approx ])
128
129 if test "x${float_approx}" = "xyes"; then
130     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
131 fi
132
133 ac_enable_static_modes="no"
134 AC_ARG_ENABLE(static-modes, [  --enable-static-modes   use pre-computed codec configurations],
135 [if test "$enableval" = yes; then
136   ac_enable_static_modes="yes"
137   AC_DEFINE([STATIC_MODES], , [Static modes])
138 fi])
139
140 ac_enable_assertions="no"
141 AC_ARG_ENABLE(assertions, [  --enable-assertions     enable additional software error checking],
142 [if test "$enableval" = yes; then
143   ac_enable_assertions="yes"
144   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
145 fi])
146
147 ac_enable_new_plc="no"
148 AC_ARG_ENABLE(new-plc, [  --enable-new-plc        enable the new loss concealment code],
149 [if test "$enableval" = yes; then
150   ac_enable_new_plc="yes"
151   AC_DEFINE([NEW_PLC], , [Use new PLC code])
152 fi])
153
154 saved_CFLAGS="$CFLAGS"
155 CFLAGS="$CFLAGS -fvisibility=hidden"
156 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden])
157 AC_COMPILE_IFELSE([char foo;],
158       [ AC_MSG_RESULT([yes])
159         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
160         AC_MSG_RESULT([no]))
161 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
162 AC_SUBST(SYMBOL_VISIBILITY)
163
164 if test $ac_cv_c_compiler_gnu = yes ; then
165         CFLAGS="$CFLAGS -W -Wstrict-prototypes -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wno-parentheses -Wno-unused-parameter -Wno-sign-compare"
166 fi
167
168 AC_C99_FUNC_LRINTF
169 AC_C99_FUNC_LRINT
170
171 AC_CHECK_SIZEOF(short)
172 AC_CHECK_SIZEOF(int)
173 AC_CHECK_SIZEOF(long)
174 AC_CHECK_SIZEOF(long long)
175
176 if test x$has_char16 = "xyes" ; then
177         case 1 in
178                 $ac_cv_sizeof_short) SIZE16="short";;
179                 $ac_cv_sizeof_int) SIZE16="int";;
180         esac
181 else
182         case 2 in
183                 $ac_cv_sizeof_short) SIZE16="short";;
184                 $ac_cv_sizeof_int) SIZE16="int";;
185         esac
186 fi
187
188 if test x$has_char16 = "xyes" ; then
189         case 2 in
190                 $ac_cv_sizeof_int) SIZE32="int";;
191                 $ac_cv_sizeof_long) SIZE32="long";;
192                 $ac_cv_sizeof_short) SIZE32="short";;
193         esac
194 else
195         case 4 in
196                 $ac_cv_sizeof_int) SIZE32="int";;
197                 $ac_cv_sizeof_long) SIZE32="long";;
198                 $ac_cv_sizeof_short) SIZE32="short";;
199         esac
200 fi
201
202 AC_SUBST(SIZE16)
203 AC_SUBST(SIZE32)
204
205 AC_OUTPUT([Makefile libcelt/Makefile tests/Makefile 
206            celt.pc tools/Makefile libcelt.spec ])
207
208 AC_MSG_RESULT([
209 ------------------------------------------------------------------------
210   $PACKAGE $VERSION:  Automatic configuration OK.
211   
212     Compiler support:
213
214       C99 var arrays: ................ ${has_var_arrays}
215       C99 lrintf: .................... ${ac_cv_c99_lrintf}
216       Alloca: ........................ ${has_alloca}
217     
218     General configuration:
219     
220       Fast float approximations: ..... ${float_approx}
221       Fixed point support: ........... ${ac_enable_fixed}
222       Fixed point debugging: ......... ${ac_enable_fixed_debug}
223       Static modes: .................. ${ac_enable_static_modes}
224       Assertion checking: ............ ${ac_enable_assertions}
225       New PLC: ....................... ${ac_enable_new_plc}
226 ------------------------------------------------------------------------
227 ])
228
229 if test "x$tools" = "x"; then 
230 echo "**IMPORTANT**"
231 echo "You don't seem to have the development package for libogg (libogg-devel) available. Only the library will be built (no encoder/decoder executable)"
232 echo "You can download libogg from http://www.vorbis.com/download.psp"
233 fi
234
235 echo "Type \"make; make install\" to compile and install";
236 echo "Type \"make check\" to run the test suite";