220fd558716213cdcd658f0861470267cd5a40a6
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.0], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.11 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 AC_PROG_MAKE_SET
39
40 AC_SYS_LARGEFILE
41 AC_FUNC_FSEEKO
42
43 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
44 AC_CHECK_SIZEOF([void*])
45 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
46
47 AC_LANG_PUSH([C++])
48 # c++ flavor first
49 AC_C_VARARRAYS
50 if test $ac_cv_c_vararrays = yes; then
51         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
52 fi
53 AC_LANG_POP([C++])
54
55 # c flavor
56 AC_HEADER_STDC
57 AM_PROG_CC_C_O
58 AC_C_INLINE
59 AC_C_VARARRAYS
60 AC_C_TYPEOF
61
62 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h termios.h])
63
64 AC_HEADER_TIOCGWINSZ
65
66 XIPH_C_BSWAP32
67
68 ac_cv_c_big_endian=0
69 ac_cv_c_little_endian=0
70 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
71         AC_MSG_WARN([[*****************************************************************]])
72         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
73         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
74         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
75         AC_MSG_WARN([[*****************************************************************]])
76 ])
77 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
78                                         [Target processor is big endian.])
79 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
80                                         [Target processor is little endian.])
81 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
82                                         [Target processor is big endian.])
83
84 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
85 dnl ' Terminate the damn single quote
86 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
87 if test "x$asm_opt" = xno ; then
88 AC_DEFINE(FLAC__NO_ASM)
89 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
90 fi
91
92 # For the XMMS plugin.
93 AC_CHECK_TYPES(socklen_t, [], [])
94
95 dnl check for getopt in standard library
96 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
97 AC_CHECK_FUNCS(getopt_long, [], [])
98
99 AC_CHECK_SIZEOF(void*,1)
100
101 asm_optimisation=no
102 case "$host_cpu" in
103         x86_64)
104                 if test $ac_cv_sizeof_voidp = 4 ; then
105                         cpu_ia32=true
106                         AC_DEFINE(FLAC__CPU_IA32)
107                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
108                         asm_optimisation=$asm_opt
109                         fi
110                 ;;
111         i*86)
112                 cpu_ia32=true
113                 AC_DEFINE(FLAC__CPU_IA32)
114                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
115                 asm_optimisation=$asm_opt
116                 ;;
117         powerpc|powerpc64)
118                 cpu_ppc=true
119                 AC_DEFINE(FLAC__CPU_PPC)
120                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
121                 asm_optimisation=$asm_opt
122                 ;;
123         sparc)
124                 cpu_sparc=true
125                 AC_DEFINE(FLAC__CPU_SPARC)
126                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
127                 asm_optimisation=$asm_opt
128                 ;;
129 esac
130 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
131 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
132 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
133
134 case "$host" in
135         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
136         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
137         *-*-darwin*) OBJ_FORMAT=macho ;;
138         *emx*) OBJ_FORMAT=aout ;;
139         *) OBJ_FORMAT=elf ;;
140 esac
141 AC_SUBST(OBJ_FORMAT)
142 case "$host" in
143         *-gnuspe)
144                 abi_spe=true
145                 AC_DEFINE(FLAC__CPU_PPC_SPE)
146                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
147                 ;;
148 esac
149 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
150
151 os_is_windows=no
152 case "$host" in
153         *-*-cygwin|*mingw*)
154                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
155                 os_is_windows=yes
156                 ;;
157 esac
158
159 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
160
161 case "$host" in
162         *-pc-linux-gnu)
163                 sys_linux=true
164                 AC_DEFINE(FLAC__SYS_LINUX)
165                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
166                 ;;
167         *-*-darwin*)
168                 sys_darwin=true
169                 AC_DEFINE(FLAC__SYS_DARWIN)
170                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
171                 ;;
172 esac
173 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
174 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
175
176 if test "x$cpu_ia32" = xtrue ; then
177 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
178 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
179 fi
180
181 AC_ARG_ENABLE(debug,
182 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
183 [case "${enableval}" in
184         yes) debug=true ;;
185         no)  debug=false ;;
186         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
187 esac],[debug=false])
188 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
189
190 AC_ARG_ENABLE(sse,
191 AC_HELP_STRING([--enable-sse], [Enable SSE support by asserting that the OS supports SSE instructions]),
192 [case "${enableval}" in
193         yes) sse_os=true ;;
194         no)  sse_os=false ;;
195         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
196 esac],[sse_os=false])
197 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
198 if test "x$sse_os" = xtrue ; then
199 AC_DEFINE(FLAC__SSE_OS)
200 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
201 fi
202
203 AC_ARG_ENABLE(3dnow,
204 AC_HELP_STRING([--disable-3dnow], [Disable 3DNOW! optimizations]),
205 [case "${enableval}" in
206         yes) use_3dnow=true ;;
207         no)  use_3dnow=false ;;
208         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
209 esac],[use_3dnow=true])
210 AM_CONDITIONAL(FLaC__USE_3DNOW, test "x$use_3dnow" = xtrue)
211 if test "x$use_3dnow" = xtrue ; then
212 AC_DEFINE(FLAC__USE_3DNOW)
213 AH_TEMPLATE(FLAC__USE_3DNOW, [define to enable use of 3Dnow! instructions])
214 fi
215
216 AC_ARG_ENABLE(altivec,
217 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
218 [case "${enableval}" in
219         yes) use_altivec=true ;;
220         no)  use_altivec=false ;;
221         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
222 esac],[use_altivec=true])
223 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
224 if test "x$use_altivec" = xtrue ; then
225 AC_DEFINE(FLAC__USE_ALTIVEC)
226 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
227 fi
228
229 AC_ARG_ENABLE(thorough-tests,
230 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
231 [case "${enableval}" in
232         yes) thorough_tests=true ;;
233         no)  thorough_tests=false ;;
234         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
235 esac],[thorough_tests=true])
236 AC_ARG_ENABLE(exhaustive-tests,
237 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
238 [case "${enableval}" in
239         yes) exhaustive_tests=true ;;
240         no)  exhaustive_tests=false ;;
241         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
242 esac],[exhaustive_tests=false])
243 if test "x$thorough_tests" = xfalse ; then
244 FLAC__TEST_LEVEL=0
245 elif test "x$exhaustive_tests" = xfalse ; then
246 FLAC__TEST_LEVEL=1
247 else
248 FLAC__TEST_LEVEL=2
249 fi
250 AC_SUBST(FLAC__TEST_LEVEL)
251
252 AC_ARG_ENABLE(gcc-werror,
253         AC_HELP_STRING([--enable-gcc-werror], [Enable -Werror in all Makefiles]))
254
255 AC_ARG_ENABLE(stack-smash-protection,
256         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
257
258 AC_ARG_ENABLE(valgrind-testing,
259 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
260 [case "${enableval}" in
261         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
262         no)  FLAC__TEST_WITH_VALGRIND=no ;;
263         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
264 esac],[FLAC__TEST_WITH_VALGRIND=no])
265 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
266
267 AC_ARG_ENABLE(doxygen-docs,
268 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
269 [case "${enableval}" in
270         yes) enable_doxygen_docs=true ;;
271         no)  enable_doxygen_docs=false ;;
272         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
273 esac],[enable_doxygen_docs=true])
274 if test "x$enable_doxygen_docs" != xfalse ; then
275         AC_CHECK_PROGS(DOXYGEN, doxygen)
276 fi
277 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
278
279 AC_ARG_ENABLE(local-xmms-plugin,
280 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
281 [case "${enableval}" in
282         yes) install_xmms_plugin_locally=true ;;
283         no)  install_xmms_plugin_locally=false ;;
284         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
285 esac],[install_xmms_plugin_locally=false])
286 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
287
288 AC_ARG_ENABLE(xmms-plugin,
289 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
290 [case "${enableval}" in
291         yes) enable_xmms_plugin=true ;;
292         no)  enable_xmms_plugin=false ;;
293         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
294 esac],[enable_xmms_plugin=true])
295 if test "x$enable_xmms_plugin" != xfalse ; then
296         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
297 fi
298 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
299
300 dnl build FLAC++ or not
301 AC_ARG_ENABLE([cpplibs],
302 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
303 [case "${enableval}" in
304         yes) disable_cpplibs=false ;;
305         no)  disable_cpplibs=true ;;
306         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
307 esac], [disable_cpplibs=false])
308 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
309
310 dnl check for ogg library
311 AC_ARG_ENABLE([ogg],
312         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
313         [ want_ogg=$enableval ], [ want_ogg=yes ] )
314
315 if test "x$want_ogg" != "xno"; then
316         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
317 fi
318
319 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
320 if test "x$have_ogg" = xyes ; then
321         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
322         OGG_PACKAGE="ogg"
323 else
324         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
325 fi
326 AC_SUBST(OGG_PACKAGE)
327
328 dnl check for i18n(internationalization); these are from libiconv/gettext
329 AM_ICONV
330 AM_LANGINFO_CODESET
331
332 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
333 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
334 if test -n "$DOCBOOK_TO_MAN" ; then
335 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
336 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
337 fi
338
339 # only matters for x86
340 AC_CHECK_PROGS(NASM, nasm)
341 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
342 if test -n "$NASM" ; then
343 AC_DEFINE(FLAC__HAS_NASM)
344 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
345 fi
346
347 # only matters for PowerPC
348 AC_CHECK_PROGS(AS, as, as)
349 AC_CHECK_PROGS(GAS, gas, gas)
350
351 # try -v (apple as) and --version (gas) at the same time
352 test "$AS" = "as" && as --version -v < /dev/null 2>&1 | grep Apple >/dev/null || AS=gas
353
354 AM_CONDITIONAL(FLaC__HAS_AS, test "$AS" = "as")
355 AM_CONDITIONAL(FLaC__HAS_GAS, test "$AS" = "gas")
356 if test "$AS" = "as" ; then
357 AC_DEFINE(FLAC__HAS_AS)
358 AH_TEMPLATE(FLAC__HAS_AS, [define if you are compiling for PowerPC and have the 'as' assembler])
359 fi
360 if test "$AS" = "gas" ; then
361 # funniest. macro. ever.
362 AC_DEFINE(FLAC__HAS_GAS)
363 AH_TEMPLATE(FLAC__HAS_GAS, [define if you are compiling for PowerPC and have the 'gas' assembler])
364 fi
365
366 if test "x$debug" = xtrue; then
367         CPPFLAGS="-DDEBUG $CPPFLAGS"
368         CFLAGS="-g $CFLAGS"
369 else
370         CPPFLAGS="-DNDEBUG $CPPFLAGS"
371         if test "x$GCC" = xyes; then
372                 if test "x$user_cflags" = x; then
373                         CFLAGS="-O3 -funroll-loops -Wall -W -Winline"
374                 fi
375         fi
376 fi
377
378 XIPH_GCC_VERSION
379
380 if test x$ac_cv_c_compiler_gnu = xyes ; then
381         CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Winline -Wconversion
382         CXXFLAGS="$CXXFLAGS -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
383
384
385         if test x$enable_gcc_werror = "xyes" ; then
386                 CFLAGS="$CFLAGS -Wall -Wextra -Werror "
387                 CXXFLAGS="$CXXFLAGS -Wall -Wextra -Werror "
388                 fi
389
390         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
391                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
392                 CFLAGS="$CFLAGS -fvisibility=hidden"
393                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
394                 fi
395
396         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
397                 XIPH_ADD_CFLAGS([-fgnu89-inline])
398                 fi
399         fi
400
401
402 XIPH_ADD_CFLAGS([-Wextra])
403 XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
404 XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
405
406 if test x$enable_stack_smash_protection = "xyes" ; then
407         XIPH_GCC_STACK_PROTECTOR
408         XIPH_GXX_STACK_PROTECTOR
409         fi
410
411 #@@@
412 AM_CONDITIONAL(FLaC__HAS_AS__TEMPORARILY_DISABLED, test "yes" = "no")
413 AM_CONDITIONAL(FLaC__HAS_GAS__TEMPORARILY_DISABLED, test "yes" = "no")
414
415 AC_CONFIG_FILES([ \
416         Makefile \
417         src/Makefile \
418         src/libFLAC/Makefile \
419         src/libFLAC/flac.pc \
420         src/libFLAC/ia32/Makefile \
421         src/libFLAC/ppc/Makefile \
422         src/libFLAC/ppc/as/Makefile \
423         src/libFLAC/ppc/gas/Makefile \
424         src/libFLAC/include/Makefile \
425         src/libFLAC/include/private/Makefile \
426         src/libFLAC/include/protected/Makefile \
427         src/libFLAC++/Makefile \
428         src/libFLAC++/flac++.pc \
429         src/flac/Makefile \
430         src/metaflac/Makefile \
431         src/monkeys_audio_utilities/Makefile \
432         src/monkeys_audio_utilities/flac_mac/Makefile \
433         src/monkeys_audio_utilities/flac_ren/Makefile \
434         src/plugin_common/Makefile \
435         src/plugin_xmms/Makefile \
436         src/share/Makefile \
437         src/test_grabbag/Makefile \
438         src/test_grabbag/cuesheet/Makefile \
439         src/test_grabbag/picture/Makefile \
440         src/test_libs_common/Makefile \
441         src/test_libFLAC/Makefile \
442         src/test_libFLAC++/Makefile \
443         src/test_seeking/Makefile \
444         src/test_streams/Makefile \
445         src/utils/Makefile \
446         src/utils/flacdiff/Makefile \
447         src/utils/flactimer/Makefile \
448         examples/Makefile \
449         examples/c/Makefile \
450         examples/c/decode/Makefile \
451         examples/c/decode/file/Makefile \
452         examples/c/encode/Makefile \
453         examples/c/encode/file/Makefile \
454         examples/cpp/Makefile \
455         examples/cpp/decode/Makefile \
456         examples/cpp/decode/file/Makefile \
457         examples/cpp/encode/Makefile \
458         examples/cpp/encode/file/Makefile \
459         include/Makefile \
460         include/FLAC/Makefile \
461         include/FLAC++/Makefile \
462         include/share/Makefile \
463         include/share/grabbag/Makefile \
464         include/test_libs_common/Makefile \
465         doc/Doxyfile \
466         doc/Makefile \
467         doc/html/Makefile \
468         doc/html/images/Makefile \
469         doc/html/images/hw/Makefile \
470         doc/html/ru/Makefile \
471         m4/Makefile \
472         man/Makefile \
473         test/Makefile \
474         test/cuesheets/Makefile \
475         test/flac-to-flac-metadata-test-files/Makefile \
476         test/metaflac-test-files/Makefile \
477         test/pictures/Makefile \
478         build/Makefile \
479         objs/Makefile \
480         objs/debug/Makefile \
481         objs/debug/bin/Makefile \
482         objs/debug/lib/Makefile \
483         objs/release/Makefile \
484         objs/release/bin/Makefile \
485         objs/release/lib/Makefile \
486 ])
487 AC_OUTPUT
488
489 AC_MSG_RESULT([
490 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
491
492   Configuration summary :
493
494     FLAC version : ........................ ${VERSION}
495
496     Host CPU : ............................ ${host_cpu}
497     Host Vendor : ......................... ${host_vendor}
498     Host OS : ............................. ${host_os}
499 ])
500
501         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
502 if test x$ac_cv_c_compiler_gnu = xyes ; then
503         echo "    GCC version : ......................... ${GCC_VERSION}"
504 fi
505         echo "    Asm optimiizations : .................. ${asm_optimisation}"
506 echo