remove unnecessary -fw option
[flac.git] / configure.in
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001  Josh Coalson
3 #
4 #  This program is part of FLAC; you can redistribute it and/or
5 #  modify it under the terms of the GNU General Public License
6 #  as published by the Free Software Foundation; either version 2
7 #  of the License, or (at your option) any later version.
8 #
9 #  This program is distributed in the hope that it will be useful,
10 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
11 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12 #  GNU General Public License for more details.
13 #
14 #  You should have received a copy of the GNU General Public License
15 #  along with this program; if not, write to the Free Software
16 #  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_INIT(src/flac/main.c)
22 AM_INIT_AUTOMAKE(flac, 1.0)
23
24 # We need two libtools, one that builds both shared and static, and
25 # one that builds only static.  This is because the resulting libtool
26 # does not allow us to choose which to build at runtime.
27 AM_PROG_LIBTOOL
28 sed -e 's/^build_old_libs=yes/build_old_libs=no/' libtool > libtool-disable-static
29 chmod +x libtool-disable-static
30
31 AC_PROG_MAKE_SET
32
33 AC_CANONICAL_HOST
34 case $host_cpu in
35         i*86)   cpu_ia32=true ; AC_DEFINE(FLAC__CPU_IA32) ;;
36         powerpc)        cpu_ppc=true ; AC_DEFINE(FLAC__CPU_PPC) ;;
37         sparc)  cpu_sparc=true ; AC_DEFINE(FLAC__CPU_SPARC) ;;
38 esac
39 AM_CONDITIONAL(FLaC__CPU_IA32, test x$cpu_ia32 = xtrue)
40 AM_CONDITIONAL(FLaC__CPU_PPC, test x$cpu_ppc = xtrue)
41 AM_CONDITIONAL(FLaC__CPU_SPARC, test x$cpu_sparc = xtrue)
42 case "$host" in
43         i[[3-6]]86-*-openbsd*) OBJ_FORMAT=aoutb ;;
44         *) OBJ_FORMAT=elf ;;
45 esac
46 AC_SUBST(OBJ_FORMAT)
47
48 if test x$cpu_ia32 = xtrue ; then
49 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
50 fi
51
52 AC_ARG_ENABLE(asm-optimizations, [  --disable-asm-optimizations    Don't use any assembly optimization routines], asm_opt=no, asm_opt=yes)
53 AM_CONDITIONAL(FLaC__NO_ASM, test x$asm_opt = xno)
54 if test x$asm_opt = xno ; then
55 AC_DEFINE(FLAC__NO_ASM)
56 fi
57
58 AC_ARG_ENABLE(debug,
59 [  --enable-debug                 Turn on debugging],
60 [case "${enableval}" in
61         yes) debug=true ;;
62         no)  debug=false ;;
63         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
64 esac],[debug=false])
65 AM_CONDITIONAL(DEBUG, test x$debug = xtrue)
66
67 AC_ARG_ENABLE(sse_os,
68 [  --sse-os                 Enable SSE support by asserting that the OS supports SSE instructions],
69 [case "${enableval}" in
70         yes) sse_os=true ;;
71         no)  sse_os=false ;;
72         *) AC_MSG_ERROR(bad value ${enableval} for --sse-os) ;;
73 esac],[sse_os=false])
74 AM_CONDITIONAL(FLaC__SSE_OS, test x$sse_os = xtrue)
75 if test x$sse_os = xtrue ; then
76 AC_DEFINE(FLAC__SSE_OS)
77 fi
78
79 AM_PATH_OGG( , AC_MSG_WARN([*** Ogg development enviroment not installed - ogg support will not be built]))
80 AM_CONDITIONAL(FLaC__HAS_OGG, test x$OGG_LIBS != x)
81
82 AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - xmms support will not be built]))
83 AM_CONDITIONAL(FLaC__HAS_XMMS, test x$XMMS_INPUT_PLUGIN_DIR != x)
84
85 AC_CHECK_PROGS(NASM, nasm)
86 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
87 if test -n "$NASM" ; then
88 AC_DEFINE(FLAC__HAS_NASM)
89 fi
90
91 dnl Check for type sizes
92
93 AC_CHECK_SIZEOF(short)
94 AC_CHECK_SIZEOF(int)
95 AC_CHECK_SIZEOF(long)
96 AC_CHECK_SIZEOF(long long)
97
98 case 2 in
99         $ac_cv_sizeof_short) FLaC__SIZE16="short" ; FLaC__USIZE16="unsigned short";;
100         $ac_cv_sizeof_int) FLaC__SIZE16="int" ; FLaC__USIZE16="unsigned int";;
101 esac
102
103 case 4 in
104         $ac_cv_sizeof_short) FLaC__SIZE32="short" ; FLaC__USIZE32="unsigned short";;
105         $ac_cv_sizeof_int) FLaC__SIZE32="int" ; FLaC__USIZE32="unsigned int";;
106         $ac_cv_sizeof_long) FLaC__SIZE32="long" ; FLaC__USIZE32="unsigned long";;
107 esac
108
109 case 8 in
110         $ac_cv_sizeof_int) FLaC__SIZE64="int" ; FLaC__USIZE64="unsigned int";;
111         $ac_cv_sizeof_long) FLaC__SIZE64="long" ; FLaC__USIZE64="unsigned long";;
112         $ac_cv_sizeof_long_long) FLaC__SIZE64="long long" ; FLaC__USIZE64="unsigned long long";;
113 esac
114
115 if test -z "$FLaC__SIZE16"; then
116         AC_MSG_ERROR(No 16 bit type found on this platform!)
117 fi
118 if test -z "$FLaC__USIZE16"; then
119         AC_MSG_ERROR(No unsigned 16 bit type found on this platform!)
120 fi
121 if test -z "$FLaC__SIZE32"; then
122         AC_MSG_ERROR(No 32 bit type found on this platform!)
123 fi
124 if test -z "$FLaC__USIZE32"; then
125         AC_MSG_ERROR(No unsigned 32 bit type found on this platform!)
126 fi
127 if test -z "$FLaC__SIZE64"; then
128         AC_MSG_WARN(No 64 bit type found on this platform!)
129 fi
130 if test -z "$FLaC__USIZE64"; then
131         AC_MSG_ERROR(No unsigned 64 bit type found on this platform!)
132 fi
133
134 AC_SUBST(FLaC__SIZE16)
135 AC_SUBST(FLaC__USIZE16)
136 AC_SUBST(FLaC__SIZE32)
137 AC_SUBST(FLaC__USIZE32)
138 AC_SUBST(FLaC__SIZE64)
139 AC_SUBST(FLaC__USIZE64)
140
141 SAVE_CFLAGS="$CFLAGS"
142 CFLAGS='-I$(top_builddir) -I$(srcdir)/include -I $(top_srcdir)/include -Wall -W'
143 if test x$debug = xtrue; then
144         CFLAGS="$CFLAGS -g -O0 -DDEBUG"
145 else
146         CFLAGS="$CFLAGS -O3 -DNDEBUG"
147         if test x$GCC = xyes; then
148                 CFLAGS="$CFLAGS -fomit-frame-pointer -funroll-loops -finline-functions -Winline -DFLaC__INLINE=__inline__"
149         fi
150 fi
151 CFLAGS="$CFLAGS $SAVE_CFLAGS"
152
153 AC_OUTPUT(      Makefile        \
154         src/Makefile    \
155         src/libFLAC/Makefile    \
156         src/libFLAC/ia32/Makefile       \
157         src/libFLAC/include/Makefile    \
158         src/libFLAC/include/private/Makefile    \
159         src/libFLAC/include/protected/Makefile  \
160         src/flac/Makefile       \
161         src/metaflac/Makefile   \
162         src/plugin_xmms/Makefile        \
163         src/test_streams/Makefile       \
164         src/test_unit/Makefile  \
165         include/Makefile \
166         include/FLAC/Makefile \
167         include/FLAC/ordinals.h \
168         doc/Makefile \
169         doc/images/Makefile \
170         doc/ru/Makefile \
171         man/Makefile \
172         test/Makefile   \
173 )