armv7: Enable NE10's fixed-point FFT for the MDCT
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 dnl The package_version file will be automatically synced to the git revision
4 dnl by the update_version script when configured in the repository, but will
5 dnl remain constant in tarball releases unless it is manually edited.
6 m4_define([CURRENT_VERSION],
7           m4_esyscmd([ ./update_version 2>/dev/null || true
8                        if test -e package_version; then
9                            . ./package_version
10                            printf "$PACKAGE_VERSION"
11                        else
12                            printf "unknown"
13                        fi ]))
14
15 AC_INIT([opus],[CURRENT_VERSION],[opus@xiph.org])
16
17 AC_CONFIG_SRCDIR(src/opus_encoder.c)
18 AC_CONFIG_MACRO_DIR([m4])
19
20 dnl enable silent rules on automake 1.11 and later
21 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
22
23 # For libtool.
24 dnl Please update these for releases.
25 OPUS_LT_CURRENT=5
26 OPUS_LT_REVISION=0
27 OPUS_LT_AGE=5
28
29 AC_SUBST(OPUS_LT_CURRENT)
30 AC_SUBST(OPUS_LT_REVISION)
31 AC_SUBST(OPUS_LT_AGE)
32
33 AM_INIT_AUTOMAKE([no-define])
34 AM_MAINTAINER_MODE([enable])
35
36 AC_CANONICAL_HOST
37 AC_MINGW32
38 AM_PROG_LIBTOOL
39 AM_PROG_CC_C_O
40
41 AC_PROG_CC_C99
42 AC_C_CONST
43 AC_C_INLINE
44
45 AM_PROG_AS
46
47 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
48
49 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
50 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
51 #Note: Both this and the test for variable-size arrays below are also
52 #      done by AC_PROG_CC_C99, but not thoroughly enough apparently.
53 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
54   [ac_cv_c_restrict=no
55    # The order here caters to the fact that C++ does not require restrict.
56    for ac_kw in __restrict __restrict__ _Restrict restrict; do
57      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
58       [[typedef int * int_ptr;
59         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
60         return ip[0];
61        }]],
62       [[int s[1];
63         int * $ac_kw t = s;
64         t[0] = 0;
65         return foo(t, (void *)0)]])],
66       [ac_cv_c_restrict=$ac_kw])
67      test "$ac_cv_c_restrict" != no && break
68    done
69   ])
70
71 AH_VERBATIM([restrict],
72 [/* Define to the equivalent of the C99 'restrict' keyword, or to
73    nothing if this is not supported.  Do not define if restrict is
74    supported directly.  */
75 #undef restrict
76 /* Work around a bug in Sun C++: it does not support _Restrict or
77    __restrict__, even though the corresponding Sun C compiler ends up with
78    "#define restrict _Restrict" or "#define restrict __restrict__" in the
79    previous line.  Perhaps some future version of Sun C++ will work with
80    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
81 #if defined __SUNPRO_CC && !defined __RESTRICT
82 # define _Restrict
83 # define __restrict__
84 #endif])
85
86 case $ac_cv_c_restrict in
87    restrict) ;;
88    no) AC_DEFINE([restrict], []) ;;
89    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
90 esac
91
92 AC_MSG_CHECKING(for C99 variable-size arrays)
93 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
94                    [[static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];]])],
95     [ has_var_arrays=yes
96       use_alloca="no (using var arrays)"
97       AC_DEFINE([VAR_ARRAYS], [1], [Use C99 variable-size arrays])
98     ],[
99       has_var_arrays=no
100     ])
101 AC_MSG_RESULT([$has_var_arrays])
102
103 AS_IF([test "$has_var_arrays" = "no"],
104   [
105    AC_CHECK_HEADERS([alloca.h])
106    AC_MSG_CHECKING(for alloca)
107    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alloca.h>]],
108                                       [[int foo=10; int *array = alloca(foo);]])],
109      [ use_alloca=yes;
110        AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
111      ],[
112        use_alloca=no
113      ])
114    AC_MSG_RESULT([$use_alloca])
115   ])
116
117 LT_LIB_M
118
119 AC_ARG_ENABLE([fixed-point],
120     [AS_HELP_STRING([--enable-fixed-point],
121                     [compile without floating point (for machines without a fast enough FPU)])],,
122     [enable_fixed_point=no])
123
124 AS_IF([test "$enable_fixed_point" = "yes"],[
125   enable_float="no"
126   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point (for machines without a fast enough FPU)])
127   PC_BUILD="fixed-point"
128 ],[
129   enable_float="yes";
130   PC_BUILD="floating-point"
131 ])
132
133 AM_CONDITIONAL([FIXED_POINT], [test "$enable_fixed_point" = "yes"])
134
135 AC_ARG_ENABLE([fixed-point-debug],
136     [AS_HELP_STRING([--enable-fixed-point-debug], [debug fixed-point implementation])],,
137     [enable_fixed_point_debug=no])
138
139 AS_IF([test "$enable_fixed_point_debug" = "yes"],[
140   AC_DEFINE([FIXED_DEBUG], [1], [Debug fixed-point implementation])
141 ])
142
143 AC_ARG_ENABLE([float_api],
144     [AS_HELP_STRING([--disable-float-api],
145                     [compile without the floating point API (for machines with no float library)])],,
146     [enable_float_api=yes])
147
148 AM_CONDITIONAL([DISABLE_FLOAT_API], [test "$enable_float_api" = "no"])
149
150 AS_IF([test "$enable_float_api" = "no"],[
151   AC_DEFINE([DISABLE_FLOAT_API], [1], [Do not build the float API])
152 ])
153
154 AC_ARG_ENABLE([custom-modes],
155     [AS_HELP_STRING([--enable-custom-modes], [enable non-Opus modes, e.g. 44.1 kHz & 2^n frames])],,
156     [enable_custom_modes=no])
157
158 AS_IF([test "$enable_custom_modes" = "yes"],[
159   AC_DEFINE([CUSTOM_MODES], [1], [Custom modes])
160   PC_BUILD="$PC_BUILD, custom modes"
161 ])
162
163 AM_CONDITIONAL([CUSTOM_MODES], [test "$enable_custom_modes" = "yes"])
164
165 has_float_approx=no
166 #case "$host_cpu" in
167 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
168 #  has_float_approx=yes
169 #  ;;
170 #esac
171
172 AC_ARG_ENABLE([float-approx],
173     [AS_HELP_STRING([--enable-float-approx], [enable fast approximations for floating point])],
174     [if test "$enable_float_approx" = "yes"; then
175        AC_WARN([Floating point approximations are not supported on all platforms.])
176      fi
177     ],
178     [enable_float_approx=$has_float_approx])
179
180 AS_IF([test "$enable_float_approx" = "yes"],[
181   AC_DEFINE([FLOAT_APPROX], [1], [Float approximations])
182 ])
183
184 AC_ARG_ENABLE([asm],
185     [AS_HELP_STRING([--disable-asm], [Disable assembly optimizations])],,
186     [enable_asm=yes])
187
188 AC_ARG_ENABLE([rtcd],
189     [AS_HELP_STRING([--disable-rtcd], [Disable run-time CPU capabilities detection])],,
190     [enable_rtcd=yes])
191
192 AC_ARG_ENABLE([intrinsics],
193     [AS_HELP_STRING([--enable-intrinsics], [Enable intrinsics optimizations for ARM(float) X86(fixed)])],,
194     [enable_intrinsics=no])
195
196 rtcd_support=no
197 cpu_arm=no
198
199 AS_IF([test x"${enable_asm}" = x"yes"],[
200     inline_optimization="No inline ASM for your platform, please send patches"
201     case $host_cpu in
202       arm*)
203         dnl Currently we only have asm for fixed-point
204         AS_IF([test "$enable_float" != "yes"],[
205             cpu_arm=yes
206             AC_DEFINE([OPUS_ARM_ASM], [],  [Make use of ARM asm optimization])
207             AS_GCC_INLINE_ASSEMBLY(
208                 [inline_optimization="ARM"],
209                 [inline_optimization="disabled"]
210             )
211             AS_ASM_ARM_EDSP([OPUS_ARM_INLINE_EDSP=1],[OPUS_ARM_INLINE_EDSP=0])
212             AS_ASM_ARM_MEDIA([OPUS_ARM_INLINE_MEDIA=1],
213                 [OPUS_ARM_INLINE_MEDIA=0])
214             AS_ASM_ARM_NEON([OPUS_ARM_INLINE_NEON=1],[OPUS_ARM_INLINE_NEON=0])
215             AS_IF([test x"$inline_optimization" = x"ARM"],[
216                 AM_CONDITIONAL([OPUS_ARM_INLINE_ASM],[true])
217                 AC_DEFINE([OPUS_ARM_INLINE_ASM], 1,
218                     [Use generic ARMv4 inline asm optimizations])
219                 AS_IF([test x"$OPUS_ARM_INLINE_EDSP" = x"1"],[
220                     AC_DEFINE([OPUS_ARM_INLINE_EDSP], [1],
221                         [Use ARMv5E inline asm optimizations])
222                     inline_optimization="$inline_optimization (EDSP)"
223                 ])
224                 AS_IF([test x"$OPUS_ARM_INLINE_MEDIA" = x"1"],[
225                     AC_DEFINE([OPUS_ARM_INLINE_MEDIA], [1],
226                         [Use ARMv6 inline asm optimizations])
227                     inline_optimization="$inline_optimization (Media)"
228                 ])
229                 AS_IF([test x"$OPUS_ARM_INLINE_NEON" = x"1"],[
230                     AC_DEFINE([OPUS_ARM_INLINE_NEON], 1,
231                         [Use ARM NEON inline asm optimizations])
232                     inline_optimization="$inline_optimization (NEON)"
233                 ])
234             ])
235             dnl We need Perl to translate RVCT-syntax asm to gas syntax.
236             AC_CHECK_PROG([HAVE_PERL], perl, yes, no)
237             AS_IF([test x"$HAVE_PERL" = x"yes"],[
238                 AM_CONDITIONAL([OPUS_ARM_EXTERNAL_ASM],[true])
239                 asm_optimization="ARM"
240                 AS_IF([test x"$OPUS_ARM_INLINE_EDSP" = x"1"], [
241                     OPUS_ARM_PRESUME_EDSP=1
242                     OPUS_ARM_MAY_HAVE_EDSP=1
243                 ],
244                 [
245                     OPUS_ARM_PRESUME_EDSP=0
246                     OPUS_ARM_MAY_HAVE_EDSP=0
247                 ])
248                 AS_IF([test x"$OPUS_ARM_INLINE_MEDIA" = x"1"], [
249                     OPUS_ARM_PRESUME_MEDIA=1
250                     OPUS_ARM_MAY_HAVE_MEDIA=1
251                 ],
252                 [
253                     OPUS_ARM_PRESUME_MEDIA=0
254                     OPUS_ARM_MAY_HAVE_MEDIA=0
255                 ])
256                 AS_IF([test x"$OPUS_ARM_INLINE_NEON" = x"1"], [
257                     OPUS_ARM_PRESUME_NEON=1
258                     OPUS_ARM_MAY_HAVE_NEON=1
259                 ],
260                 [
261                     OPUS_ARM_PRESUME_NEON=0
262                     OPUS_ARM_MAY_HAVE_NEON=0
263                 ])
264                 AS_IF([test x"$enable_rtcd" = x"yes"],[
265                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_EDSP" != x"1"],[
266                         AC_MSG_NOTICE(
267                           [Trying to force-enable armv5e EDSP instructions...])
268                         AS_ASM_ARM_EDSP_FORCE([OPUS_ARM_MAY_HAVE_EDSP=1])
269                     ])
270                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_MEDIA" != x"1"],[
271                         AC_MSG_NOTICE(
272                           [Trying to force-enable ARMv6 media instructions...])
273                         AS_ASM_ARM_MEDIA_FORCE([OPUS_ARM_MAY_HAVE_MEDIA=1])
274                     ])
275                     AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON" != x"1"],[
276                         AC_MSG_NOTICE(
277                           [Trying to force-enable NEON instructions...])
278                         AS_ASM_ARM_NEON_FORCE([OPUS_ARM_MAY_HAVE_NEON=1])
279                     ])
280                 ])
281                 rtcd_support=
282                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_EDSP" = x"1"],[
283                     AC_DEFINE(OPUS_ARM_MAY_HAVE_EDSP, 1,
284                         [Define if assembler supports EDSP instructions])
285                     AS_IF([test x"$OPUS_ARM_PRESUME_EDSP" = x"1"],[
286                         AC_DEFINE(OPUS_ARM_PRESUME_EDSP, 1,
287                           [Define if binary requires EDSP instruction support])
288                         asm_optimization="$asm_optimization (EDSP)"
289                     ],
290                         [rtcd_support="$rtcd_support (EDSP)"]
291                     )
292                 ])
293                 AC_SUBST(OPUS_ARM_MAY_HAVE_EDSP)
294                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_MEDIA" = x"1"],[
295                     AC_DEFINE(OPUS_ARM_MAY_HAVE_MEDIA, 1,
296                       [Define if assembler supports ARMv6 media instructions])
297                     AS_IF([test x"$OPUS_ARM_PRESUME_MEDIA" = x"1"],[
298                         AC_DEFINE(OPUS_ARM_PRESUME_MEDIA, 1,
299                           [Define if binary requires ARMv6 media instruction support])
300                         asm_optimization="$asm_optimization (Media)"
301                     ],
302                         [rtcd_support="$rtcd_support (Media)"]
303                     )
304                 ])
305                 AC_SUBST(OPUS_ARM_MAY_HAVE_MEDIA)
306                 AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON" = x"1"],[
307                     AC_DEFINE(OPUS_ARM_MAY_HAVE_NEON, 1,
308                       [Define if compiler supports NEON instructions])
309                     AS_IF([test x"$OPUS_ARM_PRESUME_NEON" = x"1"], [
310                         AC_DEFINE(OPUS_ARM_PRESUME_NEON, 1,
311                           [Define if binary requires NEON instruction support])
312                         asm_optimization="$asm_optimization (NEON)"
313                     ],
314                         [rtcd_support="$rtcd_support (NEON)"]
315                     )
316                 ])
317                 AC_SUBST(OPUS_ARM_MAY_HAVE_NEON)
318                 dnl Make sure turning on RTCD gets us at least one
319                 dnl instruction set.
320                 AS_IF([test x"$rtcd_support" != x""],
321                     [rtcd_support=ARM"$rtcd_support"],
322                     [rtcd_support="no"]
323                 )
324                 AC_MSG_CHECKING([for apple style tools])
325                 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
326 #ifndef __APPLE__
327 #error 1
328 #endif],[])],
329                     [AC_MSG_RESULT([yes]); ARM2GNU_PARAMS="--apple"],
330                     [AC_MSG_RESULT([no]); ARM2GNU_PARAMS=""])
331                 AC_SUBST(ARM2GNU_PARAMS)
332             ],
333             [
334                 AC_MSG_WARN(
335                   [*** ARM assembly requires perl -- disabling optimizations])
336                 asm_optimization="(missing perl dependency for ARM)"
337             ])
338         ])
339         ;;
340     esac
341 ],[
342    inline_optimization="disabled"
343    asm_optimization="disabled"
344 ])
345
346 AM_CONDITIONAL([OPUS_ARM_INLINE_ASM],
347     [test x"${inline_optimization%% *}" = x"ARM"])
348 AM_CONDITIONAL([OPUS_ARM_EXTERNAL_ASM],
349     [test x"${asm_optimization%% *}" = x"ARM"])
350
351 AM_CONDITIONAL([HAVE_SSE], [false])
352 AM_CONDITIONAL([HAVE_SSE2], [false])
353 AM_CONDITIONAL([HAVE_SSE4_1], [false])
354
355 m4_define([DEFAULT_X86_SSE_CFLAGS], [-msse])
356 m4_define([DEFAULT_X86_SSE2_CFLAGS], [-msse2])
357 m4_define([DEFAULT_X86_SSE4_1_CFLAGS], [-msse4.1])
358 m4_define([DEFAULT_ARM_NEON_INTR_CFLAGS], [-mfpu=neon])
359 # With GCC on ARM32 softfp architectures (e.g. Android, or older Ubuntu) you need to specify
360 # -mfloat-abi=softfp for -mfpu=neon to work.  However, on ARM32 hardfp architectures (e.g. newer Ubuntu),
361 # this option will break things.
362
363 # As a heuristic, if host matches arm*eabi* but not arm*hf*, it's probably soft-float.
364 m4_define([DEFAULT_ARM_NEON_SOFTFP_INTR_CFLAGS], [-mfpu=neon -mfloat-abi=softfp])
365
366 AS_CASE([$host],
367         [arm*hf*], [AS_VAR_SET([RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS], "DEFAULT_ARM_NEON_INTR_CFLAGS")],
368         [arm*eabi*], [AS_VAR_SET([RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS], "DEFAULT_ARM_NEON_SOFTFP_INTR_CFLAGS")],
369         [AS_VAR_SET([RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS], "DEFAULT_ARM_NEON_INTR_CFLAGS")])
370
371 AC_ARG_VAR([X86_SSE_CFLAGS], [C compiler flags to compile SSE intrinsics @<:@default=]DEFAULT_X86_SSE_CFLAGS[@:>@])
372 AC_ARG_VAR([X86_SSE2_CFLAGS], [C compiler flags to compile SSE2 intrinsics @<:@default=]DEFAULT_X86_SSE2_CFLAGS[@:>@])
373 AC_ARG_VAR([X86_SSE4_1_CFLAGS], [C compiler flags to compile SSE4.1 intrinsics @<:@default=]DEFAULT_X86_SSE4_1_CFLAGS[@:>@])
374 AC_ARG_VAR([ARM_NEON_INTR_CFLAGS], [C compiler flags to compile ARM NEON intrinsics @<:@default=]DEFAULT_ARM_NEON_INTR_CFLAGS / DEFAULT_ARM_NEON_SOFTFP_INTR_CFLAGS[@:>@])
375
376 AS_VAR_SET_IF([X86_SSE_CFLAGS], [], [AS_VAR_SET([X86_SSE_CFLAGS], "DEFAULT_X86_SSE_CFLAGS")])
377 AS_VAR_SET_IF([X86_SSE2_CFLAGS], [], [AS_VAR_SET([X86_SSE2_CFLAGS], "DEFAULT_X86_SSE2_CFLAGS")])
378 AS_VAR_SET_IF([X86_SSE4_1_CFLAGS], [], [AS_VAR_SET([X86_SSE4_1_CFLAGS], "DEFAULT_X86_SSE4_1_CFLAGS")])
379 AS_VAR_SET_IF([ARM_NEON_INTR_CFLAGS], [], [AS_VAR_SET([ARM_NEON_INTR_CFLAGS], ["$RESOLVED_DEFAULT_ARM_NEON_INTR_CFLAGS"])])
380
381 AC_DEFUN([OPUS_PATH_NE10],
382    [
383       AC_ARG_WITH(NE10,
384                   AC_HELP_STRING([--with-NE10=PFX],[Prefix where libNE10 is installed (optional)]),
385                   NE10_prefix="$withval", NE10_prefix="")
386       AC_ARG_WITH(NE10-libraries,
387                   AC_HELP_STRING([--with-NE10-libraries=DIR],
388                         [Directory where libNE10 library is installed (optional)]),
389                   NE10_libraries="$withval", NE10_libraries="")
390       AC_ARG_WITH(NE10-includes,
391                   AC_HELP_STRING([--with-NE10-includes=DIR],
392                                  [Directory where libNE10 header files are installed (optional)]),
393                   NE10_includes="$withval", NE10_includes="")
394
395       if test "x$NE10_libraries" != "x" ; then
396          NE10_LIBS="-L$NE10_libraries"
397       elif test "x$NE10_prefix" = "xno" || test "x$NE10_prefix" = "xyes" ; then
398          NE10_LIBS=""
399       elif test "x$NE10_prefix" != "x" ; then
400          NE10_LIBS="-L$NE10_prefix/lib"
401       elif test "x$prefix" != "xNONE" ; then
402          NE10_LIBS="-L$prefix/lib"
403       fi
404
405       if test "x$NE10_prefix" != "xno" ; then
406          NE10_LIBS="$NE10_LIBS -lNE10"
407       fi
408
409       if test "x$NE10_includes" != "x" ; then
410          NE10_CFLAGS="-I$NE10_includes"
411       elif test "x$NE10_prefix" = "xno" || test "x$NE10_prefix" = "xyes" ; then
412          NE10_CFLAGS=""
413       elif test "x$ogg_prefix" != "x" ; then
414          NE10_CFLAGS="-I$NE10_prefix/include"
415       elif test "x$prefix" != "xNONE"; then
416          NE10_CFLAGS="-I$prefix/include"
417       fi
418
419       AC_MSG_CHECKING(for NE10)
420       save_CFLAGS="$CFLAGS"; CFLAGS="$NE10_CFLAGS"
421       save_LIBS="$LIBS"; LIBS="$NE10_LIBS $LIBM"
422       AC_LINK_IFELSE(
423          [
424             AC_LANG_PROGRAM(
425                [[#include <NE10_init.h>
426                ]],
427                [[
428                   ne10_fft_cfg_float32_t cfg;
429                   cfg = ne10_fft_alloc_c2c_float32_neon(480);
430                ]]
431             )
432          ],[
433             HAVE_ARM_NE10=1
434             AC_MSG_RESULT([yes])
435          ],[
436             HAVE_ARM_NE10=0
437             AC_MSG_RESULT([no])
438             NE10_CFLAGS=""
439             NE10_LIBS=""
440          ]
441       )
442       CFLAGS="$save_CFLAGS"; LIBS="$save_LIBS"
443       #Now we know if libNE10 is installed or not
444       AS_IF([test x"$HAVE_ARM_NE10" = x"1"],
445          [
446             AC_DEFINE([HAVE_ARM_NE10], 1, [NE10 library is installed on host. Make sure it is on target!])
447             AC_SUBST(HAVE_ARM_NE10)
448             AC_SUBST(NE10_CFLAGS)
449             AC_SUBST(NE10_LIBS)
450          ],[]
451       )
452    ]
453 )
454
455 AS_IF([test x"$enable_intrinsics" = x"yes"],[
456    intrinsics_support=""
457    AS_CASE([$host_cpu],
458    [arm*],
459    [
460       cpu_arm=yes
461       OPUS_CHECK_INTRINSICS(
462          [ARM Neon],
463          [$ARM_NEON_INTR_CFLAGS],
464          [OPUS_ARM_MAY_HAVE_NEON_INTR],
465          [OPUS_ARM_PRESUME_NEON_INTR],
466          [[#include <arm_neon.h>
467          ]],
468          [[
469             static float32x4_t A0, A1, SUMM;
470             SUMM = vmlaq_f32(SUMM, A0, A1);
471          ]]
472       )
473       AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON_INTR" = x"1" && test x"$OPUS_ARM_PRESUME_NEON_INTR" != x"1"],
474           [
475              OPUS_ARM_NEON_INTR_CFLAGS="$ARM_NEON_INTR_CFLAGS"
476              AC_SUBST([OPUS_ARM_NEON_INTR_CFLAGS])
477           ]
478       )
479
480       AS_IF([test x"$OPUS_ARM_MAY_HAVE_NEON_INTR" = x"1"],
481       [
482          AC_DEFINE([OPUS_ARM_MAY_HAVE_NEON_INTR], 1, [Compiler supports ARMv7 Neon Intrinsics])
483          intrinsics_support="$intrinsics_support (Neon_Intrinsics)"
484
485          AS_IF([test x"enable_rtcd" != x"" && test x"$OPUS_ARM_PRESUME_NEON_INTR" != x"1"],
486             [rtcd_support="$rtcd_support (ARMv7_Neon_Intrinsics)"],[])
487
488          AS_IF([test x"$OPUS_ARM_PRESUME_NEON_INTR" = x"1"],
489             [AC_DEFINE([OPUS_ARM_PRESUME_NEON_INTR], 1, [Define if binary requires NEON intrinsics support])])
490
491          OPUS_PATH_NE10()
492          AS_IF([test x"$NE10_LIBS" != x""],
493          [
494               intrinsics_support="$intrinsics_support (NE10)"
495               AS_IF([test x"enable_rtcd" != x"" \
496                && test x"$OPUS_ARM_PRESUME_NEON_INTR" != x"1"],
497                  [rtcd_support="$rtcd_support (NE10)"],[])
498          ])
499
500          AS_IF([test x"$rtcd_support" = x""],
501             [rtcd_support=no])
502
503          AS_IF([test x"$intrinsics_support" = x""],
504             [intrinsics_support=no],
505             [intrinsics_support="arm$intrinsics_support"])
506       ],
507       [
508          AC_MSG_WARN([Compiler does not support ARM intrinsics])
509          intrinsics_support=no
510       ])
511    ],
512    [i?86|x86_64],
513    [
514       OPUS_CHECK_INTRINSICS(
515          [SSE],
516          [$X86_SSE_CFLAGS],
517          [OPUS_X86_MAY_HAVE_SSE],
518          [OPUS_X86_PRESUME_SSE],
519          [[#include <xmmintrin.h>
520          ]],
521          [[
522              static __m128 mtest;
523              mtest = _mm_setzero_ps();
524          ]]
525       )
526       AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE" = x"1" && test x"$OPUS_X86_PRESUME_SSE" != x"1"],
527           [
528              OPUS_X86_SSE_CFLAGS="$X86_SSE_CFLAGS"
529              AC_SUBST([OPUS_X86_SSE_CFLAGS])
530           ]
531       )
532       OPUS_CHECK_INTRINSICS(
533          [SSE2],
534          [$X86_SSE2_CFLAGS],
535          [OPUS_X86_MAY_HAVE_SSE2],
536          [OPUS_X86_PRESUME_SSE2],
537          [[#include <emmintrin.h>
538          ]],
539          [[
540              static __m128i mtest;
541              mtest = _mm_setzero_si128();
542          ]]
543       )
544       AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE2" = x"1" && test x"$OPUS_X86_PRESUME_SSE2" != x"1"],
545           [
546              OPUS_X86_SSE2_CFLAGS="$X86_SSE2_CFLAGS"
547              AC_SUBST([OPUS_X86_SSE2_CFLAGS])
548           ]
549       )
550       OPUS_CHECK_INTRINSICS(
551          [SSE4.1],
552          [$X86_SSE4_1_CFLAGS],
553          [OPUS_X86_MAY_HAVE_SSE4_1],
554          [OPUS_X86_PRESUME_SSE4_1],
555          [[#include <smmintrin.h>
556          ]],
557          [[
558             static __m128i mtest;
559             mtest = _mm_setzero_si128();
560             mtest = _mm_cmpeq_epi64(mtest, mtest);
561          ]]
562       )
563       AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE4_1" = x"1" && test x"$OPUS_X86_PRESUME_SSE4_1" != x"1"],
564           [
565              OPUS_X86_SSE4_1_CFLAGS="$X86_SSE4_1_CFLAGS"
566              AC_SUBST([OPUS_X86_SSE4_1_CFLAGS])
567           ]
568       )
569
570          AS_IF([test x"$rtcd_support" = x"no"], [rtcd_support=""])
571          AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE" = x"1"],
572          [
573             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE], 1, [Compiler supports X86 SSE Intrinsics])
574             intrinsics_support="$intrinsics_support SSE"
575
576             AS_IF([test x"$OPUS_X86_PRESUME_SSE" = x"1"],
577                [AC_DEFINE([OPUS_X86_PRESUME_SSE], 1, [Define if binary requires SSE intrinsics support])],
578                [rtcd_support="$rtcd_support SSE"])
579          ],
580          [
581             AC_MSG_WARN([Compiler does not support SSE intrinsics])
582          ])
583
584          AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE2" = x"1"],
585          [
586             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE2], 1, [Compiler supports X86 SSE2 Intrinsics])
587             intrinsics_support="$intrinsics_support SSE2"
588
589             AS_IF([test x"$OPUS_X86_PRESUME_SSE2" = x"1"],
590                [AC_DEFINE([OPUS_X86_PRESUME_SSE2], 1, [Define if binary requires SSE2 intrinsics support])],
591                [rtcd_support="$rtcd_support SSE2"])
592          ],
593          [
594             AC_MSG_WARN([Compiler does not support SSE2 intrinsics])
595          ])
596
597          AS_IF([test x"$OPUS_X86_MAY_HAVE_SSE4_1" = x"1"],
598          [
599             AC_DEFINE([OPUS_X86_MAY_HAVE_SSE4_1], 1, [Compiler supports X86 SSE4.1 Intrinsics])
600             intrinsics_support="$intrinsics_support SSE4.1"
601
602             AS_IF([test x"$OPUS_X86_PRESUME_SSE4_1" = x"1"],
603                [AC_DEFINE([OPUS_X86_PRESUME_SSE4_1], 1, [Define if binary requires SSE4.1 intrinsics support])],
604                [rtcd_support="$rtcd_support SSE4.1"])
605          ],
606          [
607             AC_MSG_WARN([Compiler does not support SSE4.1 intrinsics])
608          ])
609          AS_IF([test x"$intrinsics_support" = x""],
610             [intrinsics_support=no],
611             [intrinsics_support="x86$intrinsics_support"]
612          )
613          AS_IF([test x"$rtcd_support" = x""],
614             [rtcd_support=no],
615             [rtcd_support="x86$rtcd_support"],
616         )
617
618     AS_IF([test x"$enable_rtcd" = x"yes" && test x"$rtcd_support" != x""],[
619             get_cpuid_by_asm="no"
620             AC_MSG_CHECKING([How to get X86 CPU Info])
621             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
622                  #include <stdio.h>
623             ]],[[
624                  unsigned int CPUInfo0;
625                  unsigned int CPUInfo1;
626                  unsigned int CPUInfo2;
627                  unsigned int CPUInfo3;
628                  unsigned int InfoType;
629                  __asm__ __volatile__ (
630                  "cpuid":
631                  "=a" (CPUInfo0),
632                  "=b" (CPUInfo1),
633                  "=c" (CPUInfo2),
634                  "=d" (CPUInfo3) :
635                  "a" (InfoType), "c" (0)
636                 );
637             ]])],
638             [get_cpuid_by_asm="yes"
639              AC_MSG_RESULT([Inline Assembly])
640                          AC_DEFINE([CPU_INFO_BY_ASM], [1], [Get CPU Info by asm method])],
641              [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
642                  #include <cpuid.h>
643             ]],[[
644                  unsigned int CPUInfo0;
645                  unsigned int CPUInfo1;
646                  unsigned int CPUInfo2;
647                  unsigned int CPUInfo3;
648                  unsigned int InfoType;
649                  __get_cpuid(InfoType, &CPUInfo0, &CPUInfo1, &CPUInfo2, &CPUInfo3);
650             ]])],
651             [AC_MSG_RESULT([C method])
652                          AC_DEFINE([CPU_INFO_BY_C], [1], [Get CPU Info by c method])],
653             [AC_MSG_ERROR([no supported Get CPU Info method, please disable intrinsics])])])])
654    ],
655    [
656       AC_MSG_WARN([No intrinsics support for your architecture])
657       intrinsics_support="no"
658    ])
659 ],
660 [
661    intrinsics_support="no"
662 ])
663
664 AM_CONDITIONAL([CPU_ARM], [test "$cpu_arm" = "yes"])
665 AM_CONDITIONAL([OPUS_ARM_NEON_INTR],
666     [test x"$OPUS_ARM_MAY_HAVE_NEON_INTR" = x"1"])
667 AM_CONDITIONAL([HAVE_ARM_NE10],
668     [test x"$HAVE_ARM_NE10" = x"1"])
669 AM_CONDITIONAL([HAVE_SSE],
670     [test x"$OPUS_X86_MAY_HAVE_SSE" = x"1"])
671 AM_CONDITIONAL([HAVE_SSE2],
672     [test x"$OPUS_X86_MAY_HAVE_SSE2" = x"1"])
673 AM_CONDITIONAL([HAVE_SSE4_1],
674     [test x"$OPUS_X86_MAY_HAVE_SSE4_1" = x"1"])
675
676 AS_IF([test x"$enable_rtcd" = x"yes"],[
677     AS_IF([test x"$rtcd_support" != x"no"],[
678         AC_DEFINE([OPUS_HAVE_RTCD], [1],
679             [Use run-time CPU capabilities detection])
680         OPUS_HAVE_RTCD=1
681         AC_SUBST(OPUS_HAVE_RTCD)
682     ])
683 ],[
684     rtcd_support="disabled"
685 ])
686
687 AC_ARG_ENABLE([assertions],
688     [AS_HELP_STRING([--enable-assertions],[enable additional software error checking])],,
689     [enable_assertions=no])
690
691 AS_IF([test "$enable_assertions" = "yes"], [
692   AC_DEFINE([ENABLE_ASSERTIONS], [1], [Assertions])
693 ])
694
695 AC_ARG_ENABLE([fuzzing],
696     [AS_HELP_STRING([--enable-fuzzing],[causes the encoder to make random decisions])],,
697     [enable_fuzzing=no])
698
699 AS_IF([test "$enable_fuzzing" = "yes"], [
700   AC_DEFINE([FUZZING], [1], [Fuzzing])
701 ])
702
703 AC_ARG_ENABLE([doc],
704     [AS_HELP_STRING([--disable-doc], [Do not build API documentation])],,
705     [enable_doc=yes])
706
707 AS_IF([test "$enable_doc" = "yes"], [
708   AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
709 ],[
710   HAVE_DOXYGEN=no
711 ])
712
713 AM_CONDITIONAL([HAVE_DOXYGEN], [test "$HAVE_DOXYGEN" = "yes"])
714
715 AC_ARG_ENABLE([extra-programs],
716     [AS_HELP_STRING([--disable-extra-programs], [Do not build extra programs (demo and tests)])],,
717     [enable_extra_programs=yes])
718
719 AM_CONDITIONAL([EXTRA_PROGRAMS], [test "$enable_extra_programs" = "yes"])
720
721
722 saved_CFLAGS="$CFLAGS"
723 CFLAGS="$CFLAGS -fvisibility=hidden"
724 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
725 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
726     [ AC_MSG_RESULT([yes]) ],
727     [ AC_MSG_RESULT([no])
728       CFLAGS="$saved_CFLAGS"
729     ])
730
731 CFLAGS="$CFLAGS -W"
732
733 warn_CFLAGS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
734 saved_CFLAGS="$CFLAGS"
735 CFLAGS="$CFLAGS $warn_CFLAGS"
736 AC_MSG_CHECKING([if ${CC} supports ${warn_CFLAGS}])
737 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[char foo;]])],
738     [ AC_MSG_RESULT([yes]) ],
739     [ AC_MSG_RESULT([no])
740       CFLAGS="$saved_CFLAGS"
741     ])
742
743 saved_LIBS="$LIBS"
744 LIBS="$LIBS $LIBM"
745 AC_CHECK_FUNCS([lrintf])
746 AC_CHECK_FUNCS([lrint])
747 LIBS="$saved_LIBS"
748
749 AC_CHECK_FUNCS([__malloc_hook])
750
751 AC_SUBST([PC_BUILD])
752
753 AC_CONFIG_FILES([
754     Makefile
755     opus.pc
756     opus-uninstalled.pc
757     celt/arm/armopts.s
758     doc/Makefile
759     doc/Doxyfile
760 ])
761 AC_CONFIG_HEADERS([config.h])
762
763 AC_OUTPUT
764
765 AC_MSG_NOTICE([
766 ------------------------------------------------------------------------
767   $PACKAGE_NAME $PACKAGE_VERSION:  Automatic configuration OK.
768
769     Compiler support:
770
771       C99 var arrays: ................ ${has_var_arrays}
772       C99 lrintf: .................... ${ac_cv_func_lrintf}
773       Use alloca: .................... ${use_alloca}
774
775     General configuration:
776
777       Floating point support: ........ ${enable_float}
778       Fast float approximations: ..... ${enable_float_approx}
779       Fixed point debugging: ......... ${enable_fixed_point_debug}
780       Inline Assembly Optimizations: . ${inline_optimization}
781       External Assembly Optimizations: ${asm_optimization}
782       Intrinsics Optimizations.......: ${intrinsics_support}
783       Run-time CPU detection: ........ ${rtcd_support}
784       Custom modes: .................. ${enable_custom_modes}
785       Assertion checking: ............ ${enable_assertions}
786       Fuzzing: ....................... ${enable_fuzzing}
787
788       API documentation: ............. ${enable_doc}
789       Extra programs: ................ ${enable_extra_programs}
790 ------------------------------------------------------------------------
791
792  Type "make; make install" to compile and install
793  Type "make check" to run the test suite
794 ])
795