flac/vorbiscomment.c : Fix typo.
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.1], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.10 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 XIPH_C_COMPILER_IS_CLANG
39 XIPH_GCC_REALLY_IS_GCC
40 AC_PROG_MAKE_SET
41 AC_PROG_MKDIR_P
42
43 AC_SYS_LARGEFILE
44 AC_FUNC_FSEEKO
45
46 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
47 AC_CHECK_SIZEOF([void*])
48 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
49
50 AC_LANG_PUSH([C++])
51 # c++ flavor first
52 AC_C_VARARRAYS
53 if test $ac_cv_c_vararrays = yes; then
54         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
55 fi
56 AC_LANG_POP([C++])
57
58 # c flavor
59 AC_HEADER_STDC
60 AM_PROG_CC_C_O
61 AC_C_INLINE
62 AC_C_VARARRAYS
63 AC_C_TYPEOF
64
65 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h termios.h x86intrin.h cpuid.h])
66
67 AC_HEADER_TIOCGWINSZ
68
69 XIPH_C_BSWAP32
70 XIPH_C_BSWAP16
71
72 ac_cv_c_big_endian=0
73 ac_cv_c_little_endian=0
74 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
75         AC_MSG_WARN([[*****************************************************************]])
76         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
77         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
78         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
79         AC_MSG_WARN([[*****************************************************************]])
80 ])
81 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
82                                         [Target processor is big endian.])
83 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
84                                         [Target processor is little endian.])
85 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
86                                         [Target processor is big endian.])
87
88 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
89 dnl ' Terminate the damn single quote
90 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
91 if test "x$asm_opt" = xno ; then
92 AC_DEFINE(FLAC__NO_ASM)
93 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
94 fi
95
96 # For the XMMS plugin.
97 AC_CHECK_TYPES(socklen_t, [], [])
98
99 dnl check for getopt in standard library
100 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
101 AC_CHECK_FUNCS(getopt_long, [], [])
102
103 AC_CHECK_SIZEOF(void*,1)
104
105 asm_optimisation=no
106 case "$host_cpu" in
107         x86_64)
108                 if test $ac_cv_sizeof_voidp = 4 ; then
109                         # This must be a 32 bit user space running on 64 bit kernel so treat
110                         # this as ia32.
111                         cpu_ia32=true
112                         AC_DEFINE(FLAC__CPU_IA32)
113                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
114                 else
115                         # x86_64 user space and kernel.
116                         cpu_x86_64=true
117                         AC_DEFINE(FLAC__CPU_X86_64)
118                         AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
119                         fi
120                 asm_optimisation=$asm_opt
121                 ;;
122         i*86)
123                 cpu_ia32=true
124                 AC_DEFINE(FLAC__CPU_IA32)
125                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
126                 asm_optimisation=$asm_opt
127                 ;;
128         powerpc|powerpc64)
129                 cpu_ppc=true
130                 AC_DEFINE(FLAC__CPU_PPC)
131                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
132                 asm_optimisation=$asm_opt
133                 ;;
134         sparc)
135                 cpu_sparc=true
136                 AC_DEFINE(FLAC__CPU_SPARC)
137                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
138                 asm_optimisation=$asm_opt
139                 ;;
140 esac
141 AM_CONDITIONAL(FLAC__CPU_X86_64, test "x$cpu_x86_64" = xtrue)
142 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
143 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
144 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
145
146 AC_DEFINE_UNQUOTED([FLAC__HAS_X86INTRIN],${HAVE_X86INTRIN_H}, [Set to 1 if <x86intrin.h> is available.])
147
148 case "$host" in
149         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
150         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
151         *-*-darwin*) OBJ_FORMAT=macho ;;
152         *emx*) OBJ_FORMAT=aout ;;
153         *) OBJ_FORMAT=elf ;;
154 esac
155 AC_SUBST(OBJ_FORMAT)
156 case "$host" in
157         *-gnuspe)
158                 abi_spe=true
159                 AC_DEFINE(FLAC__CPU_PPC_SPE)
160                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
161                 ;;
162 esac
163 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
164
165 os_is_windows=no
166 case "$host" in
167         *-*-cygwin|*mingw*)
168                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
169                 os_is_windows=yes
170                 ;;
171 esac
172
173 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
174
175 case "$host" in
176         *-pc-linux-gnu)
177                 sys_linux=true
178                 AC_DEFINE(FLAC__SYS_LINUX)
179                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
180                 ;;
181         *-*-darwin*)
182                 sys_darwin=true
183                 AC_DEFINE(FLAC__SYS_DARWIN)
184                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
185                 ;;
186 esac
187 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
188 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
189
190 if test "x$cpu_ia32" = xtrue || test "x$cpu_x86_64" = xtrue ; then
191 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
192 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
193 fi
194
195 AC_ARG_ENABLE(debug,
196 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
197 [case "${enableval}" in
198         yes) debug=true ;;
199         no)  debug=false ;;
200         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
201 esac],[debug=false])
202 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
203
204 AC_ARG_ENABLE(sse,
205 AC_HELP_STRING([--disable-sse], [Disable SSE if the OS does not support SSE instructions]),
206 [case "${enableval}" in
207         yes) sse_os=yes ;;
208         no)  sse_os=no ;;
209         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
210 esac],[sse_os=yes])
211 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
212 if test "x$sse_os" = xyes ; then
213 AC_DEFINE(FLAC__SSE_OS)
214 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
215 fi
216
217 AC_ARG_ENABLE(altivec,
218 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
219 [case "${enableval}" in
220         yes) use_altivec=true ;;
221         no)  use_altivec=false ;;
222         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
223 esac],[use_altivec=true])
224 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
225 if test "x$use_altivec" = xtrue ; then
226 AC_DEFINE(FLAC__USE_ALTIVEC)
227 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
228 fi
229
230 AC_ARG_ENABLE(thorough-tests,
231 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
232 [case "${enableval}" in
233         yes) thorough_tests=true ;;
234         no)  thorough_tests=false ;;
235         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
236 esac],[thorough_tests=true])
237 AC_ARG_ENABLE(exhaustive-tests,
238 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
239 [case "${enableval}" in
240         yes) exhaustive_tests=true ;;
241         no)  exhaustive_tests=false ;;
242         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
243 esac],[exhaustive_tests=false])
244 if test "x$thorough_tests" = xfalse ; then
245 FLAC__TEST_LEVEL=0
246 elif test "x$exhaustive_tests" = xfalse ; then
247 FLAC__TEST_LEVEL=1
248 else
249 FLAC__TEST_LEVEL=2
250 fi
251 AC_SUBST(FLAC__TEST_LEVEL)
252
253 AC_ARG_ENABLE(werror,
254         AC_HELP_STRING([--enable-werror], [Enable -Werror in all Makefiles]))
255
256 AC_ARG_ENABLE(stack-smash-protection,
257         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
258
259 AC_ARG_ENABLE(valgrind-testing,
260 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
261 [case "${enableval}" in
262         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
263         no)  FLAC__TEST_WITH_VALGRIND=no ;;
264         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
265 esac],[FLAC__TEST_WITH_VALGRIND=no])
266 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
267
268 AC_ARG_ENABLE(doxygen-docs,
269 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
270 [case "${enableval}" in
271         yes) enable_doxygen_docs=true ;;
272         no)  enable_doxygen_docs=false ;;
273         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
274 esac],[enable_doxygen_docs=true])
275 if test "x$enable_doxygen_docs" != xfalse ; then
276         AC_CHECK_PROGS(DOXYGEN, doxygen)
277 fi
278 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
279
280 AC_ARG_ENABLE(local-xmms-plugin,
281 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
282 [case "${enableval}" in
283         yes) install_xmms_plugin_locally=true ;;
284         no)  install_xmms_plugin_locally=false ;;
285         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
286 esac],[install_xmms_plugin_locally=false])
287 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
288
289 AC_ARG_ENABLE(xmms-plugin,
290 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
291 [case "${enableval}" in
292         yes) enable_xmms_plugin=true ;;
293         no)  enable_xmms_plugin=false ;;
294         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
295 esac],[enable_xmms_plugin=true])
296 if test "x$enable_xmms_plugin" != xfalse ; then
297         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
298 fi
299 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
300
301 dnl build FLAC++ or not
302 AC_ARG_ENABLE([cpplibs],
303 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
304 [case "${enableval}" in
305         yes) disable_cpplibs=false ;;
306         no)  disable_cpplibs=true ;;
307         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
308 esac], [disable_cpplibs=false])
309 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
310
311 dnl check for ogg library
312 AC_ARG_ENABLE([ogg],
313         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
314         [ want_ogg=$enableval ], [ want_ogg=yes ] )
315
316 if test "x$want_ogg" != "xno"; then
317         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
318 fi
319
320 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
321 if test "x$have_ogg" = xyes ; then
322         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
323         OGG_PACKAGE="ogg"
324 else
325         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
326         have_ogg=no
327 fi
328 AC_SUBST(OGG_PACKAGE)
329
330 dnl check for i18n(internationalization); these are from libiconv/gettext
331 AM_ICONV
332 AM_LANGINFO_CODESET
333
334 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
335 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
336 if test -n "$DOCBOOK_TO_MAN" ; then
337 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
338 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
339 fi
340
341 # only matters for x86
342 AC_CHECK_PROGS(NASM, nasm)
343 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
344 if test -n "$NASM" ; then
345 AC_DEFINE(FLAC__HAS_NASM)
346 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
347 fi
348
349 if test "x$debug" = xtrue; then
350         CPPFLAGS="-DDEBUG $CPPFLAGS"
351         CFLAGS="-g $CFLAGS"
352 else
353         CPPFLAGS="-DNDEBUG $CPPFLAGS"
354         CFLAGS=$(echo "$CFLAGS" | sed 's/-O2//')
355         CFLAGS="-O3 -funroll-loops $CFLAGS"
356 fi
357
358 XIPH_GCC_VERSION
359
360 if test x$ac_cv_c_compiler_gnu = xyes ; then
361         CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations -Wunreachable-code -Winline " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Wconversion
362         CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef -Wunreachable-code " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
363
364         XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
365         XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
366
367         AC_LANG_PUSH([C++])
368         XIPH_ADD_CXXFLAGS([-Weffc++])
369         AC_LANG_POP([C++])
370
371         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
372                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
373                 CFLAGS="$CFLAGS -fvisibility=hidden"
374                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
375                 fi
376
377         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = macho; then
378                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
379                 CFLAGS="$CFLAGS -fvisibility=hidden"
380                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
381                 fi
382
383         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
384                 XIPH_ADD_CFLAGS([-fgnu89-inline])
385                 fi
386
387         if test "x$asm_optimisation$sse_os" = "xyesyes" ; then
388                 XIPH_ADD_CFLAGS([-msse2])
389                 fi
390
391         fi
392
393 XIPH_ADD_CFLAGS([-Wextra])
394
395 if test x$enable_werror = "xyes" ; then
396         XIPH_ADD_CFLAGS([-Werror])
397         AC_LANG_PUSH([C++])
398         XIPH_ADD_CXXFLAGS([-Werror])
399         AC_LANG_POP([C++])
400         fi
401
402 if test x$enable_stack_smash_protection = "xyes" ; then
403         XIPH_GCC_STACK_PROTECTOR
404         XIPH_GXX_STACK_PROTECTOR
405         fi
406
407 AC_CONFIG_FILES([ \
408         Makefile \
409         src/Makefile \
410         src/libFLAC/Makefile \
411         src/libFLAC/flac.pc \
412         src/libFLAC/ia32/Makefile \
413         src/libFLAC/include/Makefile \
414         src/libFLAC/include/private/Makefile \
415         src/libFLAC/include/protected/Makefile \
416         src/libFLAC++/Makefile \
417         src/libFLAC++/flac++.pc \
418         src/flac/Makefile \
419         src/metaflac/Makefile \
420         src/plugin_common/Makefile \
421         src/plugin_xmms/Makefile \
422         src/share/Makefile \
423         src/test_grabbag/Makefile \
424         src/test_grabbag/cuesheet/Makefile \
425         src/test_grabbag/picture/Makefile \
426         src/test_libs_common/Makefile \
427         src/test_libFLAC/Makefile \
428         src/test_libFLAC++/Makefile \
429         src/test_seeking/Makefile \
430         src/test_streams/Makefile \
431         src/utils/Makefile \
432         src/utils/flacdiff/Makefile \
433         src/utils/flactimer/Makefile \
434         examples/Makefile \
435         examples/c/Makefile \
436         examples/c/decode/Makefile \
437         examples/c/decode/file/Makefile \
438         examples/c/encode/Makefile \
439         examples/c/encode/file/Makefile \
440         examples/cpp/Makefile \
441         examples/cpp/decode/Makefile \
442         examples/cpp/decode/file/Makefile \
443         examples/cpp/encode/Makefile \
444         examples/cpp/encode/file/Makefile \
445         include/Makefile \
446         include/FLAC/Makefile \
447         include/FLAC++/Makefile \
448         include/share/Makefile \
449         include/share/grabbag/Makefile \
450         include/test_libs_common/Makefile \
451         doc/Doxyfile \
452         doc/Makefile \
453         doc/html/Makefile \
454         doc/html/images/Makefile \
455         m4/Makefile \
456         man/Makefile \
457         test/common.sh \
458         test/Makefile \
459         test/cuesheets/Makefile \
460         test/flac-to-flac-metadata-test-files/Makefile \
461         test/metaflac-test-files/Makefile \
462         test/pictures/Makefile \
463         build/Makefile \
464         objs/Makefile \
465         objs/debug/Makefile \
466         objs/debug/bin/Makefile \
467         objs/debug/lib/Makefile \
468         objs/release/Makefile \
469         objs/release/bin/Makefile \
470         objs/release/lib/Makefile \
471 ])
472 AC_OUTPUT
473
474 AC_MSG_RESULT([
475 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
476
477   Configuration summary :
478
479     FLAC version : ........................ ${VERSION}
480
481     Host CPU : ............................ ${host_cpu}
482     Host Vendor : ......................... ${host_vendor}
483     Host OS : ............................. ${host_os}
484 ])
485
486         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
487 if test x$ac_cv_c_compiler_gnu = xyes ; then
488         echo "    GCC version : ......................... ${GCC_VERSION}"
489 fi
490         echo "    Compiler is Clang : ................... ${xiph_cv_c_compiler_clang}"
491         echo "    SSE optimizations : ................... ${sse_os}"
492         echo "    Asm optimizations : ................... ${asm_optimisation}"
493         echo "    Ogg/FLAC support : .................... ${have_ogg}"
494 echo