getopt.c: Pointer comparison fix
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.2], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.10 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 XIPH_C_COMPILER_IS_CLANG
39 XIPH_GCC_REALLY_IS_GCC
40 AC_PROG_MAKE_SET
41 AC_PROG_MKDIR_P
42
43 AC_SYS_LARGEFILE
44 AC_FUNC_FSEEKO
45
46 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
47 AC_CHECK_SIZEOF([void*])
48 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
49
50 AC_LANG_PUSH([C++])
51 # c++ flavor first
52 AC_C_VARARRAYS
53 if test $ac_cv_c_vararrays = yes; then
54         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
55 fi
56 AC_LANG_POP([C++])
57
58 # c flavor
59 AC_HEADER_STDC
60 AM_PROG_CC_C_O
61 AC_C_INLINE
62 AC_C_VARARRAYS
63 AC_C_TYPEOF
64
65 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h sys/ioctl.h termios.h x86intrin.h cpuid.h])
66
67 XIPH_C_BSWAP32
68 XIPH_C_BSWAP16
69
70 ac_cv_c_big_endian=0
71 ac_cv_c_little_endian=0
72 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
73         AC_MSG_WARN([[*****************************************************************]])
74         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
75         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
76         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
77         AC_MSG_WARN([[*****************************************************************]])
78 ])
79 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
80                                         [Target processor is big endian.])
81 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
82                                         [Target processor is little endian.])
83 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
84                                         [Target processor is big endian.])
85
86 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
87 dnl ' Terminate the damn single quote
88 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
89 if test "x$asm_opt" = xno ; then
90 AC_DEFINE(FLAC__NO_ASM)
91 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
92 fi
93
94 # For the XMMS plugin.
95 AC_CHECK_TYPES(socklen_t, [], [])
96
97 dnl check for getopt in standard library
98 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
99 AC_CHECK_FUNCS(getopt_long, [], [])
100
101 AC_CHECK_SIZEOF(void*,1)
102
103 asm_optimisation=no
104 case "$host_cpu" in
105         amd64|x86_64)
106                 case "$host" in
107                         *gnux32)
108                                 # x32 user space and 64 bit kernel.
109                                 cpu_x86_64=true
110                                 AC_DEFINE(FLAC__CPU_X86_64)
111                                 AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
112                                 asm_optimisation=$asm_opt
113                                 ;;
114                         *)
115                                 if test $ac_cv_sizeof_voidp = 4 ; then
116                                         # This must be a 32 bit user space running on 64 bit kernel so treat
117                                         # this as ia32.
118                                         cpu_ia32=true
119                                         AC_DEFINE(FLAC__CPU_IA32)
120                                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
121                         else
122                                         # x86_64 user space and kernel.
123                                         cpu_x86_64=true
124                                         AC_DEFINE(FLAC__CPU_X86_64)
125                                         AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
126                                 fi
127                                 asm_optimisation=$asm_opt
128                                 ;;
129                 esac
130                 ;;
131         i*86)
132                 cpu_ia32=true
133                 AC_DEFINE(FLAC__CPU_IA32)
134                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
135                 asm_optimisation=$asm_opt
136                 ;;
137         powerpc|powerpc64)
138                 cpu_ppc=true
139                 AC_DEFINE(FLAC__CPU_PPC)
140                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
141                 asm_optimisation=$asm_opt
142                 ;;
143         sparc)
144                 cpu_sparc=true
145                 AC_DEFINE(FLAC__CPU_SPARC)
146                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
147                 asm_optimisation=$asm_opt
148                 ;;
149 esac
150 AM_CONDITIONAL(FLAC__CPU_X86_64, test "x$cpu_x86_64" = xtrue)
151 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
152 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
153 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
154
155 if test "x$ac_cv_header_x86intrin_h" = xyes; then
156 AC_DEFINE([FLAC__HAS_X86INTRIN], 1, [Set to 1 if <x86intrin.h> is available.])
157 else
158 AC_DEFINE([FLAC__HAS_X86INTRIN], 0)
159 fi
160
161 case "$host" in
162         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
163         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
164         *-*-darwin*) OBJ_FORMAT=macho ;;
165         *emx*) OBJ_FORMAT=aout ;;
166         *djgpp) OBJ_FORMAT=coff ;;
167         *) OBJ_FORMAT=elf ;;
168 esac
169 AC_SUBST(OBJ_FORMAT)
170 case "$host" in
171         *-gnuspe)
172                 abi_spe=true
173                 AC_DEFINE(FLAC__CPU_PPC_SPE)
174                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
175                 ;;
176 esac
177 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
178
179 os_is_windows=no
180 case "$host" in
181         *-*-cygwin|*mingw*)
182                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
183                 os_is_windows=yes
184                 ;;
185 esac
186
187 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
188
189 case "$host" in
190         *-linux-*)
191                 sys_linux=true
192                 AC_DEFINE(FLAC__SYS_LINUX)
193                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
194                 ;;
195         *-*-darwin*)
196                 sys_darwin=true
197                 AC_DEFINE(FLAC__SYS_DARWIN)
198                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
199                 ;;
200 esac
201 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
202 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
203
204 if test "x$cpu_ia32" = xtrue || test "x$cpu_x86_64" = xtrue ; then
205 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
206 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
207 fi
208
209 AC_ARG_ENABLE(debug,
210 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
211 [case "${enableval}" in
212         yes) debug=true ;;
213         no)  debug=false ;;
214         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
215 esac],[debug=false])
216 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
217
218 AC_ARG_ENABLE(sse,
219 AC_HELP_STRING([--disable-sse], [Disable passing of -msse2 to the compiler]),
220 [case "${enableval}" in
221         yes) sse_os=yes ;;
222         no)  sse_os=no ;;
223         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
224 esac],[sse_os=yes])
225
226 AC_ARG_ENABLE(altivec,
227 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
228 [case "${enableval}" in
229         yes) use_altivec=true ;;
230         no)  use_altivec=false ;;
231         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
232 esac],[use_altivec=true])
233 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
234 if test "x$use_altivec" = xtrue ; then
235 AC_DEFINE(FLAC__USE_ALTIVEC)
236 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
237 fi
238
239 AC_ARG_ENABLE(avx,
240 AC_HELP_STRING([--disable-avx], [Disable AVX, AVX2 optimizations]),
241 [case "${enableval}" in
242         yes) use_avx=true ;;
243         no)  use_avx=false ;;
244         *) AC_MSG_ERROR(bad value ${enableval} for --enable-avx) ;;
245 esac],[use_avx=true])
246 AM_CONDITIONAL(FLaC__USE_AVX, test "x$use_avx" = xtrue)
247 if test "x$use_avx" = xtrue ; then
248 AC_DEFINE(FLAC__USE_AVX)
249 AH_TEMPLATE(FLAC__USE_AVX, [define to enable use of AVX instructions])
250 fi
251
252 AC_ARG_ENABLE(thorough-tests,
253 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
254 [case "${enableval}" in
255         yes) thorough_tests=true ;;
256         no)  thorough_tests=false ;;
257         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
258 esac],[thorough_tests=true])
259 AC_ARG_ENABLE(exhaustive-tests,
260 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
261 [case "${enableval}" in
262         yes) exhaustive_tests=true ;;
263         no)  exhaustive_tests=false ;;
264         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
265 esac],[exhaustive_tests=false])
266 if test "x$thorough_tests" = xfalse ; then
267 FLAC__TEST_LEVEL=0
268 elif test "x$exhaustive_tests" = xfalse ; then
269 FLAC__TEST_LEVEL=1
270 else
271 FLAC__TEST_LEVEL=2
272 fi
273 AC_SUBST(FLAC__TEST_LEVEL)
274
275 AC_ARG_ENABLE(werror,
276         AC_HELP_STRING([--enable-werror], [Enable -Werror in all Makefiles]))
277
278 AC_ARG_ENABLE(stack-smash-protection,
279         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
280
281 AC_ARG_ENABLE(64-bit-words,
282         AC_HELP_STRING([--enable-64-bit-words], [Set FLAC__BYTES_PER_WORD to 8 (4 is the default)]))
283 if test "x$enable_64_bit_words" = xyes ; then
284         AC_DEFINE_UNQUOTED([ENABLE_64_BIT_WORDS],1,[Set FLAC__BYTES_PER_WORD to 8 (4 is the default)])
285 else
286         AC_DEFINE_UNQUOTED([ENABLE_64_BIT_WORDS],0)
287         fi
288 AC_SUBST(ENABLE_64_BIT_WORDS)
289
290 AC_ARG_ENABLE(valgrind-testing,
291 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
292 [case "${enableval}" in
293         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
294         no)  FLAC__TEST_WITH_VALGRIND=no ;;
295         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
296 esac],[FLAC__TEST_WITH_VALGRIND=no])
297 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
298
299 AC_ARG_ENABLE(doxygen-docs,
300 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
301 [case "${enableval}" in
302         yes) enable_doxygen_docs=true ;;
303         no)  enable_doxygen_docs=false ;;
304         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
305 esac],[enable_doxygen_docs=true])
306 if test "x$enable_doxygen_docs" != xfalse ; then
307         AC_CHECK_PROGS(DOXYGEN, doxygen)
308 fi
309 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
310
311 AC_ARG_ENABLE(local-xmms-plugin,
312 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
313 [case "${enableval}" in
314         yes) install_xmms_plugin_locally=true ;;
315         no)  install_xmms_plugin_locally=false ;;
316         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
317 esac],[install_xmms_plugin_locally=false])
318 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
319
320 AC_ARG_ENABLE(xmms-plugin,
321 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
322 [case "${enableval}" in
323         yes) enable_xmms_plugin=true ;;
324         no)  enable_xmms_plugin=false ;;
325         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
326 esac],[enable_xmms_plugin=true])
327 if test "x$enable_xmms_plugin" != xfalse ; then
328         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
329 fi
330 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
331
332 dnl build FLAC++ or not
333 AC_ARG_ENABLE([cpplibs],
334 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
335 [case "${enableval}" in
336         yes) disable_cpplibs=false ;;
337         no)  disable_cpplibs=true ;;
338         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
339 esac], [disable_cpplibs=false])
340 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
341
342 dnl check for ogg library
343 AC_ARG_ENABLE([ogg],
344         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
345         [ want_ogg=$enableval ], [ want_ogg=yes ] )
346
347 if test "x$want_ogg" != "xno"; then
348         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
349 fi
350
351 FLAC__HAS_OGG=0
352 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
353 if test "x$have_ogg" = xyes ; then
354         FLAC__HAS_OGG=1
355         OGG_PACKAGE="ogg"
356 else
357         have_ogg=no
358 fi
359 AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],$FLAC__HAS_OGG,[define if you have the ogg library])
360 AC_SUBST(FLAC__HAS_OGG)
361 AC_SUBST(OGG_PACKAGE)
362
363 dnl Build examples?
364 AC_ARG_ENABLE([examples],
365         AS_HELP_STRING([--disable-examples], [Don't build and install examples]))
366 AM_CONDITIONAL([EXAMPLES], [test "x$enable_examples" != "xno"])
367
368 dnl check for i18n(internationalization); these are from libiconv/gettext
369 AM_ICONV
370 AM_LANGINFO_CODESET
371
372 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
373 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
374 if test -n "$DOCBOOK_TO_MAN" ; then
375 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
376 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
377 fi
378
379 AC_CHECK_LIB(rt, clock_gettime, have_clock_gettime=yes)
380 if test x$have_clock_gettime = xyes; then
381         AC_DEFINE(HAVE_CLOCK_GETTIME)
382         AH_TEMPLATE(HAVE_CLOCK_GETTIME, [define if you have clock_gettime])
383 fi
384
385 # only matters for x86
386 AC_CHECK_PROGS(NASM, nasm)
387 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
388 if test -n "$NASM" ; then
389 AC_DEFINE(FLAC__HAS_NASM)
390 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
391 fi
392
393 if test "x$debug" = xtrue; then
394         CPPFLAGS="-DDEBUG $CPPFLAGS"
395         CFLAGS="-g $CFLAGS"
396 else
397         CPPFLAGS="-DNDEBUG $CPPFLAGS"
398         CFLAGS=$(echo "$CFLAGS" | sed 's/-O2//')
399         CFLAGS="-O3 -funroll-loops $CFLAGS"
400 fi
401
402 XIPH_GCC_VERSION
403
404 if test x$ac_cv_c_compiler_gnu = xyes ; then
405         CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations -Winline " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Wconversion
406         CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
407
408         XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
409         XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
410
411         AC_LANG_PUSH([C++])
412         XIPH_ADD_CXXFLAGS([-Weffc++])
413         AC_LANG_POP([C++])
414
415         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
416                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
417                 CFLAGS="$CFLAGS -fvisibility=hidden"
418                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
419                 fi
420
421         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = macho; then
422                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
423                 CFLAGS="$CFLAGS -fvisibility=hidden"
424                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
425                 fi
426
427         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
428                 XIPH_ADD_CFLAGS([-fgnu89-inline])
429                 fi
430
431         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x47" ; then
432                 XIPH_ADD_CFLAGS([-fno-inline-small-functions])
433                 fi
434
435         if test "x$asm_optimisation$sse_os" = "xyesyes" ; then
436                 XIPH_ADD_CFLAGS([-msse2])
437                 fi
438
439         fi
440
441 case "$host_os" in
442         "mingw32"|"os2")
443         if test "$host_cpu" = "i686"; then
444                 XIPH_ADD_CFLAGS([-mstackrealign])
445                 fi
446         esac
447
448 if test x$enable_werror = "xyes" ; then
449         XIPH_ADD_CFLAGS([-Werror])
450         AC_LANG_PUSH([C++])
451         XIPH_ADD_CXXFLAGS([-Werror])
452         AC_LANG_POP([C++])
453         fi
454
455 if test x$enable_stack_smash_protection = "xyes" ; then
456         XIPH_GCC_STACK_PROTECTOR
457         XIPH_GXX_STACK_PROTECTOR
458         fi
459
460 if test "x$sys_linux" = xtrue ; then
461        LIB_CLOCK_GETTIME=-lrt
462        fi
463 AC_SUBST(LIB_CLOCK_GETTIME)
464
465 AC_CONFIG_FILES([ \
466         Makefile \
467         src/Makefile \
468         src/libFLAC/Makefile \
469         src/libFLAC/flac.pc \
470         src/libFLAC/ia32/Makefile \
471         src/libFLAC/include/Makefile \
472         src/libFLAC/include/private/Makefile \
473         src/libFLAC/include/protected/Makefile \
474         src/libFLAC++/Makefile \
475         src/libFLAC++/flac++.pc \
476         src/flac/Makefile \
477         src/metaflac/Makefile \
478         src/plugin_common/Makefile \
479         src/plugin_xmms/Makefile \
480         src/share/Makefile \
481         src/test_grabbag/Makefile \
482         src/test_grabbag/cuesheet/Makefile \
483         src/test_grabbag/picture/Makefile \
484         src/test_libs_common/Makefile \
485         src/test_libFLAC/Makefile \
486         src/test_libFLAC++/Makefile \
487         src/test_seeking/Makefile \
488         src/test_streams/Makefile \
489         src/utils/Makefile \
490         src/utils/flacdiff/Makefile \
491         src/utils/flactimer/Makefile \
492         examples/Makefile \
493         examples/c/Makefile \
494         examples/c/decode/Makefile \
495         examples/c/decode/file/Makefile \
496         examples/c/encode/Makefile \
497         examples/c/encode/file/Makefile \
498         examples/cpp/Makefile \
499         examples/cpp/decode/Makefile \
500         examples/cpp/decode/file/Makefile \
501         examples/cpp/encode/Makefile \
502         examples/cpp/encode/file/Makefile \
503         include/Makefile \
504         include/FLAC/Makefile \
505         include/FLAC++/Makefile \
506         include/share/Makefile \
507         include/share/grabbag/Makefile \
508         include/test_libs_common/Makefile \
509         doc/Doxyfile \
510         doc/Makefile \
511         doc/html/Makefile \
512         doc/html/images/Makefile \
513         m4/Makefile \
514         man/Makefile \
515         test/common.sh \
516         test/Makefile \
517         test/cuesheets/Makefile \
518         test/flac-to-flac-metadata-test-files/Makefile \
519         test/metaflac-test-files/Makefile \
520         test/pictures/Makefile \
521         build/Makefile \
522         objs/Makefile \
523         objs/debug/Makefile \
524         objs/debug/bin/Makefile \
525         objs/debug/lib/Makefile \
526         objs/release/Makefile \
527         objs/release/bin/Makefile \
528         objs/release/lib/Makefile \
529         microbench/Makefile
530 ])
531 AC_OUTPUT
532
533 AC_MSG_RESULT([
534 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
535
536   Configuration summary :
537
538     FLAC version : ........................ ${VERSION}
539
540     Host CPU : ............................ ${host_cpu}
541     Host Vendor : ......................... ${host_vendor}
542     Host OS : ............................. ${host_os}
543 ])
544
545         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
546 if test x$ac_cv_c_compiler_gnu = xyes ; then
547         echo "    GCC version : ......................... ${GCC_VERSION}"
548 fi
549         echo "    Compiler is Clang : ................... ${xiph_cv_c_compiler_clang}"
550         echo "    SSE optimizations : ................... ${sse_os}"
551         echo "    Asm optimizations : ................... ${asm_optimisation}"
552         echo "    Ogg/FLAC support : .................... ${have_ogg}"
553 echo