FLAC++: Add missing prototype for construct_block
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.2], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.10 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 AC_MSG_CHECKING([whether configure should try to set CFLAGS/CXXFLAGS/CPPFLAGS/LDFLAGS])
30 AS_IF([test "x${CFLAGS+set}" = "xset" || test "x${CXXFLAGS+set}" = "xset" || test "x${CPPFLAGS+set}" = "xset" || test "x${LDFLAGS+set}" = "xset"],
31         [enable_flags_setting=no],
32         [enable_flags_setting=yes]
33 )
34 AC_MSG_RESULT([${enable_flags_setting}])
35 AX_CHECK_ENABLE_DEBUG
36 user_cflags=$CFLAGS
37
38 #Prefer whatever the current ISO standard is.
39 AC_PROG_CC_STDC
40 AC_USE_SYSTEM_EXTENSIONS
41 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
42 LT_INIT([win32-dll disable-static pic-only])
43 AM_PROG_AS
44 AC_PROG_CXX
45 XIPH_C_COMPILER_IS_CLANG
46 XIPH_GCC_REALLY_IS_GCC
47 AC_PROG_MAKE_SET
48 AC_PROG_MKDIR_P
49
50 AC_SYS_LARGEFILE
51 AC_FUNC_FSEEKO
52
53 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
54 AC_CHECK_SIZEOF([void*])
55 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
56
57 AC_LANG_PUSH([C++])
58 # c++ flavor first
59 AC_C_VARARRAYS
60 if test $ac_cv_c_vararrays = yes; then
61         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
62 fi
63 AC_LANG_POP([C++])
64
65 # c flavor
66 AC_HEADER_STDC
67 AM_PROG_CC_C_O
68 AC_C_INLINE
69 AC_C_VARARRAYS
70 AC_C_TYPEOF
71
72 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h sys/ioctl.h termios.h x86intrin.h cpuid.h])
73
74 XIPH_C_BSWAP32
75 XIPH_C_BSWAP16
76
77 ac_cv_c_big_endian=0
78 ac_cv_c_little_endian=0
79 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
80         AC_MSG_WARN([[*****************************************************************]])
81         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
82         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
83         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
84         AC_MSG_WARN([[*****************************************************************]])
85 ])
86 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
87                                         [Target processor is big endian.])
88 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
89                                         [Target processor is little endian.])
90 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
91                                         [Target processor is big endian.])
92
93 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
94 dnl ' Terminate the damn single quote
95 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
96 if test "x$asm_opt" = xno ; then
97 AC_DEFINE(FLAC__NO_ASM)
98 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
99 fi
100
101 # For the XMMS plugin.
102 AC_CHECK_TYPES(socklen_t, [], [])
103
104 dnl check for getopt in standard library
105 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
106 AC_CHECK_FUNCS(getopt_long, [], [])
107
108 AC_CHECK_SIZEOF(void*,1)
109
110 asm_optimisation=no
111 case "$host_cpu" in
112         amd64|x86_64)
113                 case "$host" in
114                         *gnux32)
115                                 # x32 user space and 64 bit kernel.
116                                 cpu_x86_64=true
117                                 AC_DEFINE(FLAC__CPU_X86_64)
118                                 AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
119                                 asm_optimisation=$asm_opt
120                                 ;;
121                         *)
122                                 if test $ac_cv_sizeof_voidp = 4 ; then
123                                         # This must be a 32 bit user space running on 64 bit kernel so treat
124                                         # this as ia32.
125                                         cpu_ia32=true
126                                         AC_DEFINE(FLAC__CPU_IA32)
127                                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
128                         else
129                                         # x86_64 user space and kernel.
130                                         cpu_x86_64=true
131                                         AC_DEFINE(FLAC__CPU_X86_64)
132                                         AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
133                                 fi
134                                 asm_optimisation=$asm_opt
135                                 ;;
136                 esac
137                 ;;
138         i*86)
139                 cpu_ia32=true
140                 AC_DEFINE(FLAC__CPU_IA32)
141                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
142                 asm_optimisation=$asm_opt
143                 ;;
144         powerpc|powerpc64)
145                 cpu_ppc=true
146                 AC_DEFINE(FLAC__CPU_PPC)
147                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
148                 asm_optimisation=$asm_opt
149                 ;;
150         sparc)
151                 cpu_sparc=true
152                 AC_DEFINE(FLAC__CPU_SPARC)
153                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
154                 asm_optimisation=$asm_opt
155                 ;;
156 esac
157 AM_CONDITIONAL(FLAC__CPU_X86_64, test "x$cpu_x86_64" = xtrue)
158 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
159 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
160 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
161
162 if test "x$ac_cv_header_x86intrin_h" = xyes; then
163 AC_DEFINE([FLAC__HAS_X86INTRIN], 1, [Set to 1 if <x86intrin.h> is available.])
164 else
165 AC_DEFINE([FLAC__HAS_X86INTRIN], 0)
166 fi
167
168 case "$host" in
169         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
170         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
171         *-*-darwin*) OBJ_FORMAT=macho ;;
172         *emx*) OBJ_FORMAT=aout ;;
173         *djgpp) OBJ_FORMAT=coff ;;
174         *) OBJ_FORMAT=elf ;;
175 esac
176 AC_SUBST(OBJ_FORMAT)
177 case "$host" in
178         *-gnuspe)
179                 abi_spe=true
180                 AC_DEFINE(FLAC__CPU_PPC_SPE)
181                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
182                 ;;
183 esac
184 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
185
186 os_is_windows=no
187 case "$host" in
188         *mingw*)
189                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
190                 os_is_windows=yes
191                 ;;
192 esac
193
194 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
195
196 case "$host" in
197         *-linux-*)
198                 sys_linux=true
199                 AC_DEFINE(FLAC__SYS_LINUX)
200                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
201                 ;;
202         *-*-darwin*)
203                 sys_darwin=true
204                 AC_DEFINE(FLAC__SYS_DARWIN)
205                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
206                 ;;
207 esac
208 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
209 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
210
211 if test "x$cpu_ia32" = xtrue || test "x$cpu_x86_64" = xtrue ; then
212 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
213 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
214 fi
215
216 AM_CONDITIONAL([DEBUG], [test "x${ax_enable_debug}" = "xyes" || test "x${ax_enable_debug}" = "xinfo"])
217
218 AC_ARG_ENABLE(sse,
219 AC_HELP_STRING([--disable-sse], [Disable passing of -msse2 to the compiler]),
220 [case "${enableval}" in
221         yes) sse_os=yes ;;
222         no)  sse_os=no ;;
223         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
224 esac],[sse_os=yes])
225
226 AC_ARG_ENABLE(altivec,
227 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
228 [case "${enableval}" in
229         yes) use_altivec=true ;;
230         no)  use_altivec=false ;;
231         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
232 esac],[use_altivec=true])
233 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
234 if test "x$use_altivec" = xtrue ; then
235 AC_DEFINE(FLAC__USE_ALTIVEC)
236 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
237 fi
238
239 AC_ARG_ENABLE(avx,
240 AC_HELP_STRING([--disable-avx], [Disable AVX, AVX2 optimizations]),
241 [case "${enableval}" in
242         yes) use_avx=true ;;
243         no)  use_avx=false ;;
244         *) AC_MSG_ERROR(bad value ${enableval} for --enable-avx) ;;
245 esac],[use_avx=true])
246 AM_CONDITIONAL(FLaC__USE_AVX, test "x$use_avx" = xtrue)
247 if test "x$use_avx" = xtrue ; then
248 AC_DEFINE(FLAC__USE_AVX)
249 AH_TEMPLATE(FLAC__USE_AVX, [define to enable use of AVX instructions])
250 fi
251
252 AC_ARG_ENABLE(thorough-tests,
253 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
254 [case "${enableval}" in
255         yes) thorough_tests=true ;;
256         no)  thorough_tests=false ;;
257         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
258 esac],[thorough_tests=true])
259 AC_ARG_ENABLE(exhaustive-tests,
260 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
261 [case "${enableval}" in
262         yes) exhaustive_tests=true ;;
263         no)  exhaustive_tests=false ;;
264         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
265 esac],[exhaustive_tests=false])
266 if test "x$thorough_tests" = xfalse ; then
267 FLAC__TEST_LEVEL=0
268 elif test "x$exhaustive_tests" = xfalse ; then
269 FLAC__TEST_LEVEL=1
270 else
271 FLAC__TEST_LEVEL=2
272 fi
273 AC_SUBST(FLAC__TEST_LEVEL)
274
275 AC_ARG_ENABLE(werror,
276         AC_HELP_STRING([--enable-werror], [Enable -Werror in all Makefiles]))
277
278 AC_ARG_ENABLE(stack-smash-protection,
279         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
280
281 AC_ARG_ENABLE(64-bit-words,
282         AC_HELP_STRING([--enable-64-bit-words], [Set FLAC__BYTES_PER_WORD to 8 (4 is the default)]))
283 if test "x$enable_64_bit_words" = xyes ; then
284         AC_DEFINE_UNQUOTED([ENABLE_64_BIT_WORDS],1,[Set FLAC__BYTES_PER_WORD to 8 (4 is the default)])
285 else
286         AC_DEFINE_UNQUOTED([ENABLE_64_BIT_WORDS],0)
287         fi
288 AC_SUBST(ENABLE_64_BIT_WORDS)
289
290 AC_ARG_ENABLE(valgrind-testing,
291 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
292 [case "${enableval}" in
293         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
294         no)  FLAC__TEST_WITH_VALGRIND=no ;;
295         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
296 esac],[FLAC__TEST_WITH_VALGRIND=no])
297 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
298
299 AC_ARG_ENABLE(doxygen-docs,
300 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
301 [case "${enableval}" in
302         yes) enable_doxygen_docs=true ;;
303         no)  enable_doxygen_docs=false ;;
304         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
305 esac],[enable_doxygen_docs=true])
306 if test "x$enable_doxygen_docs" != xfalse ; then
307         AC_CHECK_PROGS(DOXYGEN, doxygen)
308 fi
309 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
310
311 AC_ARG_ENABLE(local-xmms-plugin,
312 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
313 [case "${enableval}" in
314         yes) install_xmms_plugin_locally=true ;;
315         no)  install_xmms_plugin_locally=false ;;
316         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
317 esac],[install_xmms_plugin_locally=false])
318 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
319
320 AC_ARG_ENABLE(xmms-plugin,
321 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
322 [case "${enableval}" in
323         yes) enable_xmms_plugin=true ;;
324         no)  enable_xmms_plugin=false ;;
325         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
326 esac],[enable_xmms_plugin=true])
327 if test "x$enable_xmms_plugin" != xfalse ; then
328         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
329 fi
330 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
331
332 dnl build FLAC++ or not
333 AC_ARG_ENABLE([cpplibs],
334 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
335 [case "${enableval}" in
336         yes) disable_cpplibs=false ;;
337         no)  disable_cpplibs=true ;;
338         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
339 esac], [disable_cpplibs=false])
340 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
341
342 dnl check for ogg library
343 AC_ARG_ENABLE([ogg],
344         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
345         [ want_ogg=$enableval ], [ want_ogg=yes ] )
346
347 if test "x$want_ogg" != "xno"; then
348         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
349 fi
350
351 FLAC__HAS_OGG=0
352 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
353 if test "x$have_ogg" = xyes ; then
354         FLAC__HAS_OGG=1
355         OGG_PACKAGE="ogg"
356 else
357         have_ogg=no
358 fi
359 AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],$FLAC__HAS_OGG,[define if you have the ogg library])
360 AC_SUBST(FLAC__HAS_OGG)
361 AC_SUBST(OGG_PACKAGE)
362
363 dnl Build examples?
364 AC_ARG_ENABLE([examples],
365         AS_HELP_STRING([--disable-examples], [Don't build and install examples]))
366 AM_CONDITIONAL([EXAMPLES], [test "x$enable_examples" != "xno"])
367
368 dnl check for i18n(internationalization); these are from libiconv/gettext
369 AM_ICONV
370 AM_LANGINFO_CODESET
371
372 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
373 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
374 if test -n "$DOCBOOK_TO_MAN" ; then
375 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
376 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
377 fi
378
379 AC_CHECK_LIB(rt, clock_gettime, have_clock_gettime=yes)
380 if test x$have_clock_gettime = xyes; then
381         AC_DEFINE(HAVE_CLOCK_GETTIME)
382         AH_TEMPLATE(HAVE_CLOCK_GETTIME, [define if you have clock_gettime])
383 fi
384
385 # only matters for x86
386 AC_CHECK_PROGS(NASM, nasm)
387 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
388 if test -n "$NASM" ; then
389 AC_DEFINE(FLAC__HAS_NASM)
390 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
391 fi
392
393 dnl If debugging is disabled AND no CFLAGS/CXXFLAGS/CPPFLAGS/LDFLAGS
394 dnl are provided, we can set defaults to our liking
395 AS_IF([test "x${ax_enable_debug}" = "xno" && test "x${enable_flags_setting}" = "xyes"], [
396         CFLAGS="-O3 -funroll-loops"
397 ])
398
399 XIPH_GCC_VERSION
400
401 if test x$ac_cv_c_compiler_gnu = xyes ; then
402         CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations -Winline " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Wconversion
403         CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
404
405         XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
406
407         dnl some distributions (such as Gentoo) have _FORTIFY_SOURCE always
408         dnl enabled. We test for this situation in order to prevent polluting
409         dnl the console with messages of macro redefinitions.
410         AX_ADD_FORTIFY_SOURCE
411
412         AC_LANG_PUSH([C++])
413         XIPH_ADD_CXXFLAGS([-Weffc++])
414         AC_LANG_POP([C++])
415
416         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
417                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
418                 CFLAGS="$CFLAGS -fvisibility=hidden"
419                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
420                 fi
421
422         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = macho; then
423                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
424                 CFLAGS="$CFLAGS -fvisibility=hidden"
425                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
426                 fi
427
428         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
429                 XIPH_ADD_CFLAGS([-fgnu89-inline])
430                 fi
431
432         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x47" ; then
433                 XIPH_ADD_CFLAGS([-fno-inline-small-functions])
434                 fi
435
436         if test "x$asm_optimisation$sse_os" = "xyesyes" ; then
437                 XIPH_ADD_CFLAGS([-msse2])
438                 fi
439
440         fi
441
442 case "$host_os" in
443         "mingw32"|"os2")
444         if test "$host_cpu" = "i686"; then
445                 XIPH_ADD_CFLAGS([-mstackrealign])
446                 fi
447         esac
448
449 if test x$enable_werror = "xyes" ; then
450         XIPH_ADD_CFLAGS([-Werror])
451         AC_LANG_PUSH([C++])
452         XIPH_ADD_CXXFLAGS([-Werror])
453         AC_LANG_POP([C++])
454         fi
455
456 if test x$enable_stack_smash_protection = "xyes" ; then
457         XIPH_GCC_STACK_PROTECTOR
458         XIPH_GXX_STACK_PROTECTOR
459         fi
460
461 if test "x$sys_linux" = xtrue ; then
462        LIB_CLOCK_GETTIME=-lrt
463        fi
464 AC_SUBST(LIB_CLOCK_GETTIME)
465
466 AC_CONFIG_FILES([ \
467         Makefile \
468         src/Makefile \
469         src/libFLAC/Makefile \
470         src/libFLAC/flac.pc \
471         src/libFLAC/ia32/Makefile \
472         src/libFLAC/include/Makefile \
473         src/libFLAC/include/private/Makefile \
474         src/libFLAC/include/protected/Makefile \
475         src/libFLAC++/Makefile \
476         src/libFLAC++/flac++.pc \
477         src/flac/Makefile \
478         src/metaflac/Makefile \
479         src/plugin_common/Makefile \
480         src/plugin_xmms/Makefile \
481         src/share/Makefile \
482         src/test_grabbag/Makefile \
483         src/test_grabbag/cuesheet/Makefile \
484         src/test_grabbag/picture/Makefile \
485         src/test_libs_common/Makefile \
486         src/test_libFLAC/Makefile \
487         src/test_libFLAC++/Makefile \
488         src/test_seeking/Makefile \
489         src/test_streams/Makefile \
490         src/utils/Makefile \
491         src/utils/flacdiff/Makefile \
492         src/utils/flactimer/Makefile \
493         examples/Makefile \
494         examples/c/Makefile \
495         examples/c/decode/Makefile \
496         examples/c/decode/file/Makefile \
497         examples/c/encode/Makefile \
498         examples/c/encode/file/Makefile \
499         examples/cpp/Makefile \
500         examples/cpp/decode/Makefile \
501         examples/cpp/decode/file/Makefile \
502         examples/cpp/encode/Makefile \
503         examples/cpp/encode/file/Makefile \
504         include/Makefile \
505         include/FLAC/Makefile \
506         include/FLAC++/Makefile \
507         include/share/Makefile \
508         include/share/grabbag/Makefile \
509         include/test_libs_common/Makefile \
510         doc/Doxyfile \
511         doc/Makefile \
512         doc/html/Makefile \
513         doc/html/images/Makefile \
514         m4/Makefile \
515         man/Makefile \
516         test/common.sh \
517         test/Makefile \
518         test/cuesheets/Makefile \
519         test/flac-to-flac-metadata-test-files/Makefile \
520         test/metaflac-test-files/Makefile \
521         test/pictures/Makefile \
522         build/Makefile \
523         objs/Makefile \
524         objs/debug/Makefile \
525         objs/debug/bin/Makefile \
526         objs/debug/lib/Makefile \
527         objs/release/Makefile \
528         objs/release/bin/Makefile \
529         objs/release/lib/Makefile \
530         microbench/Makefile
531 ])
532 AC_OUTPUT
533
534 AC_MSG_RESULT([
535 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
536
537   Configuration summary :
538
539     FLAC version : ........................ ${VERSION}
540
541     Host CPU : ............................ ${host_cpu}
542     Host Vendor : ......................... ${host_vendor}
543     Host OS : ............................. ${host_os}
544 ])
545
546         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
547 if test x$ac_cv_c_compiler_gnu = xyes ; then
548         echo "    GCC version : ......................... ${GCC_VERSION}"
549 fi
550         echo "    Compiler is Clang : ................... ${xiph_cv_c_compiler_clang}"
551         echo "    SSE optimizations : ................... ${sse_os}"
552         echo "    Asm optimizations : ................... ${asm_optimisation}"
553         echo "    Ogg/FLAC support : .................... ${have_ogg}"
554 echo