configure.ac : Version 1.3.0pre3.
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under difference licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.0pre3], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.11 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 AC_PROG_MAKE_SET
39
40 AC_SYS_LARGEFILE
41 AC_FUNC_FSEEKO
42
43 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
44 AC_CHECK_SIZEOF([void*])
45 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
46
47 AC_LANG_PUSH([C++])
48 # c++ flavor first
49 AC_C_VARARRAYS
50 if test $ac_cv_c_vararrays = yes; then
51         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
52 fi
53 AC_LANG_POP([C++])
54
55 # c flavor
56 AC_HEADER_STDC
57 AM_PROG_CC_C_O
58 AC_C_INLINE
59 AC_C_VARARRAYS
60 AC_C_TYPEOF
61
62 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h])
63
64 XIPH_C_BSWAP32
65
66 ac_cv_c_big_endian=0
67 ac_cv_c_little_endian=0
68 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
69         AC_MSG_WARN([[*****************************************************************]])
70         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
71         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
72         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
73         AC_MSG_WARN([[*****************************************************************]])
74 ])
75 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
76                                         [Target processor is big endian.])
77 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
78                                         [Target processor is little endian.])
79 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
80                                         [Target processor is big endian.])
81
82 # For the XMMS plugin.
83 AC_CHECK_TYPES(socklen_t, [], [])
84
85 dnl check for getopt in standard library
86 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
87 AC_CHECK_FUNCS(getopt_long, [], [])
88
89 case "$host_cpu" in
90         i*86)
91                 cpu_ia32=true
92                 AC_DEFINE(FLAC__CPU_IA32)
93                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
94                 ;;
95         powerpc|powerpc64)
96                 cpu_ppc=true
97                 AC_DEFINE(FLAC__CPU_PPC)
98                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
99                 ;;
100         sparc)
101                 cpu_sparc=true
102                 AC_DEFINE(FLAC__CPU_SPARC)
103                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
104                 ;;
105 esac
106 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
107 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
108 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
109
110 case "$host" in
111         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
112         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
113         *-*-darwin*) OBJ_FORMAT=macho ;;
114         *emx*) OBJ_FORMAT=aout ;;
115         *) OBJ_FORMAT=elf ;;
116 esac
117 AC_SUBST(OBJ_FORMAT)
118 case "$host" in
119         *-gnuspe)
120                 abi_spe=true
121                 AC_DEFINE(FLAC__CPU_PPC_SPE)
122                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
123                 ;;
124 esac
125 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
126
127 os_is_windows=no
128 case "$host" in
129         *-*-cygwin|*mingw*|*emx*)
130                 # define this variable for enabling strict exports with libtool; for now, it's supported by Win32 and OS/2
131                 LT_NO_UNDEFINED="-no-undefined"
132                 os_is_windows=yes
133                 ;;
134         *)
135                 LT_NO_UNDEFINED=
136                 ;;
137 esac
138 AC_SUBST(LT_NO_UNDEFINED)
139 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
140
141 case "$host" in
142         *-pc-linux-gnu)
143                 sys_linux=true
144                 AC_DEFINE(FLAC__SYS_LINUX)
145                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
146                 ;;
147         *-*-darwin*)
148                 sys_darwin=true
149                 AC_DEFINE(FLAC__SYS_DARWIN)
150                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
151                 ;;
152 esac
153 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
154 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
155
156 if test "x$cpu_ia32" = xtrue ; then
157 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
158 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
159 fi
160
161 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
162 dnl ' Terminate the damn single quote
163 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
164 if test "x$asm_opt" = xno ; then
165 AC_DEFINE(FLAC__NO_ASM)
166 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
167 fi
168
169 AC_ARG_ENABLE(debug,
170 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
171 [case "${enableval}" in
172         yes) debug=true ;;
173         no)  debug=false ;;
174         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
175 esac],[debug=false])
176 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
177
178 AC_ARG_ENABLE(sse,
179 AC_HELP_STRING([--enable-sse], [Enable SSE support by asserting that the OS supports SSE instructions]),
180 [case "${enableval}" in
181         yes) sse_os=true ;;
182         no)  sse_os=false ;;
183         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
184 esac],[sse_os=false])
185 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
186 if test "x$sse_os" = xtrue ; then
187 AC_DEFINE(FLAC__SSE_OS)
188 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
189 fi
190
191 AC_ARG_ENABLE(3dnow,
192 AC_HELP_STRING([--disable-3dnow], [Disable 3DNOW! optimizations]),
193 [case "${enableval}" in
194         yes) use_3dnow=true ;;
195         no)  use_3dnow=false ;;
196         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
197 esac],[use_3dnow=true])
198 AM_CONDITIONAL(FLaC__USE_3DNOW, test "x$use_3dnow" = xtrue)
199 if test "x$use_3dnow" = xtrue ; then
200 AC_DEFINE(FLAC__USE_3DNOW)
201 AH_TEMPLATE(FLAC__USE_3DNOW, [define to enable use of 3Dnow! instructions])
202 fi
203
204 AC_ARG_ENABLE(altivec,
205 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
206 [case "${enableval}" in
207         yes) use_altivec=true ;;
208         no)  use_altivec=false ;;
209         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
210 esac],[use_altivec=true])
211 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
212 if test "x$use_altivec" = xtrue ; then
213 AC_DEFINE(FLAC__USE_ALTIVEC)
214 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
215 fi
216
217 AC_ARG_ENABLE(thorough-tests,
218 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
219 [case "${enableval}" in
220         yes) thorough_tests=true ;;
221         no)  thorough_tests=false ;;
222         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
223 esac],[thorough_tests=true])
224 AC_ARG_ENABLE(exhaustive-tests,
225 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
226 [case "${enableval}" in
227         yes) exhaustive_tests=true ;;
228         no)  exhaustive_tests=false ;;
229         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
230 esac],[exhaustive_tests=false])
231 if test "x$thorough_tests" = xfalse ; then
232 FLAC__TEST_LEVEL=0
233 elif test "x$exhaustive_tests" = xfalse ; then
234 FLAC__TEST_LEVEL=1
235 else
236 FLAC__TEST_LEVEL=2
237 fi
238 AC_SUBST(FLAC__TEST_LEVEL)
239
240 AC_ARG_ENABLE(gcc-werror,
241         AC_HELP_STRING([--enable-gcc-werror], [Enable -Werror in all Makefiles]))
242
243 AC_ARG_ENABLE(stack-smash-protection,
244         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
245
246 AC_ARG_ENABLE(valgrind-testing,
247 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
248 [case "${enableval}" in
249         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
250         no)  FLAC__TEST_WITH_VALGRIND=no ;;
251         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
252 esac],[FLAC__TEST_WITH_VALGRIND=no])
253 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
254
255 AC_ARG_ENABLE(doxygen-docs,
256 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
257 [case "${enableval}" in
258         yes) enable_doxygen_docs=true ;;
259         no)  enable_doxygen_docs=false ;;
260         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
261 esac],[enable_doxygen_docs=true])
262 if test "x$enable_doxygen_docs" != xfalse ; then
263         AC_CHECK_PROGS(DOXYGEN, doxygen)
264 fi
265 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
266
267 AC_ARG_ENABLE(local-xmms-plugin,
268 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
269 [case "${enableval}" in
270         yes) install_xmms_plugin_locally=true ;;
271         no)  install_xmms_plugin_locally=false ;;
272         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
273 esac],[install_xmms_plugin_locally=false])
274 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
275
276 AC_ARG_ENABLE(xmms-plugin,
277 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
278 [case "${enableval}" in
279         yes) enable_xmms_plugin=true ;;
280         no)  enable_xmms_plugin=false ;;
281         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
282 esac],[enable_xmms_plugin=true])
283 if test "x$enable_xmms_plugin" != xfalse ; then
284         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
285 fi
286 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
287
288 dnl build FLAC++ or not
289 AC_ARG_ENABLE([cpplibs],
290 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
291 [case "${enableval}" in
292         yes) disable_cpplibs=false ;;
293         no)  disable_cpplibs=true ;;
294         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
295 esac], [disable_cpplibs=false])
296 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
297
298 dnl check for ogg library
299 AC_ARG_ENABLE([ogg],
300         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
301         [ want_ogg=$enableval ], [ want_ogg=yes ] )
302
303 if test "x$want_ogg" != "xno"; then
304         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
305 fi
306
307 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
308 if test "x$have_ogg" = xyes ; then
309         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
310 else
311         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
312 fi
313
314 dnl check for i18n(internationalization); these are from libiconv/gettext
315 AM_ICONV
316 AM_LANGINFO_CODESET
317
318 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
319 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
320 if test -n "$DOCBOOK_TO_MAN" ; then
321 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
322 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
323 fi
324
325 # only matters for x86
326 AC_CHECK_PROGS(NASM, nasm)
327 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
328 if test -n "$NASM" ; then
329 AC_DEFINE(FLAC__HAS_NASM)
330 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
331 fi
332
333 # only matters for PowerPC
334 AC_CHECK_PROGS(AS, as, as)
335 AC_CHECK_PROGS(GAS, gas, gas)
336
337 # try -v (apple as) and --version (gas) at the same time
338 test "$AS" = "as" && as --version -v < /dev/null 2>&1 | grep Apple >/dev/null || AS=gas
339
340 AM_CONDITIONAL(FLaC__HAS_AS, test "$AS" = "as")
341 AM_CONDITIONAL(FLaC__HAS_GAS, test "$AS" = "gas")
342 if test "$AS" = "as" ; then
343 AC_DEFINE(FLAC__HAS_AS)
344 AH_TEMPLATE(FLAC__HAS_AS, [define if you are compiling for PowerPC and have the 'as' assembler])
345 fi
346 if test "$AS" = "gas" ; then
347 # funniest. macro. ever.
348 AC_DEFINE(FLAC__HAS_GAS)
349 AH_TEMPLATE(FLAC__HAS_GAS, [define if you are compiling for PowerPC and have the 'gas' assembler])
350 fi
351
352 if test "x$debug" = xtrue; then
353         CPPFLAGS="-DDEBUG $CPPFLAGS"
354         CFLAGS="-g $CFLAGS"
355 else
356         CPPFLAGS="-DNDEBUG $CPPFLAGS"
357         if test "x$GCC" = xyes; then
358                 if test "x$user_cflags" = x; then
359                         CFLAGS="-O3 -funroll-loops -Wall -W -Winline"
360                 fi
361         fi
362 fi
363
364 XIPH_GCC_VERSION
365
366 if test x$ac_cv_c_compiler_gnu = xyes ; then
367         CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Winline -Wconversion
368         CXXFLAGS="$CXXFLAGS -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
369
370
371         if test x$enable_gcc_werror = "xyes" ; then
372                 CFLAGS="$CFLAGS -Wall -Wextra -Werror "
373                 CXXFLAGS="$CXXFLAGS -Wall -Wextra -Werror "
374                 fi
375
376         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
377                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
378                 CFLAGS="$CFLAGS -fvisibility=hidden"
379                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
380                 fi
381
382         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
383                 XIPH_ADD_CFLAGS([-fgnu89-inline])
384                 fi
385         fi
386
387
388 XIPH_ADD_CFLAGS([-Wextra])
389 XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
390 XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
391
392 if test x$enable_stack_smash_protection = "xyes" ; then
393         XIPH_GCC_STACK_PROTECTOR
394         XIPH_GXX_STACK_PROTECTOR
395         fi
396
397 #@@@
398 AM_CONDITIONAL(FLaC__HAS_AS__TEMPORARILY_DISABLED, test "yes" = "no")
399 AM_CONDITIONAL(FLaC__HAS_GAS__TEMPORARILY_DISABLED, test "yes" = "no")
400
401 AC_CONFIG_FILES([ \
402         Makefile \
403         src/Makefile \
404         src/libFLAC/Makefile \
405         src/libFLAC/flac.pc \
406         src/libFLAC/ia32/Makefile \
407         src/libFLAC/ppc/Makefile \
408         src/libFLAC/ppc/as/Makefile \
409         src/libFLAC/ppc/gas/Makefile \
410         src/libFLAC/include/Makefile \
411         src/libFLAC/include/private/Makefile \
412         src/libFLAC/include/protected/Makefile \
413         src/libFLAC++/Makefile \
414         src/libFLAC++/flac++.pc \
415         src/flac/Makefile \
416         src/metaflac/Makefile \
417         src/monkeys_audio_utilities/Makefile \
418         src/monkeys_audio_utilities/flac_mac/Makefile \
419         src/monkeys_audio_utilities/flac_ren/Makefile \
420         src/plugin_common/Makefile \
421         src/plugin_xmms/Makefile \
422         src/share/Makefile \
423         src/test_grabbag/Makefile \
424         src/test_grabbag/cuesheet/Makefile \
425         src/test_grabbag/picture/Makefile \
426         src/test_libs_common/Makefile \
427         src/test_libFLAC/Makefile \
428         src/test_libFLAC++/Makefile \
429         src/test_seeking/Makefile \
430         src/test_streams/Makefile \
431         src/utils/Makefile \
432         src/utils/flacdiff/Makefile \
433         src/utils/flactimer/Makefile \
434         examples/Makefile \
435         examples/c/Makefile \
436         examples/c/decode/Makefile \
437         examples/c/decode/file/Makefile \
438         examples/c/encode/Makefile \
439         examples/c/encode/file/Makefile \
440         examples/cpp/Makefile \
441         examples/cpp/decode/Makefile \
442         examples/cpp/decode/file/Makefile \
443         examples/cpp/encode/Makefile \
444         examples/cpp/encode/file/Makefile \
445         include/Makefile \
446         include/FLAC/Makefile \
447         include/FLAC++/Makefile \
448         include/share/Makefile \
449         include/share/grabbag/Makefile \
450         include/test_libs_common/Makefile \
451         doc/Doxyfile \
452         doc/Makefile \
453         doc/html/Makefile \
454         doc/html/images/Makefile \
455         doc/html/images/hw/Makefile \
456         doc/html/ru/Makefile \
457         m4/Makefile \
458         man/Makefile \
459         test/Makefile \
460         test/cuesheets/Makefile \
461         test/flac-to-flac-metadata-test-files/Makefile \
462         test/metaflac-test-files/Makefile \
463         test/pictures/Makefile \
464         build/Makefile \
465         objs/Makefile \
466         objs/debug/Makefile \
467         objs/debug/bin/Makefile \
468         objs/debug/lib/Makefile \
469         objs/release/Makefile \
470         objs/release/bin/Makefile \
471         objs/release/lib/Makefile \
472 ])
473 AC_OUTPUT
474
475 AC_MSG_RESULT([
476 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
477
478   Configuration summary :
479
480     FLAC version : ........................ ${VERSION}
481
482     Host CPU : ............................ ${host_cpu}
483     Host Vendor : ......................... ${host_vendor}
484     Host OS : ............................. ${host_os}
485 ])
486
487         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
488 if test x$ac_cv_c_compiler_gnu = xyes ; then
489         echo "    GCC version : ......................... ${GCC_VERSION}"
490 fi
491 echo