Fix/re-enable SSE/SSE2 lpc optimisations.
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.0], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.11 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 AC_PROG_MAKE_SET
39
40 AC_SYS_LARGEFILE
41 AC_FUNC_FSEEKO
42
43 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
44 AC_CHECK_SIZEOF([void*])
45 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
46
47 AC_LANG_PUSH([C++])
48 # c++ flavor first
49 AC_C_VARARRAYS
50 if test $ac_cv_c_vararrays = yes; then
51         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
52 fi
53 AC_LANG_POP([C++])
54
55 # c flavor
56 AC_HEADER_STDC
57 AM_PROG_CC_C_O
58 AC_C_INLINE
59 AC_C_VARARRAYS
60 AC_C_TYPEOF
61
62 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h termios.h x86intrin.h])
63
64 AC_HEADER_TIOCGWINSZ
65
66 XIPH_C_BSWAP32
67
68 ac_cv_c_big_endian=0
69 ac_cv_c_little_endian=0
70 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
71         AC_MSG_WARN([[*****************************************************************]])
72         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
73         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
74         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
75         AC_MSG_WARN([[*****************************************************************]])
76 ])
77 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
78                                         [Target processor is big endian.])
79 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
80                                         [Target processor is little endian.])
81 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
82                                         [Target processor is big endian.])
83
84 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
85 dnl ' Terminate the damn single quote
86 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
87 if test "x$asm_opt" = xno ; then
88 AC_DEFINE(FLAC__NO_ASM)
89 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
90 fi
91
92 # For the XMMS plugin.
93 AC_CHECK_TYPES(socklen_t, [], [])
94
95 dnl check for getopt in standard library
96 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
97 AC_CHECK_FUNCS(getopt_long, [], [])
98
99 AC_CHECK_SIZEOF(void*,1)
100
101 asm_optimisation=no
102 case "$host_cpu" in
103         x86_64)
104                 if test $ac_cv_sizeof_voidp = 4 ; then
105                         # This must be a 32 bit user space running on 64 bit kernel so treat
106                         # this as ia32.
107                         cpu_ia32=true
108                         AC_DEFINE(FLAC__CPU_IA32)
109                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
110                 else
111                         # x86_64 user space and kernel.
112                         cpu_x86_64=true
113                         AC_DEFINE(FLAC__CPU_X86_64)
114                         AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
115                         fi
116                 asm_optimisation=$asm_opt
117                 ;;
118         i*86)
119                 cpu_ia32=true
120                 AC_DEFINE(FLAC__CPU_IA32)
121                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
122                 asm_optimisation=$asm_opt
123                 ;;
124         powerpc|powerpc64)
125                 cpu_ppc=true
126                 AC_DEFINE(FLAC__CPU_PPC)
127                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
128                 asm_optimisation=$asm_opt
129                 ;;
130         sparc)
131                 cpu_sparc=true
132                 AC_DEFINE(FLAC__CPU_SPARC)
133                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
134                 asm_optimisation=$asm_opt
135                 ;;
136 esac
137 AM_CONDITIONAL(FLAC__CPU_X86_64, test "x$cpu_x86_64" = xtrue)
138 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
139 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
140 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
141
142 AC_DEFINE_UNQUOTED([FLAC__HAS_X86INTRIN],${HAVE_X86INTRIN_H}, [Set to 1 if <x86intrin.h> is available.])
143
144 case "$host" in
145         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
146         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
147         *-*-darwin*) OBJ_FORMAT=macho ;;
148         *emx*) OBJ_FORMAT=aout ;;
149         *) OBJ_FORMAT=elf ;;
150 esac
151 AC_SUBST(OBJ_FORMAT)
152 case "$host" in
153         *-gnuspe)
154                 abi_spe=true
155                 AC_DEFINE(FLAC__CPU_PPC_SPE)
156                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
157                 ;;
158 esac
159 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
160
161 os_is_windows=no
162 case "$host" in
163         *-*-cygwin|*mingw*)
164                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
165                 os_is_windows=yes
166                 ;;
167 esac
168
169 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
170
171 case "$host" in
172         *-pc-linux-gnu)
173                 sys_linux=true
174                 AC_DEFINE(FLAC__SYS_LINUX)
175                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
176                 ;;
177         *-*-darwin*)
178                 sys_darwin=true
179                 AC_DEFINE(FLAC__SYS_DARWIN)
180                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
181                 ;;
182 esac
183 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
184 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
185
186 if test "x$cpu_ia32" = xtrue ; then
187 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
188 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
189 fi
190
191 AC_ARG_ENABLE(debug,
192 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
193 [case "${enableval}" in
194         yes) debug=true ;;
195         no)  debug=false ;;
196         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
197 esac],[debug=false])
198 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
199
200 AC_ARG_ENABLE(sse,
201 AC_HELP_STRING([--enable-sse], [Enable SSE support by asserting that the OS supports SSE instructions]),
202 [case "${enableval}" in
203         yes) sse_os=true ;;
204         no)  sse_os=false ;;
205         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
206 esac],[sse_os=false])
207 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
208 if test "x$sse_os" = xtrue ; then
209 AC_DEFINE(FLAC__SSE_OS)
210 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
211 fi
212
213 AC_ARG_ENABLE(3dnow,
214 AC_HELP_STRING([--disable-3dnow], [Disable 3DNOW! optimizations]),
215 [case "${enableval}" in
216         yes) use_3dnow=true ;;
217         no)  use_3dnow=false ;;
218         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
219 esac],[use_3dnow=true])
220 AM_CONDITIONAL(FLaC__USE_3DNOW, test "x$use_3dnow" = xtrue)
221 if test "x$use_3dnow" = xtrue ; then
222 AC_DEFINE(FLAC__USE_3DNOW)
223 AH_TEMPLATE(FLAC__USE_3DNOW, [define to enable use of 3Dnow! instructions])
224 fi
225
226 AC_ARG_ENABLE(altivec,
227 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
228 [case "${enableval}" in
229         yes) use_altivec=true ;;
230         no)  use_altivec=false ;;
231         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
232 esac],[use_altivec=true])
233 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
234 if test "x$use_altivec" = xtrue ; then
235 AC_DEFINE(FLAC__USE_ALTIVEC)
236 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
237 fi
238
239 AC_ARG_ENABLE(thorough-tests,
240 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
241 [case "${enableval}" in
242         yes) thorough_tests=true ;;
243         no)  thorough_tests=false ;;
244         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
245 esac],[thorough_tests=true])
246 AC_ARG_ENABLE(exhaustive-tests,
247 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
248 [case "${enableval}" in
249         yes) exhaustive_tests=true ;;
250         no)  exhaustive_tests=false ;;
251         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
252 esac],[exhaustive_tests=false])
253 if test "x$thorough_tests" = xfalse ; then
254 FLAC__TEST_LEVEL=0
255 elif test "x$exhaustive_tests" = xfalse ; then
256 FLAC__TEST_LEVEL=1
257 else
258 FLAC__TEST_LEVEL=2
259 fi
260 AC_SUBST(FLAC__TEST_LEVEL)
261
262 AC_ARG_ENABLE(gcc-werror,
263         AC_HELP_STRING([--enable-gcc-werror], [Enable -Werror in all Makefiles]))
264
265 AC_ARG_ENABLE(stack-smash-protection,
266         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
267
268 AC_ARG_ENABLE(valgrind-testing,
269 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
270 [case "${enableval}" in
271         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
272         no)  FLAC__TEST_WITH_VALGRIND=no ;;
273         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
274 esac],[FLAC__TEST_WITH_VALGRIND=no])
275 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
276
277 AC_ARG_ENABLE(doxygen-docs,
278 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
279 [case "${enableval}" in
280         yes) enable_doxygen_docs=true ;;
281         no)  enable_doxygen_docs=false ;;
282         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
283 esac],[enable_doxygen_docs=true])
284 if test "x$enable_doxygen_docs" != xfalse ; then
285         AC_CHECK_PROGS(DOXYGEN, doxygen)
286 fi
287 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
288
289 AC_ARG_ENABLE(local-xmms-plugin,
290 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
291 [case "${enableval}" in
292         yes) install_xmms_plugin_locally=true ;;
293         no)  install_xmms_plugin_locally=false ;;
294         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
295 esac],[install_xmms_plugin_locally=false])
296 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
297
298 AC_ARG_ENABLE(xmms-plugin,
299 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
300 [case "${enableval}" in
301         yes) enable_xmms_plugin=true ;;
302         no)  enable_xmms_plugin=false ;;
303         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
304 esac],[enable_xmms_plugin=true])
305 if test "x$enable_xmms_plugin" != xfalse ; then
306         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
307 fi
308 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
309
310 dnl build FLAC++ or not
311 AC_ARG_ENABLE([cpplibs],
312 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
313 [case "${enableval}" in
314         yes) disable_cpplibs=false ;;
315         no)  disable_cpplibs=true ;;
316         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
317 esac], [disable_cpplibs=false])
318 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
319
320 dnl check for ogg library
321 AC_ARG_ENABLE([ogg],
322         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
323         [ want_ogg=$enableval ], [ want_ogg=yes ] )
324
325 if test "x$want_ogg" != "xno"; then
326         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
327 fi
328
329 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
330 if test "x$have_ogg" = xyes ; then
331         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
332         OGG_PACKAGE="ogg"
333 else
334         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
335         have_ogg=no
336 fi
337 AC_SUBST(OGG_PACKAGE)
338
339 dnl check for i18n(internationalization); these are from libiconv/gettext
340 AM_ICONV
341 AM_LANGINFO_CODESET
342
343 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
344 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
345 if test -n "$DOCBOOK_TO_MAN" ; then
346 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
347 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
348 fi
349
350 # only matters for x86
351 AC_CHECK_PROGS(NASM, nasm)
352 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
353 if test -n "$NASM" ; then
354 AC_DEFINE(FLAC__HAS_NASM)
355 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
356 fi
357
358 # only matters for PowerPC
359 AC_CHECK_PROGS(AS, as, as)
360 AC_CHECK_PROGS(GAS, gas, gas)
361
362 # try -v (apple as) and --version (gas) at the same time
363 test "$AS" = "as" && as --version -v < /dev/null 2>&1 | grep Apple >/dev/null || AS=gas
364
365 AM_CONDITIONAL(FLaC__HAS_AS, test "$AS" = "as")
366 AM_CONDITIONAL(FLaC__HAS_GAS, test "$AS" = "gas")
367 if test "$AS" = "as" ; then
368 AC_DEFINE(FLAC__HAS_AS)
369 AH_TEMPLATE(FLAC__HAS_AS, [define if you are compiling for PowerPC and have the 'as' assembler])
370 fi
371 if test "$AS" = "gas" ; then
372 # funniest. macro. ever.
373 AC_DEFINE(FLAC__HAS_GAS)
374 AH_TEMPLATE(FLAC__HAS_GAS, [define if you are compiling for PowerPC and have the 'gas' assembler])
375 fi
376
377 if test "x$debug" = xtrue; then
378         CPPFLAGS="-DDEBUG $CPPFLAGS"
379         CFLAGS="-g $CFLAGS"
380 else
381         CPPFLAGS="-DNDEBUG $CPPFLAGS"
382         if test "x$GCC" = xyes; then
383                 if test "x$user_cflags" = x; then
384                         CFLAGS="-O3 -funroll-loops -Wall -W -Winline"
385                 fi
386         fi
387 fi
388
389 XIPH_GCC_VERSION
390
391 if test x$ac_cv_c_compiler_gnu = xyes ; then
392         CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Winline -Wconversion
393         CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
394
395
396         if test x$enable_gcc_werror = "xyes" ; then
397                 CFLAGS="$CFLAGS -Werror "
398                 CXXFLAGS="$CXXFLAGS -Werror "
399                 fi
400
401         XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
402         XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
403
404         AC_LANG_PUSH([C++])
405         XIPH_ADD_CXXFLAGS([-Weffc++])
406         AC_LANG_POP([C++])
407
408         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
409                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
410                 CFLAGS="$CFLAGS -fvisibility=hidden"
411                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
412                 fi
413
414         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
415                 XIPH_ADD_CFLAGS([-fgnu89-inline])
416                 fi
417
418         if test "x$asm_optimisation" = "xyes" ; then
419                 XIPH_ADD_CFLAGS([-msse])
420                 XIPH_ADD_CFLAGS([-msse2])
421                 fi
422
423         fi
424
425 XIPH_ADD_CFLAGS([-Wextra])
426
427 if test x$enable_stack_smash_protection = "xyes" ; then
428         XIPH_GCC_STACK_PROTECTOR
429         XIPH_GXX_STACK_PROTECTOR
430         fi
431
432 #@@@
433 AM_CONDITIONAL(FLaC__HAS_AS__TEMPORARILY_DISABLED, test "yes" = "no")
434 AM_CONDITIONAL(FLaC__HAS_GAS__TEMPORARILY_DISABLED, test "yes" = "no")
435
436 AC_CONFIG_FILES([ \
437         Makefile \
438         src/Makefile \
439         src/libFLAC/Makefile \
440         src/libFLAC/flac.pc \
441         src/libFLAC/ia32/Makefile \
442         src/libFLAC/ppc/Makefile \
443         src/libFLAC/ppc/as/Makefile \
444         src/libFLAC/ppc/gas/Makefile \
445         src/libFLAC/include/Makefile \
446         src/libFLAC/include/private/Makefile \
447         src/libFLAC/include/protected/Makefile \
448         src/libFLAC++/Makefile \
449         src/libFLAC++/flac++.pc \
450         src/flac/Makefile \
451         src/metaflac/Makefile \
452         src/monkeys_audio_utilities/Makefile \
453         src/monkeys_audio_utilities/flac_mac/Makefile \
454         src/monkeys_audio_utilities/flac_ren/Makefile \
455         src/plugin_common/Makefile \
456         src/plugin_xmms/Makefile \
457         src/share/Makefile \
458         src/test_grabbag/Makefile \
459         src/test_grabbag/cuesheet/Makefile \
460         src/test_grabbag/picture/Makefile \
461         src/test_libs_common/Makefile \
462         src/test_libFLAC/Makefile \
463         src/test_libFLAC++/Makefile \
464         src/test_seeking/Makefile \
465         src/test_streams/Makefile \
466         src/utils/Makefile \
467         src/utils/flacdiff/Makefile \
468         src/utils/flactimer/Makefile \
469         examples/Makefile \
470         examples/c/Makefile \
471         examples/c/decode/Makefile \
472         examples/c/decode/file/Makefile \
473         examples/c/encode/Makefile \
474         examples/c/encode/file/Makefile \
475         examples/cpp/Makefile \
476         examples/cpp/decode/Makefile \
477         examples/cpp/decode/file/Makefile \
478         examples/cpp/encode/Makefile \
479         examples/cpp/encode/file/Makefile \
480         include/Makefile \
481         include/FLAC/Makefile \
482         include/FLAC++/Makefile \
483         include/share/Makefile \
484         include/share/grabbag/Makefile \
485         include/test_libs_common/Makefile \
486         doc/Doxyfile \
487         doc/Makefile \
488         doc/html/Makefile \
489         doc/html/images/Makefile \
490         doc/html/images/hw/Makefile \
491         doc/html/ru/Makefile \
492         m4/Makefile \
493         man/Makefile \
494         test/Makefile \
495         test/cuesheets/Makefile \
496         test/flac-to-flac-metadata-test-files/Makefile \
497         test/metaflac-test-files/Makefile \
498         test/pictures/Makefile \
499         build/Makefile \
500         objs/Makefile \
501         objs/debug/Makefile \
502         objs/debug/bin/Makefile \
503         objs/debug/lib/Makefile \
504         objs/release/Makefile \
505         objs/release/bin/Makefile \
506         objs/release/lib/Makefile \
507 ])
508 AC_OUTPUT
509
510 AC_MSG_RESULT([
511 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
512
513   Configuration summary :
514
515     FLAC version : ........................ ${VERSION}
516
517     Host CPU : ............................ ${host_cpu}
518     Host Vendor : ......................... ${host_vendor}
519     Host OS : ............................. ${host_os}
520 ])
521
522         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
523 if test x$ac_cv_c_compiler_gnu = xyes ; then
524         echo "    GCC version : ......................... ${GCC_VERSION}"
525 fi
526         echo "    Asm optimiizations : .................. ${asm_optimisation}"
527         echo "    Ogg/FLAC support : .................... ${have_ogg}"
528 echo