libFLAC: Support 64bit brword/bwword
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.1], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.10 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 XIPH_C_COMPILER_IS_CLANG
39 XIPH_GCC_REALLY_IS_GCC
40 AC_PROG_MAKE_SET
41 AC_PROG_MKDIR_P
42
43 AC_SYS_LARGEFILE
44 AC_FUNC_FSEEKO
45
46 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
47 AC_CHECK_SIZEOF([void*])
48 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
49
50 AC_LANG_PUSH([C++])
51 # c++ flavor first
52 AC_C_VARARRAYS
53 if test $ac_cv_c_vararrays = yes; then
54         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
55 fi
56 AC_LANG_POP([C++])
57
58 # c flavor
59 AC_HEADER_STDC
60 AM_PROG_CC_C_O
61 AC_C_INLINE
62 AC_C_VARARRAYS
63 AC_C_TYPEOF
64
65 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h termios.h x86intrin.h cpuid.h])
66
67 AC_HEADER_TIOCGWINSZ
68
69 XIPH_C_BSWAP32
70 XIPH_C_BSWAP16
71
72 ac_cv_c_big_endian=0
73 ac_cv_c_little_endian=0
74 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
75         AC_MSG_WARN([[*****************************************************************]])
76         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
77         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
78         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
79         AC_MSG_WARN([[*****************************************************************]])
80 ])
81 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
82                                         [Target processor is big endian.])
83 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
84                                         [Target processor is little endian.])
85 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
86                                         [Target processor is big endian.])
87
88 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
89 dnl ' Terminate the damn single quote
90 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
91 if test "x$asm_opt" = xno ; then
92 AC_DEFINE(FLAC__NO_ASM)
93 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
94 fi
95
96 # For the XMMS plugin.
97 AC_CHECK_TYPES(socklen_t, [], [])
98
99 dnl check for getopt in standard library
100 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
101 AC_CHECK_FUNCS(getopt_long, [], [])
102
103 AC_CHECK_SIZEOF(void*,1)
104
105 asm_optimisation=no
106 case "$host_cpu" in
107         amd64|x86_64)
108                 case "$host" in
109                         *gnux32)
110                                 # x32 user space and 64 bit kernel.
111                                 cpu_x86_64=true
112                                 AC_DEFINE(FLAC__CPU_X86_64)
113                                 AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
114                                 asm_optimisation=$asm_opt
115                                 ;;
116                         *)
117                                 if test $ac_cv_sizeof_voidp = 4 ; then
118                                         # This must be a 32 bit user space running on 64 bit kernel so treat
119                                         # this as ia32.
120                                         cpu_ia32=true
121                                         AC_DEFINE(FLAC__CPU_IA32)
122                                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
123                         else
124                                         # x86_64 user space and kernel.
125                                         cpu_x86_64=true
126                                         AC_DEFINE(FLAC__CPU_X86_64)
127                                         AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
128                                 fi
129                                 asm_optimisation=$asm_opt
130                                 ;;
131                 esac
132                 ;;
133         i*86)
134                 cpu_ia32=true
135                 AC_DEFINE(FLAC__CPU_IA32)
136                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
137                 asm_optimisation=$asm_opt
138                 ;;
139         powerpc|powerpc64)
140                 cpu_ppc=true
141                 AC_DEFINE(FLAC__CPU_PPC)
142                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
143                 asm_optimisation=$asm_opt
144                 ;;
145         sparc)
146                 cpu_sparc=true
147                 AC_DEFINE(FLAC__CPU_SPARC)
148                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
149                 asm_optimisation=$asm_opt
150                 ;;
151 esac
152 AM_CONDITIONAL(FLAC__CPU_X86_64, test "x$cpu_x86_64" = xtrue)
153 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
154 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
155 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
156
157 if test "x$ac_cv_header_x86intrin_h" = xyes; then
158 AC_DEFINE([FLAC__HAS_X86INTRIN], 1, [Set to 1 if <x86intrin.h> is available.])
159 fi
160
161 case "$host" in
162         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
163         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
164         *-*-darwin*) OBJ_FORMAT=macho ;;
165         *emx*) OBJ_FORMAT=aout ;;
166         *) OBJ_FORMAT=elf ;;
167 esac
168 AC_SUBST(OBJ_FORMAT)
169 case "$host" in
170         *-gnuspe)
171                 abi_spe=true
172                 AC_DEFINE(FLAC__CPU_PPC_SPE)
173                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
174                 ;;
175 esac
176 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
177
178 os_is_windows=no
179 case "$host" in
180         *-*-cygwin|*mingw*)
181                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
182                 os_is_windows=yes
183                 ;;
184 esac
185
186 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
187
188 case "$host" in
189         *-pc-linux-gnu)
190                 sys_linux=true
191                 AC_DEFINE(FLAC__SYS_LINUX)
192                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
193                 ;;
194         *-*-darwin*)
195                 sys_darwin=true
196                 AC_DEFINE(FLAC__SYS_DARWIN)
197                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
198                 ;;
199 esac
200 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
201 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
202
203 if test "x$cpu_ia32" = xtrue || test "x$cpu_x86_64" = xtrue ; then
204 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
205 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
206 fi
207
208 AC_ARG_ENABLE(debug,
209 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
210 [case "${enableval}" in
211         yes) debug=true ;;
212         no)  debug=false ;;
213         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
214 esac],[debug=false])
215 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
216
217 AC_ARG_ENABLE(sse,
218 AC_HELP_STRING([--disable-sse], [Disable SSE if the OS does not support SSE instructions]),
219 [case "${enableval}" in
220         yes) sse_os=yes ;;
221         no)  sse_os=no ;;
222         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
223 esac],[sse_os=yes])
224 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xyes)
225 if test "x$sse_os" = xyes ; then
226 AC_DEFINE(FLAC__SSE_OS)
227 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
228 fi
229
230 AC_ARG_ENABLE(altivec,
231 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
232 [case "${enableval}" in
233         yes) use_altivec=true ;;
234         no)  use_altivec=false ;;
235         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
236 esac],[use_altivec=true])
237 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
238 if test "x$use_altivec" = xtrue ; then
239 AC_DEFINE(FLAC__USE_ALTIVEC)
240 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
241 fi
242
243 AC_ARG_ENABLE(thorough-tests,
244 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
245 [case "${enableval}" in
246         yes) thorough_tests=true ;;
247         no)  thorough_tests=false ;;
248         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
249 esac],[thorough_tests=true])
250 AC_ARG_ENABLE(exhaustive-tests,
251 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
252 [case "${enableval}" in
253         yes) exhaustive_tests=true ;;
254         no)  exhaustive_tests=false ;;
255         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
256 esac],[exhaustive_tests=false])
257 if test "x$thorough_tests" = xfalse ; then
258 FLAC__TEST_LEVEL=0
259 elif test "x$exhaustive_tests" = xfalse ; then
260 FLAC__TEST_LEVEL=1
261 else
262 FLAC__TEST_LEVEL=2
263 fi
264 AC_SUBST(FLAC__TEST_LEVEL)
265
266 AC_ARG_ENABLE(werror,
267         AC_HELP_STRING([--enable-werror], [Enable -Werror in all Makefiles]))
268
269 AC_ARG_ENABLE(stack-smash-protection,
270         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
271
272 AC_ARG_ENABLE(valgrind-testing,
273 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
274 [case "${enableval}" in
275         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
276         no)  FLAC__TEST_WITH_VALGRIND=no ;;
277         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
278 esac],[FLAC__TEST_WITH_VALGRIND=no])
279 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
280
281 AC_ARG_ENABLE(doxygen-docs,
282 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
283 [case "${enableval}" in
284         yes) enable_doxygen_docs=true ;;
285         no)  enable_doxygen_docs=false ;;
286         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
287 esac],[enable_doxygen_docs=true])
288 if test "x$enable_doxygen_docs" != xfalse ; then
289         AC_CHECK_PROGS(DOXYGEN, doxygen)
290 fi
291 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
292
293 AC_ARG_ENABLE(local-xmms-plugin,
294 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
295 [case "${enableval}" in
296         yes) install_xmms_plugin_locally=true ;;
297         no)  install_xmms_plugin_locally=false ;;
298         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
299 esac],[install_xmms_plugin_locally=false])
300 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
301
302 AC_ARG_ENABLE(xmms-plugin,
303 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
304 [case "${enableval}" in
305         yes) enable_xmms_plugin=true ;;
306         no)  enable_xmms_plugin=false ;;
307         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
308 esac],[enable_xmms_plugin=true])
309 if test "x$enable_xmms_plugin" != xfalse ; then
310         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
311 fi
312 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
313
314 dnl build FLAC++ or not
315 AC_ARG_ENABLE([cpplibs],
316 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
317 [case "${enableval}" in
318         yes) disable_cpplibs=false ;;
319         no)  disable_cpplibs=true ;;
320         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
321 esac], [disable_cpplibs=false])
322 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
323
324 dnl check for ogg library
325 AC_ARG_ENABLE([ogg],
326         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
327         [ want_ogg=$enableval ], [ want_ogg=yes ] )
328
329 if test "x$want_ogg" != "xno"; then
330         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
331 fi
332
333 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
334 if test "x$have_ogg" = xyes ; then
335         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
336         OGG_PACKAGE="ogg"
337 else
338         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
339         have_ogg=no
340 fi
341 AC_SUBST(OGG_PACKAGE)
342
343 dnl check for i18n(internationalization); these are from libiconv/gettext
344 AM_ICONV
345 AM_LANGINFO_CODESET
346
347 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
348 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
349 if test -n "$DOCBOOK_TO_MAN" ; then
350 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
351 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
352 fi
353
354 # only matters for x86
355 AC_CHECK_PROGS(NASM, nasm)
356 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
357 if test -n "$NASM" ; then
358 AC_DEFINE(FLAC__HAS_NASM)
359 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
360 fi
361
362 if test "x$debug" = xtrue; then
363         CPPFLAGS="-DDEBUG $CPPFLAGS"
364         CFLAGS="-g $CFLAGS"
365 else
366         CPPFLAGS="-DNDEBUG $CPPFLAGS"
367         CFLAGS=$(echo "$CFLAGS" | sed 's/-O2//')
368         CFLAGS="-O3 -funroll-loops $CFLAGS"
369 fi
370
371 XIPH_GCC_VERSION
372
373 if test x$ac_cv_c_compiler_gnu = xyes ; then
374         CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations -Wunreachable-code -Winline " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Wconversion
375         CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef -Wunreachable-code " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
376
377         XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
378         XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
379
380         AC_LANG_PUSH([C++])
381         XIPH_ADD_CXXFLAGS([-Weffc++])
382         AC_LANG_POP([C++])
383
384         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
385                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
386                 CFLAGS="$CFLAGS -fvisibility=hidden"
387                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
388                 fi
389
390         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = macho; then
391                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
392                 CFLAGS="$CFLAGS -fvisibility=hidden"
393                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
394                 fi
395
396         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
397                 XIPH_ADD_CFLAGS([-fgnu89-inline])
398                 fi
399
400         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x47" ; then
401                 XIPH_ADD_CFLAGS([-fno-inline-small-functions])
402                 fi
403
404         if test "x$asm_optimisation$sse_os" = "xyesyes" ; then
405                 XIPH_ADD_CFLAGS([-msse2])
406                 fi
407
408         fi
409
410 case "$host_os" in
411         "mingw32"|"os2")
412         if test "$host_cpu" = "i686"; then
413                 XIPH_ADD_CFLAGS([-mstackrealign])
414                 fi
415         esac
416
417 XIPH_ADD_CFLAGS([-Wextra])
418
419 if test x$enable_werror = "xyes" ; then
420         XIPH_ADD_CFLAGS([-Werror])
421         AC_LANG_PUSH([C++])
422         XIPH_ADD_CXXFLAGS([-Werror])
423         AC_LANG_POP([C++])
424         fi
425
426 if test x$enable_stack_smash_protection = "xyes" ; then
427         XIPH_GCC_STACK_PROTECTOR
428         XIPH_GXX_STACK_PROTECTOR
429         fi
430
431 AC_CONFIG_FILES([ \
432         Makefile \
433         src/Makefile \
434         src/libFLAC/Makefile \
435         src/libFLAC/flac.pc \
436         src/libFLAC/ia32/Makefile \
437         src/libFLAC/include/Makefile \
438         src/libFLAC/include/private/Makefile \
439         src/libFLAC/include/protected/Makefile \
440         src/libFLAC++/Makefile \
441         src/libFLAC++/flac++.pc \
442         src/flac/Makefile \
443         src/metaflac/Makefile \
444         src/plugin_common/Makefile \
445         src/plugin_xmms/Makefile \
446         src/share/Makefile \
447         src/test_grabbag/Makefile \
448         src/test_grabbag/cuesheet/Makefile \
449         src/test_grabbag/picture/Makefile \
450         src/test_libs_common/Makefile \
451         src/test_libFLAC/Makefile \
452         src/test_libFLAC++/Makefile \
453         src/test_seeking/Makefile \
454         src/test_streams/Makefile \
455         src/utils/Makefile \
456         src/utils/flacdiff/Makefile \
457         src/utils/flactimer/Makefile \
458         examples/Makefile \
459         examples/c/Makefile \
460         examples/c/decode/Makefile \
461         examples/c/decode/file/Makefile \
462         examples/c/encode/Makefile \
463         examples/c/encode/file/Makefile \
464         examples/cpp/Makefile \
465         examples/cpp/decode/Makefile \
466         examples/cpp/decode/file/Makefile \
467         examples/cpp/encode/Makefile \
468         examples/cpp/encode/file/Makefile \
469         include/Makefile \
470         include/FLAC/Makefile \
471         include/FLAC++/Makefile \
472         include/share/Makefile \
473         include/share/grabbag/Makefile \
474         include/test_libs_common/Makefile \
475         doc/Doxyfile \
476         doc/Makefile \
477         doc/html/Makefile \
478         doc/html/images/Makefile \
479         m4/Makefile \
480         man/Makefile \
481         test/common.sh \
482         test/Makefile \
483         test/cuesheets/Makefile \
484         test/flac-to-flac-metadata-test-files/Makefile \
485         test/metaflac-test-files/Makefile \
486         test/pictures/Makefile \
487         build/Makefile \
488         objs/Makefile \
489         objs/debug/Makefile \
490         objs/debug/bin/Makefile \
491         objs/debug/lib/Makefile \
492         objs/release/Makefile \
493         objs/release/bin/Makefile \
494         objs/release/lib/Makefile \
495         microbench/Makefile
496 ])
497 AC_OUTPUT
498
499 AC_MSG_RESULT([
500 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
501
502   Configuration summary :
503
504     FLAC version : ........................ ${VERSION}
505
506     Host CPU : ............................ ${host_cpu}
507     Host Vendor : ......................... ${host_vendor}
508     Host OS : ............................. ${host_os}
509 ])
510
511         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
512 if test x$ac_cv_c_compiler_gnu = xyes ; then
513         echo "    GCC version : ......................... ${GCC_VERSION}"
514 fi
515         echo "    Compiler is Clang : ................... ${xiph_cv_c_compiler_clang}"
516         echo "    SSE optimizations : ................... ${sse_os}"
517         echo "    Asm optimizations : ................... ${asm_optimisation}"
518         echo "    Ogg/FLAC support : .................... ${have_ogg}"
519 echo