d2501bb9b839987ffa67baabc92dd4dafb75588b
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under difference licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_INIT(src/flac/main.c)
22 AM_INIT_AUTOMAKE(flac, 1.2.1)
23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
24
25 # Enable the generation of shared libraries under Win32
26 AC_LIBTOOL_WIN32_DLL
27
28 # We need two libtools, one that builds both shared and static, and
29 # one that builds only static.  This is because the resulting libtool
30 # does not allow us to choose which to build at runtime.
31 AM_PROG_LIBTOOL
32 sed -e 's/^build_old_libs=yes/build_old_libs=no/' libtool > libtool-disable-static
33 chmod +x libtool-disable-static
34
35 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
36 AC_CONFIG_MACRO_DIR([m4])
37
38 AM_PROG_AS
39 AC_PROG_CXX
40 AC_PROG_MAKE_SET
41
42 AC_SYS_LARGEFILE
43 AC_FUNC_FSEEKO
44
45 AC_CHECK_SIZEOF(void*,0)
46
47 #@@@ new name is AC_CONFIG_HEADERS
48 AM_CONFIG_HEADER(config.h)
49
50 AC_LANG_PUSH(C++)
51 # c++ flavor first
52 AC_C_VARARRAYS
53 if test $ac_cv_c_vararrays = yes; then
54         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
55 fi
56 AC_LANG_POP(C++)
57
58 # c flavor
59 AC_HEADER_STDC
60 AM_PROG_CC_C_O
61 AC_C_INLINE
62 AC_C_VARARRAYS
63
64 AC_CHECK_HEADERS(stdint.h)
65 AC_SUBST(HAVE_STDINT_H)
66 AC_CHECK_HEADERS(inttypes.h)
67 AC_SUBST(HAVE_INTTYPES_H)
68 AC_CHECK_HEADERS(byteswap.h)
69 AC_SUBST(HAVE_BYTESWAP_H)
70
71 XIPH_C_BSWAP32
72
73 XIPH_C_FIND_ENDIAN
74 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
75                                         [Target processor is big endian.])
76 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
77                                         [Target processor is little endian.])
78 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
79                                         [Target processor is big endian.])
80
81 # For the XMMS plugin.
82 AC_CHECK_TYPES(socklen_t, [], [])
83
84 dnl check for getopt in standard library
85 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
86 AC_CHECK_FUNCS(getopt_long, [], [])
87
88 case "$host_cpu" in
89         i*86)
90                 cpu_ia32=true
91                 AC_DEFINE(FLAC__CPU_IA32)
92                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
93                 ;;
94         powerpc)
95                 cpu_ppc=true
96                 AC_DEFINE(FLAC__CPU_PPC)
97                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
98                 ;;
99         sparc)
100                 cpu_sparc=true
101                 AC_DEFINE(FLAC__CPU_SPARC)
102                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
103                 ;;
104 esac
105 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
106 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
107 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
108
109 case "$host" in
110         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
111         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
112         *-*-darwin*) OBJ_FORMAT=macho ;;
113         *emx*) OBJ_FORMAT=aout ;;
114         *) OBJ_FORMAT=elf ;;
115 esac
116 AC_SUBST(OBJ_FORMAT)
117 case "$host" in
118         *-gnuspe)
119                 abi_spe=true
120                 AC_DEFINE(FLAC__CPU_PPC_SPE)
121                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
122                 ;;
123 esac
124 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
125
126 case "$host" in
127         *-*-cygwin|*mingw*|*emx*)
128                 # define this variable for enabling strict exports with libtool; for now, it's supported by Win32 and OS/2
129                 LT_NO_UNDEFINED="-no-undefined"
130                 ;;
131         *)
132                 LT_NO_UNDEFINED=
133                 ;;
134 esac
135 AC_SUBST(LT_NO_UNDEFINED)
136
137 case "$host" in
138         *-pc-linux-gnu)
139                 sys_linux=true
140                 AC_DEFINE(FLAC__SYS_LINUX)
141                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
142                 ;;
143         *-*-darwin*)
144                 sys_darwin=true
145                 AC_DEFINE(FLAC__SYS_DARWIN)
146                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
147                 ;;
148 esac
149 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
150 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
151
152 if test "x$cpu_ia32" = xtrue ; then
153 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
154 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
155 fi
156
157 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
158 dnl ' Terminate the damn single quote
159 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
160 if test "x$asm_opt" = xno ; then
161 AC_DEFINE(FLAC__NO_ASM)
162 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
163 fi
164
165 AC_ARG_ENABLE(debug,
166 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
167 [case "${enableval}" in
168         yes) debug=true ;;
169         no)  debug=false ;;
170         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
171 esac],[debug=false])
172 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
173
174 AC_ARG_ENABLE(sse,
175 AC_HELP_STRING([--enable-sse], [Enable SSE support by asserting that the OS supports SSE instructions]),
176 [case "${enableval}" in
177         yes) sse_os=true ;;
178         no)  sse_os=false ;;
179         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
180 esac],[sse_os=false])
181 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
182 if test "x$sse_os" = xtrue ; then
183 AC_DEFINE(FLAC__SSE_OS)
184 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
185 fi
186
187 AC_ARG_ENABLE(3dnow,
188 AC_HELP_STRING([--disable-3dnow], [Disable 3DNOW! optimizations]),
189 [case "${enableval}" in
190         yes) use_3dnow=true ;;
191         no)  use_3dnow=false ;;
192         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
193 esac],[use_3dnow=true])
194 AM_CONDITIONAL(FLaC__USE_3DNOW, test "x$use_3dnow" = xtrue)
195 if test "x$use_3dnow" = xtrue ; then
196 AC_DEFINE(FLAC__USE_3DNOW)
197 AH_TEMPLATE(FLAC__USE_3DNOW, [define to enable use of 3Dnow! instructions])
198 fi
199
200 AC_ARG_ENABLE(altivec,
201 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
202 [case "${enableval}" in
203         yes) use_altivec=true ;;
204         no)  use_altivec=false ;;
205         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
206 esac],[use_altivec=true])
207 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
208 if test "x$use_altivec" = xtrue ; then
209 AC_DEFINE(FLAC__USE_ALTIVEC)
210 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
211 fi
212
213 AC_ARG_ENABLE(thorough-tests,
214 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
215 [case "${enableval}" in
216         yes) thorough_tests=true ;;
217         no)  thorough_tests=false ;;
218         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
219 esac],[thorough_tests=true])
220 AC_ARG_ENABLE(exhaustive-tests,
221 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
222 [case "${enableval}" in
223         yes) exhaustive_tests=true ;;
224         no)  exhaustive_tests=false ;;
225         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
226 esac],[exhaustive_tests=false])
227 if test "x$thorough_tests" = xfalse ; then
228 FLAC__TEST_LEVEL=0
229 elif test "x$exhaustive_tests" = xfalse ; then
230 FLAC__TEST_LEVEL=1
231 else
232 FLAC__TEST_LEVEL=2
233 fi
234 AC_SUBST(FLAC__TEST_LEVEL)
235
236 AC_ARG_ENABLE(gcc-werror,
237         AC_HELP_STRING([--enable-gcc-werror], [enable -Werror in all Makefiles]))
238
239 AC_ARG_ENABLE(valgrind-testing,
240 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
241 [case "${enableval}" in
242         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
243         no)  FLAC__TEST_WITH_VALGRIND=no ;;
244         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
245 esac],[FLAC__TEST_WITH_VALGRIND=no])
246 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
247
248 AC_ARG_ENABLE(doxygen-docs,
249 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
250 [case "${enableval}" in
251         yes) enable_doxygen_docs=true ;;
252         no)  enable_doxygen_docs=false ;;
253         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
254 esac],[enable_doxygen_docs=true])
255 if test "x$enable_doxygen_docs" != xfalse ; then
256         AC_CHECK_PROGS(DOXYGEN, doxygen)
257 fi
258 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
259
260 AC_ARG_ENABLE(local-xmms-plugin,
261 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
262 [case "${enableval}" in
263         yes) install_xmms_plugin_locally=true ;;
264         no)  install_xmms_plugin_locally=false ;;
265         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
266 esac],[install_xmms_plugin_locally=false])
267 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
268
269 AC_ARG_ENABLE(xmms-plugin,
270 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
271 [case "${enableval}" in
272         yes) enable_xmms_plugin=true ;;
273         no)  enable_xmms_plugin=false ;;
274         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
275 esac],[enable_xmms_plugin=true])
276 if test "x$enable_xmms_plugin" != xfalse ; then
277         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
278 fi
279 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
280
281 dnl build FLAC++ or not
282 AC_ARG_ENABLE([cpplibs],
283 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
284 [case "${enableval}" in
285         yes) disable_cpplibs=false ;;
286         no)  disable_cpplibs=true ;;
287         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
288 esac], [disable_cpplibs=false])
289 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
290
291 dnl check for ogg library
292 AC_ARG_ENABLE([ogg],
293         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
294         [ want_ogg=$enableval ], [ want_ogg=yes ] )
295
296 if test "x$want_ogg" != "xno"; then
297         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
298 fi
299
300 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
301 if test "x$have_ogg" = xyes ; then
302 AC_DEFINE(FLAC__HAS_OGG)
303 AH_TEMPLATE(FLAC__HAS_OGG, [define if you have the ogg library])
304 fi
305
306 dnl check for i18n(internationalization); these are from libiconv/gettext
307 AM_ICONV
308 AM_LANGINFO_CODESET
309
310 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
311 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
312 if test -n "$DOCBOOK_TO_MAN" ; then
313 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
314 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
315 fi
316
317 # only matters for x86
318 AC_CHECK_PROGS(NASM, nasm)
319 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
320 if test -n "$NASM" ; then
321 AC_DEFINE(FLAC__HAS_NASM)
322 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
323 fi
324
325 # only matters for PowerPC
326 AC_CHECK_PROGS(AS, as, as)
327 AC_CHECK_PROGS(GAS, gas, gas)
328
329 # try -v (apple as) and --version (gas) at the same time
330 test "$AS" = "as" && as --version -v < /dev/null 2>&1 | grep Apple >/dev/null || AS=gas
331
332 AM_CONDITIONAL(FLaC__HAS_AS, test "$AS" = "as")
333 AM_CONDITIONAL(FLaC__HAS_GAS, test "$AS" = "gas")
334 if test "$AS" = "as" ; then
335 AC_DEFINE(FLAC__HAS_AS)
336 AH_TEMPLATE(FLAC__HAS_AS, [define if you are compiling for PowerPC and have the 'as' assembler])
337 fi
338 if test "$AS" = "gas" ; then
339 # funniest. macro. ever.
340 AC_DEFINE(FLAC__HAS_GAS)
341 AH_TEMPLATE(FLAC__HAS_GAS, [define if you are compiling for PowerPC and have the 'gas' assembler])
342 fi
343
344 CPPFLAGS='-I$(top_builddir) -I$(srcdir)/include -I$(top_srcdir)/include'" $CPPFLAGS"
345 if test "x$debug" = xtrue; then
346         CPPFLAGS="-DDEBUG -DFLaC__INLINE= $CPPFLAGS"
347         CFLAGS="-g $CFLAGS"
348 else
349         CPPFLAGS="-DNDEBUG $CPPFLAGS"
350         # $ac_cv_c_inline from AC_C_INLINE
351         if test "x$ac_cv_c_inline" != xno ; then
352                 CPPFLAGS="-DFLaC__INLINE=$ac_cv_c_inline $CPPFLAGS"
353         fi
354         if test "x$GCC" = xyes; then
355                 CFLAGS="-O3 -funroll-loops -finline-functions -Wall -W -Winline $CFLAGS"
356         fi
357 fi
358
359 XIPH_GCC_VERSION
360
361 if test x$ac_cv_c_compiler_gnu = xyes ; then
362         if test x$enable_gcc_werror = "xyes" ; then
363                 CFLAGS="-Werror $CFLAGS"
364                 CXXFLAGS="-Werror $CXXFLAGS"
365                 fi
366         fi
367
368
369 #@@@
370 AM_CONDITIONAL(FLaC__HAS_AS__TEMPORARILY_DISABLED, test "yes" = "no")
371 AM_CONDITIONAL(FLaC__HAS_GAS__TEMPORARILY_DISABLED, test "yes" = "no")
372
373 AC_CONFIG_FILES([ \
374         Makefile \
375         src/Makefile \
376         src/libFLAC/Makefile \
377         src/libFLAC/flac.pc \
378         src/libFLAC/ia32/Makefile \
379         src/libFLAC/ppc/Makefile \
380         src/libFLAC/ppc/as/Makefile \
381         src/libFLAC/ppc/gas/Makefile \
382         src/libFLAC/include/Makefile \
383         src/libFLAC/include/private/Makefile \
384         src/libFLAC/include/protected/Makefile \
385         src/libFLAC++/Makefile \
386         src/libFLAC++/flac++.pc \
387         src/flac/Makefile \
388         src/metaflac/Makefile \
389         src/monkeys_audio_utilities/Makefile \
390         src/monkeys_audio_utilities/flac_mac/Makefile \
391         src/monkeys_audio_utilities/flac_ren/Makefile \
392         src/plugin_common/Makefile \
393         src/plugin_xmms/Makefile \
394         src/share/Makefile \
395         src/share/getopt/Makefile \
396         src/share/grabbag/Makefile \
397         src/share/replaygain_analysis/Makefile \
398         src/share/replaygain_synthesis/Makefile \
399         src/share/replaygain_synthesis/include/Makefile \
400         src/share/replaygain_synthesis/include/private/Makefile \
401         src/share/utf8/Makefile \
402         src/test_grabbag/Makefile \
403         src/test_grabbag/cuesheet/Makefile \
404         src/test_grabbag/picture/Makefile \
405         src/test_libs_common/Makefile \
406         src/test_libFLAC/Makefile \
407         src/test_libFLAC++/Makefile \
408         src/test_seeking/Makefile \
409         src/test_streams/Makefile \
410         src/utils/Makefile \
411         src/utils/flacdiff/Makefile \
412         src/utils/flactimer/Makefile \
413         examples/Makefile \
414         examples/c/Makefile \
415         examples/c/decode/Makefile \
416         examples/c/decode/file/Makefile \
417         examples/c/encode/Makefile \
418         examples/c/encode/file/Makefile \
419         examples/cpp/Makefile \
420         examples/cpp/decode/Makefile \
421         examples/cpp/decode/file/Makefile \
422         examples/cpp/encode/Makefile \
423         examples/cpp/encode/file/Makefile \
424         include/Makefile \
425         include/FLAC/Makefile \
426         include/FLAC++/Makefile \
427         include/share/Makefile \
428         include/share/grabbag/Makefile \
429         include/test_libs_common/Makefile \
430         doc/Makefile \
431         doc/html/Makefile \
432         doc/html/images/Makefile \
433         doc/html/images/hw/Makefile \
434         doc/html/ru/Makefile \
435         m4/Makefile \
436         man/Makefile \
437         test/Makefile \
438         test/cuesheets/Makefile \
439         test/flac-to-flac-metadata-test-files/Makefile \
440         test/metaflac-test-files/Makefile \
441         test/pictures/Makefile \
442         build/Makefile \
443         obj/Makefile \
444         obj/debug/Makefile \
445         obj/debug/bin/Makefile \
446         obj/debug/lib/Makefile \
447         obj/release/Makefile \
448         obj/release/bin/Makefile \
449         obj/release/lib/Makefile \
450 ])
451 AC_OUTPUT
452
453 AC_MSG_RESULT([
454 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
455
456   Configuration summary :
457
458     FLAC version : ........................ ${VERSION}
459
460     Host CPU : ............................ ${host_cpu}
461     Host Vendor : ......................... ${host_vendor}
462     Host OS : ............................. ${host_os}
463 ])
464
465 if test x$ac_cv_c_compiler_gnu = xyes ; then
466         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
467         echo "    GCC version : ......................... ${GCC_VERSION}"
468         fi