commas
[opus.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script. -*-m4-*-
2
3 AC_INIT(src/opus_encoder.c)
4
5 AM_CONFIG_HEADER([config.h])
6
7 dnl enable silent rules on automake 1.11 and later
8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
9
10 OPUS_MAJOR_VERSION=0
11 OPUS_MINOR_VERSION=9
12 OPUS_MICRO_VERSION=10
13 OPUS_EXTRA_VERSION=
14
15 OPUS_VERSION="$OPUS_MAJOR_VERSION.$OPUS_MINOR_VERSION.$OPUS_MICRO_VERSION$OPUS_EXTRA_VERSION"
16 AC_MSG_CHECKING([git revision])
17 GIT_VERSION=$(git describe --tags --match 'v*' 2>/dev/null | sed 's/^v//')
18 if test -z "$GIT_VERSION"; then
19   AC_MSG_RESULT([no])
20 else
21   AC_MSG_RESULT([$GIT_VERSION])
22   OPUS_VERSION="$GIT_VERSION"
23 fi
24
25 LIBOPUS_SUFFIX=0
26
27 OPUS_LT_CURRENT=0
28 OPUS_LT_REVISION=0
29 OPUS_LT_AGE=0
30
31 AC_SUBST(OPUS_LT_CURRENT)
32 AC_SUBST(OPUS_LT_REVISION)
33 AC_SUBST(OPUS_LT_AGE)
34 AC_SUBST(LIBOPUS_SUFFIX)
35
36 # For automake.
37 VERSION=$OPUS_VERSION
38 PACKAGE=opus
39
40 # For our version string
41 AC_SUBST(OPUS_VERSION)
42
43 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
44 AM_MAINTAINER_MODE
45
46 AC_CANONICAL_HOST
47 AM_PROG_LIBTOOL
48 AM_PROG_CC_C_O
49
50 AC_PROG_CC_C99
51 AC_C_BIGENDIAN
52 AC_C_CONST
53 AC_C_INLINE
54
55 #Use a hacked up version of autoconf's AC_C_RESTRICT because it's not
56 #strong enough a test to detect old buggy versions of GCC (e.g. 2.95.3)
57 AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
58   [ac_cv_c_restrict=no
59    # The order here caters to the fact that C++ does not require restrict.
60    for ac_kw in __restrict __restrict__ _Restrict restrict; do
61      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
62       [[typedef int * int_ptr;
63         int foo (int_ptr $ac_kw ip, int * $ac_kw baz[]) {
64         return ip[0];
65        }]],
66       [[int s[1];
67         int * $ac_kw t = s;
68         t[0] = 0;
69         return foo(t, (void *)0)]])],
70       [ac_cv_c_restrict=$ac_kw])
71      test "$ac_cv_c_restrict" != no && break
72    done
73   ])
74  AH_VERBATIM([restrict],
75 [/* Define to the equivalent of the C99 'restrict' keyword, or to
76    nothing if this is not supported.  Do not define if restrict is
77    supported directly.  */
78 #undef restrict
79 /* Work around a bug in Sun C++: it does not support _Restrict or
80    __restrict__, even though the corresponding Sun C compiler ends up with
81    "#define restrict _Restrict" or "#define restrict __restrict__" in the
82    previous line.  Perhaps some future version of Sun C++ will work with
83    restrict; if so, hopefully it defines __RESTRICT like Sun C does.  */
84 #if defined __SUNPRO_CC && !defined __RESTRICT
85 # define _Restrict
86 # define __restrict__
87 #endif])
88  case $ac_cv_c_restrict in
89    restrict) ;;
90    no) AC_DEFINE([restrict], []) ;;
91    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
92  esac
93
94 AC_DEFINE([OPUS_BUILD], [], [This is a build of OPUS])
95
96 AC_MSG_CHECKING(for C99 variable-size arrays)
97 AC_TRY_COMPILE( [], [static int x; char a[++x]; a[sizeof a - 1] = 0; int N; return a[0];],
98 [has_var_arrays=yes;AC_DEFINE([VAR_ARRAYS], [], [Use C99 variable-size arrays])
99 ],
100 has_var_arrays=no
101 )
102 AC_MSG_RESULT($has_var_arrays)
103
104 AC_CHECK_HEADERS([alloca.h getopt.h])
105 AC_MSG_CHECKING(for alloca)
106 AC_TRY_COMPILE( [#include <alloca.h>], [
107 int foo=10;
108 int *array = alloca(foo);
109 ],
110 [
111 has_alloca=yes;
112 if test x$has_var_arrays = "xno" ; then
113 AC_DEFINE([USE_ALLOCA], [], [Make use of alloca])
114 fi
115 ],
116 has_alloca=no
117 )
118 AC_MSG_RESULT($has_alloca)
119
120 AC_CHECK_FUNC(exp,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
121 if test x"$fp_libm_not_needed" = xdunno; then
122   AC_CHECK_LIB([m], [exp], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
123 fi
124 AC_SUBST([LIBM])
125
126 AC_DEFINE_UNQUOTED(OPUS_VERSION, "${OPUS_VERSION}", [Complete version string])
127 AC_DEFINE_UNQUOTED(OPUS_MAJOR_VERSION, ${OPUS_MAJOR_VERSION}, [Version major])
128 AC_DEFINE_UNQUOTED(OPUS_MINOR_VERSION, ${OPUS_MINOR_VERSION}, [Version minor])
129 AC_DEFINE_UNQUOTED(OPUS_MICRO_VERSION, ${OPUS_MICRO_VERSION}, [Version micro])
130 AC_DEFINE_UNQUOTED(OPUS_EXTRA_VERSION, "${OPUS_EXTRA_VERSION}", [Version extra])
131
132 has_float_approx=no
133 #case "$host_cpu" in
134 #i[[3456]]86 | x86_64 | powerpc64 | powerpc32 | ia64)
135 #  has_float_approx=yes
136 #  ;;
137 #esac    
138
139 ac_enable_fixed="no";
140 AC_ARG_ENABLE(fixed-point, [  --enable-fixed-point    compile as fixed-point],
141 [if test "$enableval" = yes; then
142   ac_enable_fixed="yes";
143   AC_DEFINE([FIXED_POINT], [1], [Compile as fixed-point])
144 else
145   AC_DEFINE([FLOATING_POINT], , [Compile as floating-point])
146 fi],
147 AC_DEFINE([FLOATING_POINT], , [Compile as floating-point]))
148
149 ac_enable_fixed_debug="no"
150 AC_ARG_ENABLE(fixed-point-debug, [  --enable-fixed-point-debug  debug fixed-point implementation],
151 [if test "$enableval" = yes; then
152   ac_enable_fixed_debug="yes"
153   AC_DEFINE([FIXED_DEBUG], , [Debug fixed-point implementation])
154 fi])
155
156 ac_enable_custom_modes="no"
157 AC_ARG_ENABLE(custom-modes, [  --enable-custom-modes        Enable non-Opus modes, like 44.1 kHz and powers of two ],
158 [if test "$enableval" = yes; then
159   ac_enable_custom_modes="yes"
160   AC_DEFINE([CUSTOM_MODES], , [Custom modes])
161 fi])
162
163 float_approx=$has_float_approx
164 AC_ARG_ENABLE(float-approx, [  --enable-float-approx   enable fast approximations for floating point],
165     [ if test "$enableval" = yes; then
166     AC_WARN([Floating point approximations are not supported on all platforms.])
167     float_approx=yes
168     else
169     float_approx=no
170     fi], [ float_approx=$has_float_approx ])
171
172 if test "x${float_approx}" = "xyes"; then
173     AC_DEFINE([FLOAT_APPROX], , [Float approximations])
174 fi
175
176 ac_enable_assertions="no"
177 AC_ARG_ENABLE(assertions, [  --enable-assertions     enable additional software error checking],
178 [if test "$enableval" = yes; then
179   ac_enable_assertions="yes"
180   AC_DEFINE([ENABLE_ASSERTIONS], , [Assertions])
181 fi])
182
183 ac_enable_fuzzing="no"
184 AC_ARG_ENABLE(fuzzing, [  --enable-fuzzing     causes the encoder to make random decisions],
185 [if test "$enableval" = yes; then
186   ac_enable_fuzzing="yes"
187   AC_DEFINE([FUZZING], , [Fuzzing])
188 fi])
189
190 ac_enable_doc="yes"
191 AC_ARG_ENABLE([doc],
192   AS_HELP_STRING([--disable-doc], [Do not build API documentation]),
193                  [ac_enable_doc=$enableval])
194 AC_CHECK_PROG(HAVE_DOXYGEN, [doxygen], [yes], [no])
195 if test "$HAVE_DOXYGEN" != "yes" -o "$ac_enable_doc" != "yes"; then
196   HAVE_DOXYGEN="false"
197   ac_enable_doc="no"
198 fi
199 AM_CONDITIONAL(HAVE_DOXYGEN, [test $HAVE_DOXYGEN = yes])
200
201 saved_CFLAGS="$CFLAGS"
202 CFLAGS="$CFLAGS -fvisibility=hidden"
203 AC_MSG_CHECKING([if ${CC} supports -fvisibility=hidden])
204 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
205       [ AC_MSG_RESULT([yes])
206         SYMBOL_VISIBILITY="-fvisibility=hidden" ],
207         AC_MSG_RESULT([no]))
208 CFLAGS="$saved_CFLAGS $SYMBOL_VISIBILITY"
209 AC_SUBST(SYMBOL_VISIBILITY)
210
211 if test $ac_cv_c_compiler_gnu = yes ; then
212 saved_CFLAGS="$CFLAGS"
213 CFLAGS="$CFLAGS -fstack-protector-all"
214 AC_MSG_CHECKING([if ${CC} supports -fstack-protector-all])
215 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
216       [ AC_MSG_RESULT([yes])
217         STACK_PROTECTOR="-fstack-protector-all" ],
218         AC_MSG_RESULT([no]))
219 CFLAGS="$saved_CFLAGS $STACK_PROTECTOR"
220 fi
221
222 CFLAGS="$CFLAGS -W"
223
224 saved_CFLAGS="$CFLAGS"
225 CFLAGS="$CFLAGS -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes"
226 AC_MSG_CHECKING([if ${CC} supports -Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes])
227 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
228       [ AC_MSG_RESULT([yes])
229         EXTRA_WARNS="-Wall -Wextra -Wcast-align -Wnested-externs -Wshadow -Wstrict-prototypes" ],
230         AC_MSG_RESULT([no]))
231 CFLAGS="$saved_CFLAGS $EXTRA_WARNS"
232
233 AC_CHECK_FUNCS([lrintf])
234 AC_CHECK_FUNCS([lrint])
235 AC_CHECK_FUNCS([__malloc_hook])
236
237 AC_CHECK_SIZEOF(short)
238 AC_CHECK_SIZEOF(int)
239 AC_CHECK_SIZEOF(long)
240 AC_CHECK_SIZEOF(long long)
241
242 if test x$has_char16 = "xyes" ; then
243         case 1 in
244                 $ac_cv_sizeof_short) SIZE16="short";;
245                 $ac_cv_sizeof_int) SIZE16="int";;
246         esac
247 else
248         case 2 in
249                 $ac_cv_sizeof_short) SIZE16="short";;
250                 $ac_cv_sizeof_int) SIZE16="int";;
251         esac
252 fi
253
254 if test x$has_char16 = "xyes" ; then
255         case 2 in
256                 $ac_cv_sizeof_int) SIZE32="int";;
257                 $ac_cv_sizeof_long) SIZE32="long";;
258                 $ac_cv_sizeof_short) SIZE32="short";;
259         esac
260 else
261         case 4 in
262                 $ac_cv_sizeof_int) SIZE32="int";;
263                 $ac_cv_sizeof_long) SIZE32="long";;
264                 $ac_cv_sizeof_short) SIZE32="short";;
265         esac
266 fi
267
268 AC_SUBST(SIZE16)
269 AC_SUBST(SIZE32)
270
271 AM_CONDITIONAL([FIXED_POINT], [test x$ac_enable_fixed = xyes])
272 AM_CONDITIONAL([CUSTOM_MODES], [test x$ac_enable_custom_modes = xyes])
273
274 AC_OUTPUT([Makefile opus.pc opus-uninstalled.pc
275            doc/Makefile doc/Doxyfile])
276
277 AC_MSG_RESULT([
278 ------------------------------------------------------------------------
279   $PACKAGE $VERSION:  Automatic configuration OK.
280   
281     Compiler support:
282
283       C99 var arrays: ................ ${has_var_arrays}
284       C99 lrintf: .................... ${ac_cv_func_lrintf}
285       Alloca: ........................ ${has_alloca}
286     
287     General configuration:
288     
289       Fast float approximations: ..... ${float_approx}
290       Fixed point support: ........... ${ac_enable_fixed}
291       Fixed point debugging: ......... ${ac_enable_fixed_debug}
292       Custom modes: .................. ${ac_enable_custom_modes}
293       Assertion checking: ............ ${ac_enable_assertions}
294       Fuzzing: ....................... ${ac_enable_fuzzing}
295
296       API documentation: ............. ${ac_enable_doc}
297 ------------------------------------------------------------------------
298 ])
299
300 echo "Type \"make; make install\" to compile and install";
301 echo "Type \"make check\" to run the test suite";