Fix pkg-config files to avoid overlinking
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under difference licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.0pre3], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.11 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 AC_PROG_MAKE_SET
39
40 AC_SYS_LARGEFILE
41 AC_FUNC_FSEEKO
42
43 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
44 AC_CHECK_SIZEOF([void*])
45 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
46
47 AC_LANG_PUSH([C++])
48 # c++ flavor first
49 AC_C_VARARRAYS
50 if test $ac_cv_c_vararrays = yes; then
51         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
52 fi
53 AC_LANG_POP([C++])
54
55 # c flavor
56 AC_HEADER_STDC
57 AM_PROG_CC_C_O
58 AC_C_INLINE
59 AC_C_VARARRAYS
60 AC_C_TYPEOF
61
62 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h])
63
64 XIPH_C_BSWAP32
65
66 ac_cv_c_big_endian=0
67 ac_cv_c_little_endian=0
68 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
69         AC_MSG_WARN([[*****************************************************************]])
70         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
71         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
72         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
73         AC_MSG_WARN([[*****************************************************************]])
74 ])
75 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
76                                         [Target processor is big endian.])
77 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
78                                         [Target processor is little endian.])
79 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
80                                         [Target processor is big endian.])
81
82 # For the XMMS plugin.
83 AC_CHECK_TYPES(socklen_t, [], [])
84
85 dnl check for getopt in standard library
86 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
87 AC_CHECK_FUNCS(getopt_long, [], [])
88
89 case "$host_cpu" in
90         i*86)
91                 cpu_ia32=true
92                 AC_DEFINE(FLAC__CPU_IA32)
93                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
94                 ;;
95         powerpc|powerpc64)
96                 cpu_ppc=true
97                 AC_DEFINE(FLAC__CPU_PPC)
98                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
99                 ;;
100         sparc)
101                 cpu_sparc=true
102                 AC_DEFINE(FLAC__CPU_SPARC)
103                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
104                 ;;
105 esac
106 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
107 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
108 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
109
110 case "$host" in
111         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
112         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
113         *-*-darwin*) OBJ_FORMAT=macho ;;
114         *emx*) OBJ_FORMAT=aout ;;
115         *) OBJ_FORMAT=elf ;;
116 esac
117 AC_SUBST(OBJ_FORMAT)
118 case "$host" in
119         *-gnuspe)
120                 abi_spe=true
121                 AC_DEFINE(FLAC__CPU_PPC_SPE)
122                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
123                 ;;
124 esac
125 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
126
127 os_is_windows=no
128 case "$host" in
129         *-*-cygwin|*mingw*|*emx*)
130                 # define this variable for enabling strict exports with libtool; for now, it's supported by Win32 and OS/2
131                 LT_NO_UNDEFINED="-no-undefined"
132                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
133                 os_is_windows=yes
134                 ;;
135         *)
136                 LT_NO_UNDEFINED=
137                 ;;
138 esac
139 AC_SUBST(LT_NO_UNDEFINED)
140 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
141
142 case "$host" in
143         *-pc-linux-gnu)
144                 sys_linux=true
145                 AC_DEFINE(FLAC__SYS_LINUX)
146                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
147                 ;;
148         *-*-darwin*)
149                 sys_darwin=true
150                 AC_DEFINE(FLAC__SYS_DARWIN)
151                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
152                 ;;
153 esac
154 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
155 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
156
157 if test "x$cpu_ia32" = xtrue ; then
158 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
159 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
160 fi
161
162 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
163 dnl ' Terminate the damn single quote
164 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
165 if test "x$asm_opt" = xno ; then
166 AC_DEFINE(FLAC__NO_ASM)
167 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
168 fi
169
170 AC_ARG_ENABLE(debug,
171 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
172 [case "${enableval}" in
173         yes) debug=true ;;
174         no)  debug=false ;;
175         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
176 esac],[debug=false])
177 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
178
179 AC_ARG_ENABLE(sse,
180 AC_HELP_STRING([--enable-sse], [Enable SSE support by asserting that the OS supports SSE instructions]),
181 [case "${enableval}" in
182         yes) sse_os=true ;;
183         no)  sse_os=false ;;
184         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
185 esac],[sse_os=false])
186 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
187 if test "x$sse_os" = xtrue ; then
188 AC_DEFINE(FLAC__SSE_OS)
189 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
190 fi
191
192 AC_ARG_ENABLE(3dnow,
193 AC_HELP_STRING([--disable-3dnow], [Disable 3DNOW! optimizations]),
194 [case "${enableval}" in
195         yes) use_3dnow=true ;;
196         no)  use_3dnow=false ;;
197         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
198 esac],[use_3dnow=true])
199 AM_CONDITIONAL(FLaC__USE_3DNOW, test "x$use_3dnow" = xtrue)
200 if test "x$use_3dnow" = xtrue ; then
201 AC_DEFINE(FLAC__USE_3DNOW)
202 AH_TEMPLATE(FLAC__USE_3DNOW, [define to enable use of 3Dnow! instructions])
203 fi
204
205 AC_ARG_ENABLE(altivec,
206 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
207 [case "${enableval}" in
208         yes) use_altivec=true ;;
209         no)  use_altivec=false ;;
210         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
211 esac],[use_altivec=true])
212 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
213 if test "x$use_altivec" = xtrue ; then
214 AC_DEFINE(FLAC__USE_ALTIVEC)
215 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
216 fi
217
218 AC_ARG_ENABLE(thorough-tests,
219 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
220 [case "${enableval}" in
221         yes) thorough_tests=true ;;
222         no)  thorough_tests=false ;;
223         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
224 esac],[thorough_tests=true])
225 AC_ARG_ENABLE(exhaustive-tests,
226 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
227 [case "${enableval}" in
228         yes) exhaustive_tests=true ;;
229         no)  exhaustive_tests=false ;;
230         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
231 esac],[exhaustive_tests=false])
232 if test "x$thorough_tests" = xfalse ; then
233 FLAC__TEST_LEVEL=0
234 elif test "x$exhaustive_tests" = xfalse ; then
235 FLAC__TEST_LEVEL=1
236 else
237 FLAC__TEST_LEVEL=2
238 fi
239 AC_SUBST(FLAC__TEST_LEVEL)
240
241 AC_ARG_ENABLE(gcc-werror,
242         AC_HELP_STRING([--enable-gcc-werror], [Enable -Werror in all Makefiles]))
243
244 AC_ARG_ENABLE(stack-smash-protection,
245         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
246
247 AC_ARG_ENABLE(valgrind-testing,
248 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
249 [case "${enableval}" in
250         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
251         no)  FLAC__TEST_WITH_VALGRIND=no ;;
252         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
253 esac],[FLAC__TEST_WITH_VALGRIND=no])
254 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
255
256 AC_ARG_ENABLE(doxygen-docs,
257 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
258 [case "${enableval}" in
259         yes) enable_doxygen_docs=true ;;
260         no)  enable_doxygen_docs=false ;;
261         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
262 esac],[enable_doxygen_docs=true])
263 if test "x$enable_doxygen_docs" != xfalse ; then
264         AC_CHECK_PROGS(DOXYGEN, doxygen)
265 fi
266 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
267
268 AC_ARG_ENABLE(local-xmms-plugin,
269 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
270 [case "${enableval}" in
271         yes) install_xmms_plugin_locally=true ;;
272         no)  install_xmms_plugin_locally=false ;;
273         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
274 esac],[install_xmms_plugin_locally=false])
275 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
276
277 AC_ARG_ENABLE(xmms-plugin,
278 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
279 [case "${enableval}" in
280         yes) enable_xmms_plugin=true ;;
281         no)  enable_xmms_plugin=false ;;
282         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
283 esac],[enable_xmms_plugin=true])
284 if test "x$enable_xmms_plugin" != xfalse ; then
285         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
286 fi
287 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
288
289 dnl build FLAC++ or not
290 AC_ARG_ENABLE([cpplibs],
291 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
292 [case "${enableval}" in
293         yes) disable_cpplibs=false ;;
294         no)  disable_cpplibs=true ;;
295         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
296 esac], [disable_cpplibs=false])
297 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
298
299 dnl check for ogg library
300 AC_ARG_ENABLE([ogg],
301         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
302         [ want_ogg=$enableval ], [ want_ogg=yes ] )
303
304 if test "x$want_ogg" != "xno"; then
305         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
306 fi
307
308 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
309 if test "x$have_ogg" = xyes ; then
310         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
311         OGG_PACKAGE="ogg"
312 else
313         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
314 fi
315 AC_SUBST(OGG_PACKAGE)
316
317 dnl check for i18n(internationalization); these are from libiconv/gettext
318 AM_ICONV
319 AM_LANGINFO_CODESET
320
321 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
322 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
323 if test -n "$DOCBOOK_TO_MAN" ; then
324 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
325 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
326 fi
327
328 # only matters for x86
329 AC_CHECK_PROGS(NASM, nasm)
330 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
331 if test -n "$NASM" ; then
332 AC_DEFINE(FLAC__HAS_NASM)
333 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
334 fi
335
336 # only matters for PowerPC
337 AC_CHECK_PROGS(AS, as, as)
338 AC_CHECK_PROGS(GAS, gas, gas)
339
340 # try -v (apple as) and --version (gas) at the same time
341 test "$AS" = "as" && as --version -v < /dev/null 2>&1 | grep Apple >/dev/null || AS=gas
342
343 AM_CONDITIONAL(FLaC__HAS_AS, test "$AS" = "as")
344 AM_CONDITIONAL(FLaC__HAS_GAS, test "$AS" = "gas")
345 if test "$AS" = "as" ; then
346 AC_DEFINE(FLAC__HAS_AS)
347 AH_TEMPLATE(FLAC__HAS_AS, [define if you are compiling for PowerPC and have the 'as' assembler])
348 fi
349 if test "$AS" = "gas" ; then
350 # funniest. macro. ever.
351 AC_DEFINE(FLAC__HAS_GAS)
352 AH_TEMPLATE(FLAC__HAS_GAS, [define if you are compiling for PowerPC and have the 'gas' assembler])
353 fi
354
355 if test "x$debug" = xtrue; then
356         CPPFLAGS="-DDEBUG $CPPFLAGS"
357         CFLAGS="-g $CFLAGS"
358 else
359         CPPFLAGS="-DNDEBUG $CPPFLAGS"
360         if test "x$GCC" = xyes; then
361                 if test "x$user_cflags" = x; then
362                         CFLAGS="-O3 -funroll-loops -Wall -W -Winline"
363                 fi
364         fi
365 fi
366
367 XIPH_GCC_VERSION
368
369 if test x$ac_cv_c_compiler_gnu = xyes ; then
370         CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Winline -Wconversion
371         CXXFLAGS="$CXXFLAGS -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
372
373
374         if test x$enable_gcc_werror = "xyes" ; then
375                 CFLAGS="$CFLAGS -Wall -Wextra -Werror "
376                 CXXFLAGS="$CXXFLAGS -Wall -Wextra -Werror "
377                 fi
378
379         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
380                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
381                 CFLAGS="$CFLAGS -fvisibility=hidden"
382                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
383                 fi
384
385         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
386                 XIPH_ADD_CFLAGS([-fgnu89-inline])
387                 fi
388         fi
389
390
391 XIPH_ADD_CFLAGS([-Wextra])
392 XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
393 XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
394
395 if test x$enable_stack_smash_protection = "xyes" ; then
396         XIPH_GCC_STACK_PROTECTOR
397         XIPH_GXX_STACK_PROTECTOR
398         fi
399
400 #@@@
401 AM_CONDITIONAL(FLaC__HAS_AS__TEMPORARILY_DISABLED, test "yes" = "no")
402 AM_CONDITIONAL(FLaC__HAS_GAS__TEMPORARILY_DISABLED, test "yes" = "no")
403
404 AC_CONFIG_FILES([ \
405         Makefile \
406         src/Makefile \
407         src/libFLAC/Makefile \
408         src/libFLAC/flac.pc \
409         src/libFLAC/ia32/Makefile \
410         src/libFLAC/ppc/Makefile \
411         src/libFLAC/ppc/as/Makefile \
412         src/libFLAC/ppc/gas/Makefile \
413         src/libFLAC/include/Makefile \
414         src/libFLAC/include/private/Makefile \
415         src/libFLAC/include/protected/Makefile \
416         src/libFLAC++/Makefile \
417         src/libFLAC++/flac++.pc \
418         src/flac/Makefile \
419         src/metaflac/Makefile \
420         src/monkeys_audio_utilities/Makefile \
421         src/monkeys_audio_utilities/flac_mac/Makefile \
422         src/monkeys_audio_utilities/flac_ren/Makefile \
423         src/plugin_common/Makefile \
424         src/plugin_xmms/Makefile \
425         src/share/Makefile \
426         src/test_grabbag/Makefile \
427         src/test_grabbag/cuesheet/Makefile \
428         src/test_grabbag/picture/Makefile \
429         src/test_libs_common/Makefile \
430         src/test_libFLAC/Makefile \
431         src/test_libFLAC++/Makefile \
432         src/test_seeking/Makefile \
433         src/test_streams/Makefile \
434         src/utils/Makefile \
435         src/utils/flacdiff/Makefile \
436         src/utils/flactimer/Makefile \
437         examples/Makefile \
438         examples/c/Makefile \
439         examples/c/decode/Makefile \
440         examples/c/decode/file/Makefile \
441         examples/c/encode/Makefile \
442         examples/c/encode/file/Makefile \
443         examples/cpp/Makefile \
444         examples/cpp/decode/Makefile \
445         examples/cpp/decode/file/Makefile \
446         examples/cpp/encode/Makefile \
447         examples/cpp/encode/file/Makefile \
448         include/Makefile \
449         include/FLAC/Makefile \
450         include/FLAC++/Makefile \
451         include/share/Makefile \
452         include/share/grabbag/Makefile \
453         include/test_libs_common/Makefile \
454         doc/Doxyfile \
455         doc/Makefile \
456         doc/html/Makefile \
457         doc/html/images/Makefile \
458         doc/html/images/hw/Makefile \
459         doc/html/ru/Makefile \
460         m4/Makefile \
461         man/Makefile \
462         test/Makefile \
463         test/cuesheets/Makefile \
464         test/flac-to-flac-metadata-test-files/Makefile \
465         test/metaflac-test-files/Makefile \
466         test/pictures/Makefile \
467         build/Makefile \
468         objs/Makefile \
469         objs/debug/Makefile \
470         objs/debug/bin/Makefile \
471         objs/debug/lib/Makefile \
472         objs/release/Makefile \
473         objs/release/bin/Makefile \
474         objs/release/lib/Makefile \
475 ])
476 AC_OUTPUT
477
478 AC_MSG_RESULT([
479 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
480
481   Configuration summary :
482
483     FLAC version : ........................ ${VERSION}
484
485     Host CPU : ............................ ${host_cpu}
486     Host Vendor : ......................... ${host_vendor}
487     Host OS : ............................. ${host_os}
488 ])
489
490         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
491 if test x$ac_cv_c_compiler_gnu = xyes ; then
492         echo "    GCC version : ......................... ${GCC_VERSION}"
493 fi
494 echo