Fix Makefile.am altivec logic
[flac.git] / configure.ac
1 #  FLAC - Free Lossless Audio Codec
2 #  Copyright (C) 2001,2002,2003,2004,2005,2006,2007,2008,2009  Josh Coalson
3 #
4 #  This file is part the FLAC project.  FLAC is comprised of several
5 #  components distributed under different licenses.  The codec libraries
6 #  are distributed under Xiph.Org's BSD-like license (see the file
7 #  COPYING.Xiph in this distribution).  All other programs, libraries, and
8 #  plugins are distributed under the GPL (see COPYING.GPL).  The documentation
9 #  is distributed under the Gnu FDL (see COPYING.FDL).  Each file in the
10 #  FLAC distribution contains at the top the terms under which it may be
11 #  distributed.
12 #
13 #  Since this particular file is relevant to all components of FLAC,
14 #  it may be distributed under the Xiph.Org license, which is the least
15 #  restrictive of those mentioned above.  See the file COPYING.Xiph in this
16 #  distribution.
17
18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
20
21 AC_PREREQ(2.60)
22 AC_INIT([flac], [1.3.0], [flac-dev@xiph.org], [flac], [https://www.xiph.org/flac/])
23 AC_CONFIG_HEADERS([config.h])
24 AC_CONFIG_SRCDIR([src/flac/main.c])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE([foreign 1.11 -Wall tar-pax no-dist-gzip dist-xz subdir-objects])
27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
28
29 user_cflags=$CFLAGS
30
31 #Prefer whatever the current ISO standard is.
32 AC_PROG_CC_STDC
33 AC_USE_SYSTEM_EXTENSIONS
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35 LT_INIT([win32-dll disable-static pic-only])
36 AM_PROG_AS
37 AC_PROG_CXX
38 XIPH_C_COMPILER_IS_CLANG
39 XIPH_GCC_REALLY_IS_GCC
40 AC_PROG_MAKE_SET
41
42 AC_SYS_LARGEFILE
43 AC_FUNC_FSEEKO
44
45 AC_CHECK_SIZEOF(off_t,1)        # Fake default value.
46 AC_CHECK_SIZEOF([void*])
47 AC_SEARCH_LIBS([lround],[m], [AC_DEFINE(HAVE_LROUND,1,lround support)])
48
49 AC_LANG_PUSH([C++])
50 # c++ flavor first
51 AC_C_VARARRAYS
52 if test $ac_cv_c_vararrays = yes; then
53         AC_DEFINE([HAVE_CXX_VARARRAYS], 1, [Define to 1 if C++ supports variable-length arrays.])
54 fi
55 AC_LANG_POP([C++])
56
57 # c flavor
58 AC_HEADER_STDC
59 AM_PROG_CC_C_O
60 AC_C_INLINE
61 AC_C_VARARRAYS
62 AC_C_TYPEOF
63
64 AC_CHECK_HEADERS([stdint.h inttypes.h byteswap.h sys/param.h termios.h x86intrin.h])
65
66 AC_HEADER_TIOCGWINSZ
67
68 XIPH_C_BSWAP32
69
70 ac_cv_c_big_endian=0
71 ac_cv_c_little_endian=0
72 AC_C_BIGENDIAN([ac_cv_c_big_endian=1], [ac_cv_c_little_endian=1], [
73         AC_MSG_WARN([[*****************************************************************]])
74         AC_MSG_WARN([[*** Not able to determine endian-ness of target processor.       ]])
75         AC_MSG_WARN([[*** The constants CPU_IS_BIG_ENDIAN and CPU_IS_LITTLE_ENDIAN in  ]])
76         AC_MSG_WARN([[*** config.h may need to be hand editied.                        ]])
77         AC_MSG_WARN([[*****************************************************************]])
78 ])
79 AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
80                                         [Target processor is big endian.])
81 AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
82                                         [Target processor is little endian.])
83 AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
84                                         [Target processor is big endian.])
85
86 AC_ARG_ENABLE(asm-optimizations, AC_HELP_STRING([--disable-asm-optimizations], [Don't use any assembly optimization routines]), asm_opt=no, asm_opt=yes)
87 dnl ' Terminate the damn single quote
88 AM_CONDITIONAL(FLaC__NO_ASM, test "x$asm_opt" = xno)
89 if test "x$asm_opt" = xno ; then
90 AC_DEFINE(FLAC__NO_ASM)
91 AH_TEMPLATE(FLAC__NO_ASM, [define to disable use of assembly code])
92 fi
93
94 # For the XMMS plugin.
95 AC_CHECK_TYPES(socklen_t, [], [])
96
97 dnl check for getopt in standard library
98 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
99 AC_CHECK_FUNCS(getopt_long, [], [])
100
101 AC_CHECK_SIZEOF(void*,1)
102
103 asm_optimisation=no
104 case "$host_cpu" in
105         x86_64)
106                 if test $ac_cv_sizeof_voidp = 4 ; then
107                         # This must be a 32 bit user space running on 64 bit kernel so treat
108                         # this as ia32.
109                         cpu_ia32=true
110                         AC_DEFINE(FLAC__CPU_IA32)
111                         AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
112                 else
113                         # x86_64 user space and kernel.
114                         cpu_x86_64=true
115                         AC_DEFINE(FLAC__CPU_X86_64)
116                         AH_TEMPLATE(FLAC__CPU_X86_64, [define if building for x86_64])
117                         fi
118                 asm_optimisation=$asm_opt
119                 ;;
120         i*86)
121                 cpu_ia32=true
122                 AC_DEFINE(FLAC__CPU_IA32)
123                 AH_TEMPLATE(FLAC__CPU_IA32, [define if building for ia32/i386])
124                 asm_optimisation=$asm_opt
125                 ;;
126         powerpc|powerpc64)
127                 cpu_ppc=true
128                 AC_DEFINE(FLAC__CPU_PPC)
129                 AH_TEMPLATE(FLAC__CPU_PPC, [define if building for PowerPC])
130                 asm_optimisation=$asm_opt
131                 ;;
132         sparc)
133                 cpu_sparc=true
134                 AC_DEFINE(FLAC__CPU_SPARC)
135                 AH_TEMPLATE(FLAC__CPU_SPARC, [define if building for SPARC])
136                 asm_optimisation=$asm_opt
137                 ;;
138 esac
139 AM_CONDITIONAL(FLAC__CPU_X86_64, test "x$cpu_x86_64" = xtrue)
140 AM_CONDITIONAL(FLaC__CPU_IA32, test "x$cpu_ia32" = xtrue)
141 AM_CONDITIONAL(FLaC__CPU_PPC, test "x$cpu_ppc" = xtrue)
142 AM_CONDITIONAL(FLaC__CPU_SPARC, test "x$cpu_sparc" = xtrue)
143
144 AC_DEFINE_UNQUOTED([FLAC__HAS_X86INTRIN],${HAVE_X86INTRIN_H}, [Set to 1 if <x86intrin.h> is available.])
145
146 case "$host" in
147         i386-*-openbsd3.[[0-3]]) OBJ_FORMAT=aoutb ;;
148         *-*-cygwin|*mingw*) OBJ_FORMAT=win32 ;;
149         *-*-darwin*) OBJ_FORMAT=macho ;;
150         *emx*) OBJ_FORMAT=aout ;;
151         *) OBJ_FORMAT=elf ;;
152 esac
153 AC_SUBST(OBJ_FORMAT)
154 case "$host" in
155         *-gnuspe)
156                 abi_spe=true
157                 AC_DEFINE(FLAC__CPU_PPC_SPE)
158                 AH_TEMPLATE(FLAC__CPU_PPC_SPE, [define if building for PowerPC with SPE ABI])
159                 ;;
160 esac
161 AM_CONDITIONAL(FLaC__CPU_PPC_SPE, test "x$abi_spe" = xtrue)
162
163 os_is_windows=no
164 case "$host" in
165         *-*-cygwin|*mingw*)
166                 CPPFLAGS="-D__MSVCRT_VERSION__=0x0601 $CPPFLAGS"
167                 os_is_windows=yes
168                 ;;
169 esac
170
171 AM_CONDITIONAL(OS_IS_WINDOWS, test "x$os_is_windows" = xyes)
172
173 case "$host" in
174         *-pc-linux-gnu)
175                 sys_linux=true
176                 AC_DEFINE(FLAC__SYS_LINUX)
177                 AH_TEMPLATE(FLAC__SYS_LINUX, [define if building for Linux])
178                 ;;
179         *-*-darwin*)
180                 sys_darwin=true
181                 AC_DEFINE(FLAC__SYS_DARWIN)
182                 AH_TEMPLATE(FLAC__SYS_DARWIN, [define if building for Darwin / MacOS X])
183                 ;;
184 esac
185 AM_CONDITIONAL(FLaC__SYS_DARWIN, test "x$sys_darwin" = xtrue)
186 AM_CONDITIONAL(FLaC__SYS_LINUX, test "x$sys_linux" = xtrue)
187
188 if test "x$cpu_ia32" = xtrue || test "x$cpu_x86_64" = xtrue ; then
189 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
190 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA, [define to align allocated memory on 32-byte boundaries])
191 fi
192
193 AC_ARG_ENABLE(debug,
194 AC_HELP_STRING([--enable-debug], [Turn on debugging]),
195 [case "${enableval}" in
196         yes) debug=true ;;
197         no)  debug=false ;;
198         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
199 esac],[debug=false])
200 AM_CONDITIONAL(DEBUG, test "x$debug" = xtrue)
201
202 AC_ARG_ENABLE(sse,
203 AC_HELP_STRING([--enable-sse], [Enable SSE support by asserting that the OS supports SSE instructions]),
204 [case "${enableval}" in
205         yes) sse_os=true ;;
206         no)  sse_os=false ;;
207         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
208 esac],[sse_os=false])
209 AM_CONDITIONAL(FLaC__SSE_OS, test "x$sse_os" = xtrue)
210 if test "x$sse_os" = xtrue ; then
211 AC_DEFINE(FLAC__SSE_OS)
212 AH_TEMPLATE(FLAC__SSE_OS, [define if your operating system supports SSE instructions])
213 fi
214
215 AC_ARG_ENABLE(3dnow,
216 AC_HELP_STRING([--disable-3dnow], [Disable 3DNOW! optimizations]),
217 [case "${enableval}" in
218         yes) use_3dnow=true ;;
219         no)  use_3dnow=false ;;
220         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
221 esac],[use_3dnow=true])
222 AM_CONDITIONAL(FLaC__USE_3DNOW, test "x$use_3dnow" = xtrue)
223 if test "x$use_3dnow" = xtrue ; then
224 AC_DEFINE(FLAC__USE_3DNOW)
225 AH_TEMPLATE(FLAC__USE_3DNOW, [define to enable use of 3Dnow! instructions])
226 fi
227
228 AC_ARG_ENABLE(altivec,
229 AC_HELP_STRING([--disable-altivec], [Disable Altivec optimizations]),
230 [case "${enableval}" in
231         yes) use_altivec=true ;;
232         no)  use_altivec=false ;;
233         *) AC_MSG_ERROR(bad value ${enableval} for --enable-altivec) ;;
234 esac],[use_altivec=true])
235 AM_CONDITIONAL(FLaC__USE_ALTIVEC, test "x$use_altivec" = xtrue)
236 if test "x$use_altivec" = xtrue ; then
237 AC_DEFINE(FLAC__USE_ALTIVEC)
238 AH_TEMPLATE(FLAC__USE_ALTIVEC, [define to enable use of Altivec instructions])
239 fi
240
241 AC_ARG_ENABLE(thorough-tests,
242 AC_HELP_STRING([--disable-thorough-tests], [Disable thorough (long) testing, do only basic tests]),
243 [case "${enableval}" in
244         yes) thorough_tests=true ;;
245         no)  thorough_tests=false ;;
246         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thorough-tests) ;;
247 esac],[thorough_tests=true])
248 AC_ARG_ENABLE(exhaustive-tests,
249 AC_HELP_STRING([--enable-exhaustive-tests], [Enable exhaustive testing (VERY long)]),
250 [case "${enableval}" in
251         yes) exhaustive_tests=true ;;
252         no)  exhaustive_tests=false ;;
253         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
254 esac],[exhaustive_tests=false])
255 if test "x$thorough_tests" = xfalse ; then
256 FLAC__TEST_LEVEL=0
257 elif test "x$exhaustive_tests" = xfalse ; then
258 FLAC__TEST_LEVEL=1
259 else
260 FLAC__TEST_LEVEL=2
261 fi
262 AC_SUBST(FLAC__TEST_LEVEL)
263
264 AC_ARG_ENABLE(gcc-werror,
265         AC_HELP_STRING([--enable-gcc-werror], [Enable -Werror in all Makefiles]))
266
267 AC_ARG_ENABLE(stack-smash-protection,
268         AC_HELP_STRING([--enable-stack-smash-protection], [Enable GNU GCC stack smash protection]))
269
270 AC_ARG_ENABLE(valgrind-testing,
271 AC_HELP_STRING([--enable-valgrind-testing], [Run all tests inside Valgrind]),
272 [case "${enableval}" in
273         yes) FLAC__TEST_WITH_VALGRIND=yes ;;
274         no)  FLAC__TEST_WITH_VALGRIND=no ;;
275         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
276 esac],[FLAC__TEST_WITH_VALGRIND=no])
277 AC_SUBST(FLAC__TEST_WITH_VALGRIND)
278
279 AC_ARG_ENABLE(doxygen-docs,
280 AC_HELP_STRING([--disable-doxygen-docs], [Disable API documentation building via Doxygen]),
281 [case "${enableval}" in
282         yes) enable_doxygen_docs=true ;;
283         no)  enable_doxygen_docs=false ;;
284         *) AC_MSG_ERROR(bad value ${enableval} for --enable-doxygen-docs) ;;
285 esac],[enable_doxygen_docs=true])
286 if test "x$enable_doxygen_docs" != xfalse ; then
287         AC_CHECK_PROGS(DOXYGEN, doxygen)
288 fi
289 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
290
291 AC_ARG_ENABLE(local-xmms-plugin,
292 AC_HELP_STRING([--enable-local-xmms-plugin], [Install XMMS plugin to ~/.xmms/Plugins instead of system location]),
293 [case "${enableval}" in
294         yes) install_xmms_plugin_locally=true ;;
295         no)  install_xmms_plugin_locally=false ;;
296         *) AC_MSG_ERROR(bad value ${enableval} for --enable-local-xmms-plugin) ;;
297 esac],[install_xmms_plugin_locally=false])
298 AM_CONDITIONAL(FLaC__INSTALL_XMMS_PLUGIN_LOCALLY, test "x$install_xmms_plugin_locally" = xtrue)
299
300 AC_ARG_ENABLE(xmms-plugin,
301 AC_HELP_STRING([--disable-xmms-plugin], [Do not build XMMS plugin]),
302 [case "${enableval}" in
303         yes) enable_xmms_plugin=true ;;
304         no)  enable_xmms_plugin=false ;;
305         *) AC_MSG_ERROR(bad value ${enableval} for --enable-xmms-plugin) ;;
306 esac],[enable_xmms_plugin=true])
307 if test "x$enable_xmms_plugin" != xfalse ; then
308         AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - XMMS support will not be built]))
309 fi
310 AM_CONDITIONAL(FLaC__HAS_XMMS, test -n "$XMMS_INPUT_PLUGIN_DIR")
311
312 dnl build FLAC++ or not
313 AC_ARG_ENABLE([cpplibs],
314 AC_HELP_STRING([--disable-cpplibs], [Do not build libFLAC++]),
315 [case "${enableval}" in
316         yes) disable_cpplibs=false ;;
317         no)  disable_cpplibs=true ;;
318         *)   AC_MSG_ERROR(bad value ${enableval} for --enable-cpplibs) ;;
319 esac], [disable_cpplibs=false])
320 AM_CONDITIONAL(FLaC__WITH_CPPLIBS, [test "x$disable_cpplibs" != xtrue])
321
322 dnl check for ogg library
323 AC_ARG_ENABLE([ogg],
324         AC_HELP_STRING([--disable-ogg], [Disable ogg support (default: test for libogg)]),
325         [ want_ogg=$enableval ], [ want_ogg=yes ] )
326
327 if test "x$want_ogg" != "xno"; then
328         XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
329 fi
330
331 AM_CONDITIONAL(FLaC__HAS_OGG, [test "x$have_ogg" = xyes])
332 if test "x$have_ogg" = xyes ; then
333         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],1,[define if you have the ogg library])
334         OGG_PACKAGE="ogg"
335 else
336         AC_DEFINE_UNQUOTED([FLAC__HAS_OGG],0)
337         have_ogg=no
338 fi
339 AC_SUBST(OGG_PACKAGE)
340
341 dnl check for i18n(internationalization); these are from libiconv/gettext
342 AM_ICONV
343 AM_LANGINFO_CODESET
344
345 AC_CHECK_PROGS(DOCBOOK_TO_MAN, docbook-to-man docbook2man)
346 AM_CONDITIONAL(FLaC__HAS_DOCBOOK_TO_MAN, test -n "$DOCBOOK_TO_MAN")
347 if test -n "$DOCBOOK_TO_MAN" ; then
348 AC_DEFINE(FLAC__HAS_DOCBOOK_TO_MAN)
349 AH_TEMPLATE(FLAC__HAS_DOCBOOK_TO_MAN, [define if you have docbook-to-man or docbook2man])
350 fi
351
352 # only matters for x86
353 AC_CHECK_PROGS(NASM, nasm)
354 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
355 if test -n "$NASM" ; then
356 AC_DEFINE(FLAC__HAS_NASM)
357 AH_TEMPLATE(FLAC__HAS_NASM, [define if you are compiling for x86 and have the NASM assembler])
358 fi
359
360 # only matters for PowerPC
361 AC_CHECK_PROGS(AS, as, as)
362 AC_CHECK_PROGS(GAS, gas, gas)
363
364 # try -v (apple as) and --version (gas) at the same time
365 test "$AS" = "as" && as --version -v < /dev/null 2>&1 | grep Apple >/dev/null || AS=gas
366
367 AM_CONDITIONAL(FLaC__HAS_AS, test "$AS" = "as")
368 AM_CONDITIONAL(FLaC__HAS_GAS, test "$AS" = "gas")
369 if test "$AS" = "as" ; then
370 AC_DEFINE(FLAC__HAS_AS)
371 AH_TEMPLATE(FLAC__HAS_AS, [define if you are compiling for PowerPC and have the 'as' assembler])
372 fi
373 if test "$AS" = "gas" ; then
374 # funniest. macro. ever.
375 AC_DEFINE(FLAC__HAS_GAS)
376 AH_TEMPLATE(FLAC__HAS_GAS, [define if you are compiling for PowerPC and have the 'gas' assembler])
377 fi
378
379 if test "x$debug" = xtrue; then
380         CPPFLAGS="-DDEBUG $CPPFLAGS"
381         CFLAGS="-g $CFLAGS"
382 else
383         CPPFLAGS="-DNDEBUG $CPPFLAGS"
384         if test "x$GCC" = xyes; then
385                 if test "x$user_cflags" = x; then
386                         CFLAGS="-O3 -funroll-loops -Wall -W -Winline"
387                 fi
388         fi
389 fi
390
391 XIPH_GCC_VERSION
392
393 if test x$ac_cv_c_compiler_gnu = xyes ; then
394         CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Winline -Wconversion
395         CXXFLAGS="$CXXFLAGS -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef " # -Wcast-qual -Wbad-function-cast -Wwrite-strings -Woverloaded-virtual -Wmissing-declarations
396
397
398         if test x$enable_gcc_werror = "xyes" ; then
399                 CFLAGS="$CFLAGS -Werror "
400                 CXXFLAGS="$CXXFLAGS -Werror "
401                 fi
402
403         XIPH_ADD_CFLAGS([-Wdeclaration-after-statement])
404         XIPH_ADD_CFLAGS([-D_FORTIFY_SOURCE=2])
405
406         AC_LANG_PUSH([C++])
407         XIPH_ADD_CXXFLAGS([-Weffc++])
408         AC_LANG_POP([C++])
409
410         if test "$GCC_MAJOR_VERSION" -ge 4 && test "$OBJ_FORMAT" = elf; then
411                 CPPFLAGS="$CPPFLAGS -DFLAC__USE_VISIBILITY_ATTR"
412                 CFLAGS="$CFLAGS -fvisibility=hidden"
413                 CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
414                 fi
415
416         if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
417                 XIPH_ADD_CFLAGS([-fgnu89-inline])
418                 fi
419
420         if test "x$asm_optimisation" = "xyes" ; then
421                 XIPH_ADD_CFLAGS([-msse2])
422                 fi
423
424         fi
425
426 XIPH_ADD_CFLAGS([-Wextra])
427
428 if test x$enable_stack_smash_protection = "xyes" ; then
429         XIPH_GCC_STACK_PROTECTOR
430         XIPH_GXX_STACK_PROTECTOR
431         fi
432
433 #@@@
434 AM_CONDITIONAL(FLaC__HAS_AS__TEMPORARILY_DISABLED, test "yes" = "no")
435 AM_CONDITIONAL(FLaC__HAS_GAS__TEMPORARILY_DISABLED, test "yes" = "no")
436
437 AC_CONFIG_FILES([ \
438         Makefile \
439         src/Makefile \
440         src/libFLAC/Makefile \
441         src/libFLAC/flac.pc \
442         src/libFLAC/ia32/Makefile \
443         src/libFLAC/ppc/Makefile \
444         src/libFLAC/ppc/as/Makefile \
445         src/libFLAC/ppc/gas/Makefile \
446         src/libFLAC/include/Makefile \
447         src/libFLAC/include/private/Makefile \
448         src/libFLAC/include/protected/Makefile \
449         src/libFLAC++/Makefile \
450         src/libFLAC++/flac++.pc \
451         src/flac/Makefile \
452         src/metaflac/Makefile \
453         src/monkeys_audio_utilities/Makefile \
454         src/monkeys_audio_utilities/flac_mac/Makefile \
455         src/monkeys_audio_utilities/flac_ren/Makefile \
456         src/plugin_common/Makefile \
457         src/plugin_xmms/Makefile \
458         src/share/Makefile \
459         src/test_grabbag/Makefile \
460         src/test_grabbag/cuesheet/Makefile \
461         src/test_grabbag/picture/Makefile \
462         src/test_libs_common/Makefile \
463         src/test_libFLAC/Makefile \
464         src/test_libFLAC++/Makefile \
465         src/test_seeking/Makefile \
466         src/test_streams/Makefile \
467         src/utils/Makefile \
468         src/utils/flacdiff/Makefile \
469         src/utils/flactimer/Makefile \
470         examples/Makefile \
471         examples/c/Makefile \
472         examples/c/decode/Makefile \
473         examples/c/decode/file/Makefile \
474         examples/c/encode/Makefile \
475         examples/c/encode/file/Makefile \
476         examples/cpp/Makefile \
477         examples/cpp/decode/Makefile \
478         examples/cpp/decode/file/Makefile \
479         examples/cpp/encode/Makefile \
480         examples/cpp/encode/file/Makefile \
481         include/Makefile \
482         include/FLAC/Makefile \
483         include/FLAC++/Makefile \
484         include/share/Makefile \
485         include/share/grabbag/Makefile \
486         include/test_libs_common/Makefile \
487         doc/Doxyfile \
488         doc/Makefile \
489         doc/html/Makefile \
490         doc/html/images/Makefile \
491         m4/Makefile \
492         man/Makefile \
493         test/common.sh \
494         test/Makefile \
495         test/cuesheets/Makefile \
496         test/flac-to-flac-metadata-test-files/Makefile \
497         test/metaflac-test-files/Makefile \
498         test/pictures/Makefile \
499         build/Makefile \
500         objs/Makefile \
501         objs/debug/Makefile \
502         objs/debug/bin/Makefile \
503         objs/debug/lib/Makefile \
504         objs/release/Makefile \
505         objs/release/bin/Makefile \
506         objs/release/lib/Makefile \
507 ])
508 AC_OUTPUT
509
510 AC_MSG_RESULT([
511 -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
512
513   Configuration summary :
514
515     FLAC version : ........................ ${VERSION}
516
517     Host CPU : ............................ ${host_cpu}
518     Host Vendor : ......................... ${host_vendor}
519     Host OS : ............................. ${host_os}
520 ])
521
522         echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
523 if test x$ac_cv_c_compiler_gnu = xyes ; then
524         echo "    GCC version : ......................... ${GCC_VERSION}"
525 fi
526         echo "    Compiler is Clang : ................... ${xiph_cv_c_compiler_clang}"
527         echo "    Asm optimizations : ................... ${asm_optimisation}"
528         echo "    Ogg/FLAC support : .................... ${have_ogg}"
529 echo