Fix a couple of NASM warnings.
[flac.git] / src / libFLAC / ia32 / cpu_asm.nasm
1 ;  vim:filetype=nasm ts=8
2
3 ;  libFLAC - Free Lossless Audio Codec library
4 ;  Copyright (C) 2001-2009  Josh Coalson
5 ;  Copyright (C) 2011-2013  Xiph.Org Foundation
6 ;
7 ;  Redistribution and use in source and binary forms, with or without
8 ;  modification, are permitted provided that the following conditions
9 ;  are met:
10 ;
11 ;  - Redistributions of source code must retain the above copyright
12 ;  notice, this list of conditions and the following disclaimer.
13 ;
14 ;  - Redistributions in binary form must reproduce the above copyright
15 ;  notice, this list of conditions and the following disclaimer in the
16 ;  documentation and/or other materials provided with the distribution.
17 ;
18 ;  - Neither the name of the Xiph.org Foundation nor the names of its
19 ;  contributors may be used to endorse or promote products derived from
20 ;  this software without specific prior written permission.
21 ;
22 ;  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
23 ;  ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
24 ;  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
25 ;  A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR
26 ;  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
27 ;  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
28 ;  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
29 ;  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
30 ;  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
31 ;  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
32 ;  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
33
34 %include "nasm.h"
35
36         data_section
37
38 cglobal FLAC__cpu_have_cpuid_asm_ia32
39 cglobal FLAC__cpu_info_asm_ia32
40 cglobal FLAC__cpu_info_extended_amd_asm_ia32
41
42         code_section
43
44 ; **********************************************************************
45 ;
46 ; FLAC__uint32 FLAC__cpu_have_cpuid_asm_ia32()
47 ;
48
49 cident FLAC__cpu_have_cpuid_asm_ia32
50         push    ebx
51         pushfd
52         pop     eax
53         mov     edx, eax
54         xor     eax, 0x00200000
55         push    eax
56         popfd
57         pushfd
58         pop     eax
59         cmp     eax, edx
60         jz      .no_cpuid
61         mov     eax, 1
62         jmp     .end
63 .no_cpuid:
64         xor     eax, eax
65 .end:
66         pop     ebx
67         ret
68
69 ; **********************************************************************
70 ;
71 ; void FLAC__cpu_info_asm_ia32(FLAC__uint32 *flags_edx, FLAC__uint32 *flags_ecx)
72 ;
73
74 cident FLAC__cpu_info_asm_ia32
75         ;[esp + 8] == flags_edx
76         ;[esp + 12] == flags_ecx
77
78         push    ebx
79         call    FLAC__cpu_have_cpuid_asm_ia32
80         test    eax, eax
81         jz      .no_cpuid
82         mov     eax, 1
83         cpuid
84         mov     ebx, [esp + 8]
85         mov     [ebx], edx
86         mov     ebx, [esp + 12]
87         mov     [ebx], ecx
88         jmp     .end
89 .no_cpuid:
90         xor     eax, eax
91         mov     ebx, [esp + 8]
92         mov     [ebx], eax
93         mov     ebx, [esp + 12]
94         mov     [ebx], eax
95 .end:
96         pop     ebx
97         ret
98
99 cident FLAC__cpu_info_extended_amd_asm_ia32
100         push    ebx
101         call    FLAC__cpu_have_cpuid_asm_ia32
102         test    eax, eax
103         jz      .no_cpuid
104         mov     eax, 0x80000000
105         cpuid
106         cmp     eax, 0x80000001
107         jb      .no_cpuid
108         mov     eax, 0x80000001
109         cpuid
110         mov     eax, edx
111         jmp     .end
112 .no_cpuid:
113         xor     eax, eax
114 .end:
115         pop     ebx
116         ret
117
118 ; end